radio/src/targets/horus/stm32f4_flash.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32f4_flash.ld
   5 **
   6 **  Abstract    : Linker script for STM32F439 Device with
   7 **                2MByte FLASH, 192KByte SRAM, 64KByte CCM
   8 **
   9 **                Set heap size, stack size and stack location according
  10 **                to application requirements.
  11 **
  12 **                Set memory bank area and size if external memory is used.
  13 **
  14 **  Target      : STMicroelectronics STM32
  15 **
  16 *****************************************************************************
  17 */
  18
  19 /* Entry Point */
  20 ENTRY(Reset_Handler)
  21
  22 /* Highest address of the user mode stack */
  23 _estack = 0x10010000;    /* end of 64K CCM */
  24 _heap_end = 0xD0800000;  /* end of 8192K SDRAM */
  25
  26 /* Generate a link error if heap and stack don't fit into RAM */
  27 _Min_Heap_Size = 0;      /* required amount of heap  */
  28 _Main_Stack_Size = 1024; /* required amount of stack for interrupt stack (Main stack) */
  29
  30 /* Main stack end */
  31 _main_stack_start = _estack - _Main_Stack_Size;
  32
  33 /* Specify the memory areas */
  34 MEMORY
  35 {
  36   FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 2048K
  37   RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 192K
  38   CCM (xrw)       : ORIGIN = 0x10000000, LENGTH = 64K
  39   MEMORY_B1 (rx)  : ORIGIN = 0x60000000, LENGTH = 0K
  40   SDRAM(xrw)      : ORIGIN = 0xD0000000, LENGTH = 8192K
  41 }
  42
  43 /* Define output sections */
  44 SECTIONS
  45 {
  46   /* The startup code goes first into FLASH */
  47
  48   /* The program code and other data goes into FLASH */
  49   .text :
  50   {
  51     FILL(0xFFFF)
  52
  53     CREATE_OBJECT_SYMBOLS
  54
  55     KEEP(*(.bootloader)) /* Bootloader code */
  56
  57     . = 0x20000;         /* Set the start of the main program */
  58     _stext = .;          /* Provide the name for the start of this section */
  59     . = ALIGN(4);
  60     KEEP(*(.isr_vector)) /* Startup code */
  61     KEEP(*(.fwversiondata))
  62     *(.text)           /* .text sections (code) */
  63     *(.text*)          /* .text* sections (code) */
  64     *(.rodata)         /* .rodata sections (constants, strings, etc.) */
  65     *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
  66     *(.glue_7)         /* glue arm to thumb code */
  67     *(.glue_7t)        /* glue thumb to arm code */
  68     *(.eh_frame)
  69
  70     KEEP (*(.init))
  71     KEEP (*(.fini))
  72
  73     . = ALIGN(4);
  74     _etext = .;        /* define a global symbols at end of code */
  75   } >FLASH
  76
  77   .ARM.extab   :
  78   { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  79     .ARM : {
  80     __exidx_start = .;
  81       *(.ARM.exidx*)
  82       __exidx_end = .;
  83   } >FLASH
  84
  85   .preinit_array     :
  86   {
  87     PROVIDE_HIDDEN (__preinit_array_start = .);
  88     KEEP (*(.preinit_array*))
  89     PROVIDE_HIDDEN (__preinit_array_end = .);
  90   } >FLASH
  91
  92   .init_array :
  93   {
  94     PROVIDE_HIDDEN (__init_array_start = .);
  95     KEEP (*(SORT(.init_array.*)))
  96     KEEP (*(.init_array*))
  97     PROVIDE_HIDDEN (__init_array_end = .);
  98   } >FLASH
  99
 100   .fini_array :
 101   {
 102     PROVIDE_HIDDEN (__fini_array_start = .);
 103     KEEP (*(.fini_array*))
 104     KEEP (*(SORT(.fini_array.*)))
 105     PROVIDE_HIDDEN (__fini_array_end = .);
 106   } >FLASH
 107
 108   /* used by the startup to initialize data */
 109   _sidata = .;
 110
 111   /* Initialized data sections goes into RAM, load LMA copy after code */
 112   .data : AT ( _sidata )
 113   {
 114     . = ALIGN(4);
 115     _sdata = .;        /* create a global symbol at data start */
 116     *(.data)           /* .data sections */
 117     *(.data*)          /* .data* sections */
 118     . = ALIGN(4);
 119     _edata = .;        /* define a global symbol at data end */
 120   } >CCM
 121
 122   /* Uninitialized data section */
 123   . = ALIGN(4);
 124   .bss :
 125   {
 126     /* This is used by the startup in order to initialize the .bss secion */
 127     _sbss = .;         /* define a global symbol at bss start */
 128     /* __bss_start__ = _sbss; */
 129     *(.bss)
 130     *(.bss*)
 131     *(COMMON)
 132     . = ALIGN(4);
 133     _ebss = .;         /* define a global symbol at bss end */
 134   } >CCM
 135
 136   /* Non-zeroed data section */
 137   . = ALIGN(4);
 138   .noinit (NOLOAD) :
 139   {
 140     *(.noinit)
 141   } >CCM
 142
 143   /* collect all uninitialized .ccm sections */
 144   .ram (NOLOAD) :
 145   {
 146     . = ALIGN(4);
 147     _sram = .;
 148     *(.ram)
 149   } >RAM
 150
 151   /* User_heap_stack section, used to check that there is enough RAM left */
 152   ._user_heap_stack :
 153   {
 154     . = ALIGN(4);
 155     . = . + _Min_Heap_Size;
 156     . = . + _Main_Stack_Size;
 157     . = ALIGN(4);
 158   } >RAM
 159
 160   /* MEMORY_bank1 section, code must be located here explicitly            */
 161   /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
 162   .memory_b1_text :
 163   {
 164     *(.mb1text)        /* .mb1text sections (code) */
 165     *(.mb1text*)       /* .mb1text* sections (code)  */
 166     *(.mb1rodata)      /* read-only data (constants) */
 167     *(.mb1rodata*)
 168   } >MEMORY_B1
 169
 170   .sdram (NOLOAD) :
 171   {
 172     *(.sdram)
 173     *(.sdram*)
 174     *(.sdram_rodata)
 175     *(.sdram_rodata*)
 176     . = ALIGN(4);
 177     _eram = .;
 178   } >SDRAM
 179
 180   PROVIDE ( end = _eram );
 181   PROVIDE ( _end = _eram );
 182
 183   /* Remove information from the standard libraries */
 184   /DISCARD/ :
 185   {
 186     libc.a ( * )
 187     libm.a ( * )
 188     libgcc.a ( * )
 189   }
 190
 191   .ARM.attributes 0 : { *(.ARM.attributes) }
 192 }