cgi-bin/tools/blast/show_match_seq.pl

   1 use CatalystX::GlobalContext qw( $c );
   2
   3 =head1 NAME
   4
   5 show_match_seq.pl - a simple script to show the entire sequence of a
   6 match in a blast database with optional highlighting of the matched
   7 region
   8
   9 =head1 DESCRIPTION
  10
  11 This script shows a webpage with the sequence from a blast database
  12 for a specific id, using CXGN::BlastDB. This is the script that should
  13 be called if the CXGN::Tools::Identifiers cannot determine an
  14 appropriate link, so that the users still can get at the matched
  15 sequence, instead of uselessly defaulting to Genbank.
  16
  17 Page arguments:
  18
  19 =over 10
  20
  21 =item id
  22
  23 The id of the sequence [string], as it appears in the database (best
  24 retrieved from a blast report).
  25
  26 =item blast_db_id
  27
  28 The id [int] of the blast database file for CXGN::BlastDB.
  29
  30 =item hilite_coords
  31
  32 a list of start and end coordinates, of the form:
  33
  34 start1-end1,start2-end2,start3-end3
  35
  36 =item format
  37
  38 either "text" or "html" to output fasta text or a nicely ;-) formatted
  39 html page.
  40
  41 =back
  42
  43 =head1 AUTHOR
  44
  45 Lukas Mueller <lam87@cornell.edu>
  46
  47 Robert Buels <rmb32@cornelle.edu>
  48
  49 =cut
  50
  51 use strict;
  52 use warnings;
  53
  54 use CGI ();
  55
  56 use CXGN::BlastDB;
  57 use CXGN::Tools::Text qw/ sanitize_string /;
  58 use CXGN::MasonFactory;
  59
  60 use CXGN::Page::FormattingHelpers qw | info_section_html html_break_string html_string_linebreak_and_highlight | ;
  61
  62 my $cgi = CGI->new;
  63
  64 #get params
  65 my ( $id            ) = $cgi->param( 'id'            );
  66 my ( $blast_db_id   ) = $cgi->param( 'blast_db_id'   );
  67 my ( $format        ) = $cgi->param( 'format'        );
  68 my ( $hilite_coords ) = $cgi->param( 'hilite_coords' );
  69
  70 #sanitize params
  71 $format      ||= 'html';
  72 $blast_db_id +=  0;
  73 $id          =   sanitize_string( $id );
  74
  75 $c->forward_to_mason_view('/blast/show_seq/input.mas') unless $blast_db_id && defined $id;
  76
  77 # parse the coords param
  78 my @coords =
  79     map {
  80         my ($s, $e) = split "-", $_;
  81         defined $_ or die 'parse error' for $s, $e;
  82         [ $s, $e ]
  83     }
  84     grep length,
  85     split ',',
  86     ( $hilite_coords || '' );
  87
  88 #die("hilite_coords $hilite_coords. ".(join ",", @coords)."\n");
  89
  90 # look up our blastdb
  91 my $bdbo = CXGN::BlastDB->from_id( $blast_db_id )
  92     or $c->throw( is_error => 0,
  93                   message => "The blast database with id $blast_db_id could not be found (please set the blast_db_id parameter).");
  94
  95 my $seq = $bdbo->get_sequence( $id ) # returns a Bio::Seq object.
  96     or $c->throw( is_error => 0,
  97                   message => "The sequence could not be found in the blast database with id $blast_db_id.");
  98
  99 # dispatch to the proper view
 100 if ( $format eq 'html' ) {
 101     my $view_link     = do { $cgi->param( format => 'fasta_text'); '?'.$cgi->query_string };
 102     my $download_link = do { $cgi->param( format => 'fasta_file'); '?'.$cgi->query_string };
 103
 104     $c->forward_to_mason_view(
 105         '/blast/show_seq/html.mas',
 106         seq              => $seq,
 107         highlight_coords => \@coords,
 108         source           => '"'.$bdbo->title.'" BLAST dataset ',
 109         format_links     => [
 110             ( $seq->length > 500_000 ? () : [ 'View as FASTA' => $view_link ] ),
 111             [ 'Download as FASTA' => $download_link ],
 112            ],
 113         blast_url => '/tools/blast/index.pl',
 114        );
 115
 116 } elsif( $format eq 'fasta_file' || $format eq 'fasta_text' ) {
 117
 118     require Bio::SeqIO;
 119
 120     print "Content-Type: text/plain\n";
 121     my $attachment = $format eq 'fasta_file' ? 'attachment;' : '';
 122     print "Content-Disposition: $attachment filename=$id.fa\n";
 123     print "\n";
 124     Bio::SeqIO->new( -fh => \*STDOUT, -format => 'fasta' )
 125               ->write_seq( $seq )
 126 }
 127
 128