t/lib/SGN/Test/WWW/Mechanize.pm

   1 =head1 NAME
   2
   3 SGN::Test::WWW::Mechanize - subclass of
   4 L<Test::WWW::Mechanize::Catalyst> with some SGN-specific convenience
   5
   6 =head1 SYNOPSIS
   7
   8     my $mech = SGN::Test::WWW::Mechanize->new;
   9
  10     # look at some pages
  11     $mech->get_ok( '/organism/sol100/view' );
  12     $mech->content_contains('SOL100 Organisms');
  13     $mech->content_contains('presents a summary');
  14     $mech->content_contains('click on an organism name');
  15     $mech->content_lacks('Add to Tree','not logged in, does not have a form for adding an organism');
  16
  17     # do some tests while logged in as a temporary user
  18     $mech->while_logged_in( user_type => 'curator', sub {
  19
  20         $mech->get_ok( '/organism/sol100/view' );
  21         $mech->content_contains( 'Authorized user', 'now says authorized user' );
  22         $mech->content_contains( 'Add a SOL100 organism', 'now has an adding form' );
  23         $mech->submit_form_ok({
  24             form_name => 'sol100_add_form',
  25             fields    => { species => $test_organism->species },
  26            }, 'submitted add organism form');
  27
  28     });
  29
  30 =head1 SEE ALSO
  31
  32 This class has the methods from all of these:
  33   L<Test::WWW::Mechanize::Catalyst>, L<Test::WWW::Mechanize>, L<WWW::Mechanize>
  34
  35
  36 =head1 METHODS
  37
  38 Plus the following:
  39
  40 =cut
  41
  42 package SGN::Test::WWW::Mechanize;
  43 use Moose;
  44
  45 use SGN;
  46
  47 use CXGN::People::Person;
  48 use CXGN::People::Login;
  49
  50 extends 'Test::WWW::Mechanize::Catalyst';
  51
  52 has '+catalyst_app' => ( default => 'SGN' );
  53
  54 has 'test_user' => (
  55     is => 'rw',
  56     isa => 'HashRef',
  57     predicate => 'has_test_user',
  58     clearer   => 'clear_test_user',
  59    );
  60
  61 sub create_test_user {
  62     my $self = shift;
  63     my %props = @_;
  64
  65     local $SIG{__DIE__} = \&Carp::confess;
  66     my %u = qw(
  67                first_name  testfirstname
  68                last_name   testlastname
  69                user_name   testusername
  70                password    testpassword
  71               );
  72
  73     $self->_delete_user( \%u );
  74
  75     # generate a new user for testing purposes
  76     # (to be deleted right afterwards)
  77     $self->catalyst_app->dbc->txn( ping => sub {
  78         my $dbh = $_;
  79
  80         my $p = CXGN::People::Person->new( $dbh );
  81         $p->set_first_name( $u{first_name} );
  82         $p->set_last_name( $u{last_name} );
  83         my $p_id = $p->store();
  84         $u{ sp_person_id } = $p_id
  85             or die "could not create person $u{first_name} $u{last_name}";
  86
  87         my $login = CXGN::People::Login->new( $dbh, $p_id );
  88         $login->set_username( $u{user_name} );
  89         $login->set_password( $u{password} );
  90         $login->set_user_type( $props{user_type} || 'user' );
  91
  92         $login->store();
  93     });
  94
  95     $self->test_user(\%u);
  96 }
  97
  98
  99 sub DEMOLISH {
 100     shift->delete_test_user;
 101 }
 102
 103 sub set_test_user_type {
 104     my $self = shift;
 105
 106     CXGN::People::Login
 107           ->new( $self->catalyst_app->dbc->dbh, $self->test_user->{sp_person_id} )
 108           ->set_user_type(shift);
 109 }
 110
 111 sub delete_test_user {
 112     my $self = shift;
 113
 114     # delete our test user from the database if one has been created
 115     if( $self->has_test_user ) {
 116         my $u = $self->test_user;
 117         $self->_delete_user( $u );
 118     }
 119
 120     $self->clear_test_user;
 121 }
 122
 123 sub _delete_user {
 124     my ( $self, $u ) = @_;
 125
 126     $self->catalyst_app->dbc->txn( ping => sub {
 127         my $dbh = $_;
 128         if ( my $u_id = CXGN::People::Person->get_person_by_username( $dbh, $u->{user_name} ) ) {
 129             CXGN::People::Person->new( $dbh, $u_id )->hard_delete;
 130         }
 131     });
 132 }
 133
 134 =head2 while_logged_in
 135
 136 Execute the given code while logged in.  Takes an optional
 137 hash-style list of parameters to set on the temp user that is created.
 138
 139   Args:  hash-style list of props for the temp user to create,
 140          followed by a subroutine ref to execute while logged in
 141
 142          current supported user properties:
 143
 144            user_type  'curator', 'sequencer', etc.  default 'user'
 145   Ret: nothing meaningful
 146
 147   Example:
 148
 149     $mech->while_logged_in( user_type => 'curator', sub {
 150
 151         $mech->get_ok( '/organism/sol100/view' );
 152         $mech->content_contains( 'Authorized user', 'now says authorized user' );
 153
 154     });
 155
 156 =cut
 157
 158 sub while_logged_in {
 159     my $self = shift;
 160     my $sub  = pop;
 161     my %props = @_;
 162     $self->create_test_user( %props );
 163     $self->log_in_ok;
 164     $sub->();
 165     $self->log_out;
 166 }
 167
 168 sub log_in_ok {
 169     my ($self) = @_;
 170
 171     $self->get_ok("/solpeople/top-level.pl");
 172     $self->content_contains("Login");
 173
 174     my %form = (
 175         form_name => 'login',
 176         fields    => {
 177             username => $self->test_user->{user_name},
 178             pd       => $self->test_user->{password},
 179         },
 180        );
 181
 182     $self->submit_form_ok( \%form, "submitted login form" );
 183     $self->content_lacks('Incorrect username', 'did not get "Incorrect username"')
 184         or Test::More::diag $self->content;
 185     $self->content_contains('View or update personal','got MySGN')
 186         or Test::More::diag $self->content;
 187 }
 188
 189 sub log_out {
 190     my ($self) = @_;
 191     $self->get_ok( "/solpeople/login.pl?logout=yes", 'logged out' );
 192 }
 193
 194
 195 __PACKAGE__->meta->make_immutable( inline_constructor => 0 );
 196 1;