lib/SGN/Controller/Genomes.pm

   1 package SGN::Controller::Genomes;
   2
   3 =head1 NAME
   4
   5 SGN::Controller::Genomes - controller for genome portal pages
   6
   7 =cut
   8
   9 use Moose;
  10 use namespace::autoclean;
  11
  12 use List::MoreUtils 'uniq';
  13
  14 BEGIN{ extends 'Catalyst::Controller' }
  15
  16 with 'Catalyst::Component::ApplicationAttribute';
  17
  18 =head1 PUBLIC ACTIONS
  19
  20 =head1 list_genomes
  21
  22 Public path: /genomes
  23
  24 =cut
  25
  26 sub list_genomes : Path( '/genomes' ) Args(0) {
  27     my ( $self, $c ) = @_;
  28
  29     my $schema = $c->dbic_schema( 'Bio::Chado::Schema', 'sgn_chado' );
  30
  31     $c->stash(
  32
  33         genome_organisms => [
  34             $schema->resultset('Organism::Organismprop')
  35               ->search({ 'type.name' => 'genome_page' }, { join => 'type' })
  36               ->search_related('organism')
  37               ->all
  38         ],
  39
  40         template         => '/genomes/index.mas',
  41     );
  42 }
  43
  44 =head2 view_genome_data
  45
  46 Public path: /organism/<organism id or name>/genome
  47
  48 Queries for Biosource bs_sample records of type 'sequence_collection'
  49 or 'genome_annotation_set', and displays them with file download
  50 links.
  51
  52 =cut
  53
  54 sub view_genome_data : Chained('/organism/find_organism') PathPart('genome') {
  55     my ( $self, $c ) = @_;
  56
  57     my $organism = $c->stash->{organism};
  58     $c->throw_404 unless $organism && $organism->search_related('organismprops',
  59                              { 'type.name' => 'genome_page', 'me.value' => 1 },
  60                              { join => 'type' },
  61                          )->count;
  62
  63     (my $template_name = '/genomes/'.$organism->species.'.mas') =~ s/ /_/g;
  64
  65     # find assemblies for this organism
  66     $c->stash->{assembly_list} = my $assembly_list = [
  67         map {
  68             my $s = $_;
  69             my $h = $self->_bs_sample_to_display_hashref( $c, $s );
  70             # also add the associated annotation_sets to it
  71             $h->{annotation_sets} =  [ $self->assembly_annotations( $s ) ];
  72             $h
  73         } $self->assemblies_for_organism( $organism )->all
  74       ];
  75
  76     # find annotation sets for this organism
  77     $c->stash->{annotation_list} = [
  78         map {
  79             $self->_bs_sample_to_display_hashref( $c, $_ );
  80         }
  81         # annotation sets are the ones that were found related to the
  82         # assemblies, plus ones queried from the db by organism, made
  83         # unique, and sorted
  84         sort { $a->metadata && $a->metadata->create_date->epoch <=> $b->metadata && $b->metadata->create_date->epoch
  85                || $a->sample_name cmp $b->sample_name
  86              }
  87         $self->uniq_bs_samples(
  88             ( map { @{ $_->{annotation_sets} || [] } } @$assembly_list ),
  89             $self->annotation_sets_for_organism( $organism )->all
  90         )
  91       ];
  92
  93     # choose which template we will use
  94     $c->stash->{template} =
  95         $c->view('Mason')->component_exists( $template_name )
  96             ? $template_name : '/genomes/default.mas';
  97 }
  98
  99 =head2 view_inbred_genomes
 100
 101 Public path: /organism/Solanum_lycopersicum/inbred_genomes
 102
 103
 104 =cut
 105
 106 sub view_inbred_genome : Path('/organism/Solanum_lycopersicum/inbred_genomes') {
 107     my ( $self, $c ) = @_;
 108
 109     $c->stash->{template} = '/genomes/Solanum_lycopersicum/inbreds.mas';
 110 }
 111
 112 =head2 view_tomato_150
 113
 114 Public path: /organism/Solanum_lycopersicum/tomato_150
 115
 116
 117 =cut
 118
 119 sub view_tomato_150 : Path('/organism/Solanum_lycopersicum/tomato_150') {
 120     my ( $self, $c ) = @_;
 121
 122     $c->stash->{template} = '/genomes/Solanum_lycopersicum/tomato150.mas';
 123 }
 124
 125 =head2 view_tomato_360
 126
 127 Public path: /organism/Solanum_lycopersicum/tomato_360
 128
 129
 130 =cut
 131
 132 sub view_tomato_360 : Path('/organism/Solanum_lycopersicum/tomato_360') {
 133     my ( $self, $c ) = @_;
 134
 135     $c->stash->{template} = '/genomes/Solanum_lycopersicum/tomato360.mas';
 136 }
 137
 138 ####### helper methods ##########
 139
 140 sub uniq_bs_samples {
 141     my $self = shift;
 142     my %seen;
 143     return grep !$seen{$_->sample_id}++, @_
 144 }
 145
 146 sub _bs_sample_to_display_hashref {
 147     my ( $self, $c, $bs_sample ) = @_;
 148
 149     return {
 150         name => $c->view('BareMason')->render( $c, '/biosource/sample_link.mas', { sample => $bs_sample } ),
 151         date => $bs_sample->metadata ? $bs_sample->metadata->create_date : undef,
 152         description => $bs_sample->description,
 153         files => [
 154             map +{ text        => $_->basename,
 155                    url         => '/metadata/file/'.$_->file_id.'/download',
 156                    description => $_->comment,
 157                  },
 158             $self->assembly_files( $bs_sample )
 159          ],
 160     };
 161 }
 162
 163 sub _annotates_cvterms_rs {
 164     my ( $self, $row ) = @_;
 165     my $schema = $row ? $row->result_source->schema : $self->_app->dbic_schema('CXGN::Biosource::Schema');
 166
 167     return $schema->resultset('Cv::Cvterm')
 168                   ->search_rs({ name => 'annotates' });
 169 }
 170
 171 sub assembly_annotations {
 172     my ( $self, $sample_row ) = @_;
 173     return
 174         $sample_row->search_related('bs_sample_relationship_objects',
 175                        { 'me.type_id' =>
 176                              { -in => $self->_annotates_cvterms_rs( $sample_row )
 177                                            ->get_column('cvterm_id')
 178                                            ->as_query,
 179                              },
 180                        },
 181                      )
 182                    ->search_related('subject')
 183                    ->all
 184     ;
 185 }
 186
 187 sub assembly_files {
 188     my ( $self, $sample_row ) = @_;
 189
 190     return
 191         $sample_row->search_related('bs_sample_files')
 192                    ->search_related('file')
 193                    ->all
 194     ;
 195 }
 196
 197 sub assemblies_for_organism {
 198     my ( $self, $organism ) = @_;
 199
 200     my $schema = $organism->result_source->schema;
 201
 202     $schema->resultset('BsSample')
 203            ->search({
 204                type_id     => { -in => [ uniq map $_->cvterm_id, @{$self->_assembly_cvterms( $schema )}] },
 205                organism_id => $organism->organism_id,
 206              });
 207 }
 208
 209 sub annotation_sets_for_organism {
 210     my ( $self, $organism ) = @_;
 211     my $schema = $organism->result_source->schema;
 212
 213     $schema->resultset('BsSample')
 214            ->search({
 215                type_id     => { -in => [ uniq map $_->cvterm_id, @{$self->_annotation_cvterms( $schema )}] },
 216                organism_id => $organism->organism_id,
 217              });
 218 }
 219
 220 # get the RS of types (i.e. cvterms) that would indicate that we
 221 # should list a certain biosource
 222 # currently defined as 'all SO children '
 223 sub _assembly_cvterms {
 224     my ( $self, $schema ) = @_;
 225     my $sc = $schema->resultset('Cv::Cv')
 226            ->search({ 'me.name' => ['sequence','SO'] })
 227            ->search_related('cvterms', {
 228                'cvterms.name' => 'sequence_collection',
 229              });
 230
 231     my @terms = $sc->all;
 232     return [ @terms, map $_->recursive_children, @terms ];
 233 }
 234
 235 sub _annotation_cvterms {
 236     my ( $self, $schema ) = @_;
 237     my $t = $schema->resultset('Cv::Cvterm')
 238            ->search({ 'name' => 'genome_annotation_set' });
 239
 240     my @terms = $t->all;
 241     return [ @terms, map $_->recursive_children, @terms ];
 242 }
 243
 244 1;