lib/SGN/Controller/Biosource.pm

   1 =head1 NAME
   2
   3 SGN::Controller::Biosource - controller for working with Biosource data, which is metadata about datasets
   4
   5 =cut
   6
   7 package SGN::Controller::Biosource;
   8 use Moose;
   9
  10 BEGIN { extends 'Catalyst::Controller' }
  11
  12 use CXGN::Biosource::Sample;
  13 use CXGN::GEM::Target;
  14
  15 =head1 PUBLIC ACTIONS
  16
  17 =head2 view_sample
  18
  19 Public path: /data_source/<ident>/view
  20
  21 View a biosource sample detail page.
  22
  23 =cut
  24
  25 sub view_sample : Chained('get_sample') PathPart('view') Args(0) {
  26     my ( $self, $c ) = @_;
  27
  28     $c->forward('get_sample_targets');
  29     $c->forward('get_sample_files');
  30
  31     $c->stash(
  32         sample_relations_href => { $c->stash->{sample}->get_relationship },
  33         pub_list              => [ $c->stash->{sample}->get_publication_list ],
  34
  35         template => '/biosource/sample_detail.mas',
  36       );
  37
  38 }
  39
  40 ### helper actions ###
  41
  42 # chain root for retrieving a biosource sample, URL beginning with
  43 # /data_source/<ident>.  supports either an ID number or a sample name as
  44 # the identifier
  45 sub get_sample : Chained('/') CaptureArgs(1) PathPart('data_source') {
  46     my ( $self, $c, $ident ) = @_;
  47
  48     $ident or $c->throw_client_error('invalid arguments');
  49
  50     my $schema = $c->stash->{schema} = $c->dbic_schema('CXGN::Biosource::Schema','sgn_chado');
  51
  52     no strict 'refs';
  53     my $method_name = $ident =~ /\D/ ? 'new_by_name' : 'new';
  54     $c->stash->{sample} = CXGN::Biosource::Sample->$method_name( $schema, $ident )
  55         or $c->throw_404;
  56 }
  57
  58 sub get_sample_files : Private {
  59     my ( $self, $c ) = @_;
  60
  61     $c->stash->{files} = [
  62             $c->stash->{sample}->get_bssample_row
  63                                ->search_related('bs_sample_files')
  64                                ->search_related('file')
  65                                ->all
  66      ];
  67 }
  68
  69 # The sample can be associated expression data (search sample_id in
  70 # gem.ge_target_element table)
  71 sub get_sample_targets : Private {
  72     my ( $self, $c ) = @_;
  73
  74     my $sample = $c->stash->{sample};
  75
  76     return unless $sample->get_sample_id;
  77
  78     my $gemschema = $c->dbic_schema('CXGN::GEM::Schema','sgn_chado');
  79
  80     $c->stash->{target_list} = [
  81         map { CXGN::GEM::Target->new( $gemschema, $_ ) }
  82         $gemschema->resultset('GeTargetElement')
  83                   ->search({ sample_id => $sample->get_sample_id })
  84                   ->get_column('target_id')
  85                   ->all
  86     ];
  87 }
  88
  89
  90 1;