lib/SGN/Controller/Publication.pm

   1 package SGN::Controller::Publication;
   2
   3 =head1 NAME
   4
   5 SGN::Controller::Publication - Catalyst controller for the SGN publication page
   6 (replacing the old cgi script)
   7
   8 =cut
   9
  10 use Moose;
  11 use namespace::autoclean;
  12 use File::Slurp;
  13
  14 use URI::FromHash 'uri';
  15
  16 use CXGN::Chado::Publication ;
  17
  18 BEGIN { extends 'Catalyst::Controller' }
  19 with 'Catalyst::Component::ApplicationAttribute';
  20
  21
  22 has 'schema' => (
  23     is       => 'rw',
  24     isa      => 'DBIx::Class::Schema',
  25     lazy_build => 1,
  26 );
  27
  28
  29
  30 sub pub_search : Path('/search/publication') Args(0) {
  31     my $self = shift;
  32     my $c = shift;
  33
  34     $c->stash(
  35         template       => '/search/pub.mas',
  36
  37         );
  38 }
  39
  40
  41 sub _build_schema {
  42     shift->_app->dbic_schema( 'Bio::Chado::Schema', 'sgn_chado' )
  43 }
  44
  45
  46 =head2 new_pub
  47
  48 Public path: /pub/0/new
  49
  50 Create a new publication.
  51
  52 Chained off of L</get_pub> below.
  53
  54 =cut
  55
  56 sub new_pub : Chained('get_pub') PathPart('new') Args(0) {
  57     my ( $self, $c ) = @_;
  58     $c->stash(
  59         template => '/publication/index.mas',
  60
  61         pubref => {
  62             action    => "new",
  63             pub_id  => 0 ,
  64             pub       => $c->stash->{pub},
  65             schema    => $self->schema,
  66         },
  67         );
  68 }
  69
  70 =head2 view_by_doi
  71
  72 Public path: /doi/pub/
  73
  74 View publication by doi.
  75
  76 Since DOIs can have "/" in them this path captures 3 args and then concatenates to recreate the DOI (hopefully no DOI has more than 3 slashes! )
  77
  78 =cut
  79
  80
  81 sub view_by_doi : Path('/doi/pub/') CaptureArgs(3) {
  82     my ($self, $c , @doi_parts) = @_;
  83     my $doi = join '/' , @doi_parts;
  84     my $matching_pubs = $self->schema->resultset('Pub::Pub')->search(
  85             {
  86                 'dbxref.accession' => $doi,
  87             }, {
  88                 join => { 'pub_dbxrefs' => 'dbxref' },
  89             } );
  90
  91     if( $matching_pubs->count > 1 ) {
  92         $c->throw_client_error( public_message => 'Multiple matching publications' );
  93     }
  94
  95     my ( $publication ) = $matching_pubs->all
  96         or $c->throw_404( "publication $doi  not found" );
  97     my $found_pub_id = $publication->pub_id;
  98     my $pub =  CXGN::Chado::Publication->new($c->dbc->dbh, $found_pub_id);
  99     $c->{stash}->{pub} = $pub;
 100
 101     my $logged_user = $c->user;
 102     my $person_id   = $logged_user->get_object->get_sp_person_id if $logged_user;
 103     my $curator     = $logged_user->check_roles('curator') if $logged_user;
 104     my $submitter   = $logged_user->check_roles('submitter') if $logged_user;
 105     my $sequencer   = $logged_user->check_roles('sequencer') if $logged_user;
 106     my $dbh = $c->dbc->dbh;
 107     my $dbxrefs = $pub->get_dbxrefs;
 108     my $stocks = $self->_get_stocks( $c);
 109
 110      $c->stash(
 111         template => '/publication/index.mas',
 112         pubref => {
 113             pub_id    => $found_pub_id ,
 114             curator   => $curator,
 115             submitter => $submitter,
 116             sequencer => $sequencer,
 117             person_id => $person_id,
 118             pub       => $pub,
 119             dbh       => $dbh,
 120             dbxrefs   => $dbxrefs,
 121             doi       => $doi,
 122             stocks    => $stocks,
 123          },
 124          );
 125 }
 126
 127
 128
 129 =head2 view_pub
 130
 131 Public path: /publication/<pub_id>/view
 132
 133 View a publication detail page.
 134
 135 Chained off of L</get_pub> below.
 136
 137 =cut
 138
 139 sub view_pub : Chained('get_pub') PathPart('view') Args(0) {
 140     my ( $self, $c, $action) = @_;
 141     my $pub = $c->stash->{pub};
 142
 143
 144     my $logged_user = $c->user;
 145     my $person_id   = $logged_user->get_object->get_sp_person_id if $logged_user;
 146     my $curator     = $logged_user->check_roles('curator') if $logged_user;
 147     my $submitter   = $logged_user->check_roles('submitter') if $logged_user;
 148     my $sequencer   = $logged_user->check_roles('sequencer') if $logged_user;
 149     my $dbh = $c->dbc->dbh;
 150
 151     ##################
 152
 153     ###Check if a publication page can be printed###
 154     my $pub_id = $pub ? $pub->get_pub_id : undef ;
 155
 156     # print message if pub_id is not valid
 157     unless ( ( $pub_id =~ m /^\d+$/ ) || ($action eq 'new' && !$pub_id) ) {
 158         $c->throw_404( "No publication exists for that identifier." );
 159     }
 160     unless ( $pub || !$pub_id && $action && $action eq 'new' ) {
 161         $c->throw_404( "No publication exists for that identifier." );
 162     }
 163
 164     # print message if pub_id does not exist
 165     if ( !$pub && $action ne 'new' && $action ne 'store' ) {
 166         $c->throw_404('No publication exists for this identifier');
 167     }
 168
 169     ####################
 170
 171     my $dbxrefs = $pub->get_dbxrefs;
 172     my $stocks = $self->_get_stocks( $c );
 173     #########
 174     ################
 175     $c->stash(
 176         template => '/publication/index.mas',
 177         pubref => {
 178             action    => $action,
 179             pub_id  => $pub_id ,
 180             curator   => $curator,
 181             submitter => $submitter,
 182             sequencer => $sequencer,
 183             person_id => $person_id,
 184             user      => $logged_user,
 185             pub       => $pub,
 186             dbh       => $dbh,
 187             dbxrefs   => $dbxrefs,
 188             stocks    => $stocks,
 189         },
 190         );
 191 }
 192
 193
 194 =head1 PRIVATE ACTIONS
 195
 196 =head2 get_pub
 197
 198 Chain root for fetching a publication object to operate on.
 199
 200 Path part: /publication/<pub_id>
 201
 202 =cut
 203
 204 sub get_pub : Chained('/')  PathPart('publication')  CaptureArgs(1) {
 205     my ($self, $c, $pub_id) = @_;
 206
 207     my $identifier_type = $c->stash->{identifier_type}
 208         || $pub_id =~ /[^-\d]/ ? 'accession' : 'pub_id';
 209
 210     if( $identifier_type eq 'pub_id' ) {
 211         if ( $pub_id == 0 ) {
 212             $c->stash->{pub} = CXGN::Chado::Publication->new($c->dbc->dbh);
 213             return 1;
 214         }
 215         $pub_id > 0
 216             or $c->throw_client_error( public_message => 'Publication ID must be a positive integer.' );
 217     }
 218     my $matching_pubs;
 219
 220     if ($identifier_type eq 'pub_id' ) {
 221         $matching_pubs =  $self->schema->resultset('Pub::Pub')->search(
 222             {
 223                 pub_id => $pub_id,
 224             } );
 225     }
 226     if( $matching_pubs->count > 1 ) {
 227         $c->throw_client_error( public_message => 'Multiple matching publications' );
 228     }
 229
 230     my ( $publication ) = $matching_pubs->all
 231         or $c->throw_404( "publication $pub_id  not found" );
 232     my $found_pub_id = $publication->pub_id;
 233
 234     $c->stash->{pub} = CXGN::Chado::Publication->new($c->dbc->dbh, $found_pub_id);
 235
 236     return 1;
 237 }
 238
 239
 240
 241 sub _get_stocks {
 242     my ( $self, $c)  = @_;
 243     my $pub = $c->stash->{pub};
 244     my $schema = $self->schema;
 245     my @stock_ids = $pub->get_stock_ids;
 246     my @stocks;
 247     foreach my $stock_id (@stock_ids) {
 248         my $stock = CXGN::Stock->new( { schema => $schema, stock_id => $stock_id } ) ;
 249         push @stocks, $stock;
 250     }
 251     return \@stocks;
 252 }
 253
 254
 255
 256 =head2 doi_banner
 257
 258 Public path: /doibanner/
 259
 260 Return SGN logo if DOI exists, or a 1x1 empty pixel if does not exist.
 261 Used by Elsevier for banner linking publications to solgenomics publication page /pub/doi/<doi>
 262
 263 =cut
 264
 265
 266 sub doi_banner : Path('/doibanner/') CaptureArgs(3) {
 267     my ($self, $c , @doi_parts) = @_;
 268     my $doi = join '/' , @doi_parts;
 269     my $matching_pubs = $self->schema->resultset('Pub::Pub')->search(
 270             {
 271                 'dbxref.accession' => $doi,
 272             }, {
 273                 join => { 'pub_dbxrefs' => 'dbxref' },
 274             } );
 275     my $pub_count = $matching_pubs->count;
 276     if( $matching_pubs->count > 1 ) {
 277         $c->throw_client_error( public_message => 'Multiple matching publications' );
 278     }
 279
 280     my $image = $c->path_to('/documents/img/white_pixel.png');
 281
 282     if ($pub_count == 1 ) {
 283         $image = $c->path_to( '/documents/img/sgn_logo_26x60.png') ;
 284     }
 285
 286     my $image_file = read_file($image , { binmode => ':raw' } );
 287
 288     $c->response->content_type('image/png');
 289     $c->response->body($image_file);
 290
 291 }
 292
 293 __PACKAGE__->meta->make_immutable;