lib/SGN/View/Mason.pm

   1 =head1 NAME
   2
   3 SGN::View::Mason - Mason View Component for SGN
   4
   5 =head1 DESCRIPTION
   6
   7 Mason View Component for SGN. This extends Catalyst::View::HTML::Mason.
   8
   9 =cut
  10
  11 package SGN::View::Mason;
  12 use Moose;
  13 use Moose::Util::TypeConstraints;
  14 use namespace::autoclean;
  15
  16 extends 'Catalyst::View::HTML::Mason';
  17 with 'Catalyst::Component::ApplicationAttribute';
  18
  19 __PACKAGE__->config(
  20     globals => ['$c'],
  21     template_extension => '.mas',
  22     interp_args => {
  23         data_dir => SGN->tempfiles_base->subdir('mason'),
  24         comp_root => [
  25             [ main => SGN->path_to('mason') ],
  26         ],
  27         preamble => "use utf8; ",
  28     },
  29 );
  30
  31 =head1 CONFIGURATION SETTINGS (which are also accessors)
  32
  33 =head2 add_comp_root
  34
  35 Configurable arrayref of additional Mason component roots.  These will
  36 be searched before the default ones.  Must be absolute paths.
  37
  38 =cut
  39
  40 # munges the interp_args comp_root to include the add_comp_root
  41 # configuration, plus the comp roots for SiteFeatures
  42 sub COMPONENT {
  43     my ( $class, $c, $args ) = @_;
  44
  45     $args = $class->merge_config_hashes( $class->config, $args );
  46
  47     # coerce add_comp_root to arrayref
  48     if( $args->{add_comp_root} && ! ref $args->{add_comp_root} ) {
  49         $args->{add_comp_root} = [ $args->{add_comp_root} ];
  50     }
  51
  52     # add comp roots for features and add_comp_root
  53     unshift @{ $args->{interp_args}->{comp_root} }, (
  54             # add_comp_root
  55             ( map [ additional => $_ ], @{ $args->{add_comp_root} || [] } ),
  56             # SiteFeatures
  57             ( map [ $_->feature_name, $_->path_to('mason')], $c->features ),
  58     );
  59
  60     return $class->new($c, $args);
  61 }
  62
  63 =head1 FUNCTIONS
  64
  65 =head2 $self->component_exists($component)
  66
  67 Check if a Mason component exists. Returns 1 if the component exists, otherwise 0.
  68
  69
  70 =cut
  71
  72 sub component_exists {
  73     my ( $self, $component ) = @_;
  74
  75     return $self->interp->comp_exists( $component ) ? 1 : 0;
  76 }
  77
  78 =head1 SEE ALSO
  79
  80 L<SGN>, L<HTML::Mason>, L<Catalyst::View::HTML::Mason>
  81
  82 =head1 AUTHORS
  83
  84 Robert Buels, Jonathan "Duke" Leto
  85
  86 =head1 LICENSE
  87
  88 This library is free software . You can redistribute it and/or modify it under
  89 the same terms as perl itself.
  90
  91 =cut
  92
  93 __PACKAGE__->meta->make_immutable;
  94 1;