lib/CXGN/Cvterm.pm

   1 =head1 NAME
   2
   3 CXGN::Cvterm - a second-level object for Cvterm
   4
   5 Version: 1.2
   6
   7 =head1 DESCRIPTION
   8
   9 This object was re-factored from CXGN::Chado::Cvterm and moosified.
  10 Use CXGN::Cvterm for new code. CXGN::Chado::Cvterm is deprecated
  11
  12
  13 =head1 AUTHOR
  14
  15 Naama Menda <nm249@cornell.edu>
  16 Lukas Mueller <lam87@cornell.edu>
  17
  18 =cut
  19
  20 package CXGN::Cvterm ;
  21
  22 use Moose;
  23
  24 use Carp;
  25 use Data::Dumper;
  26 use Bio::Chado::Schema;
  27 use CXGN::Metadata::Schema;
  28 use SGN::Model::Cvterm;
  29
  30 use base qw / CXGN::DB::Object / ;
  31
  32 use Try::Tiny;
  33
  34 =head2 accessor schema
  35
  36 =cut
  37
  38 has 'schema' => (
  39     isa => 'Bio::Chado::Schema',
  40     is => 'rw',
  41     required => 1
  42 );
  43
  44 =head2 accessor cvterm
  45
  46    Returns: Cv::Cvterm DBIx::Class object
  47
  48 =cut
  49
  50 has 'cvterm' => (
  51     isa => 'Bio::Chado::Schema::Result::Cv::Cvterm',
  52     is => 'rw',
  53 );
  54
  55 =head2 accessor cvterm_id
  56
  57 =cut
  58
  59 has 'cvterm_id' => (
  60     isa => 'Int',
  61     is => 'rw',
  62 );
  63
  64 =head2 accessor cv
  65
  66 =cut
  67
  68 has 'cv' => (
  69     isa => 'Bio::Chado::Schema::Result::Cv::Cv',
  70     is => 'rw',
  71 );
  72
  73 =head2 accessor cv_id
  74
  75 =cut
  76
  77 has 'cv_id' => (
  78     isa => 'Int',
  79     is => 'rw',
  80 );
  81
  82 =head2 accessor dbxref
  83
  84 =cut
  85
  86 has 'dbxref' => (
  87     isa => 'Bio::Chado::Schema::Result::General::Dbxref',
  88     is => 'rw',
  89 );
  90
  91 =head2 accessor db
  92
  93 =cut
  94
  95 has 'db' => (
  96     isa => 'Bio::Chado::Schema::Result::General::Db',
  97     is => 'rw',
  98 );
  99
 100 =head2 accessor name
 101
 102 =cut
 103
 104 has 'name' => (
 105     isa => 'Str',
 106     is => 'rw',
 107 );
 108
 109 =head2 accessor definition
 110
 111 =cut
 112
 113 has 'definition' => (
 114     isa => 'Str',
 115     is => 'rw',
 116 );
 117
 118 =head2 accessor is_obsolete
 119
 120 =cut
 121
 122
 123 has 'is_obsolete' => (
 124     isa => 'Bool',
 125     is => 'rw',
 126     default => 0,
 127 );
 128
 129
 130 =head2 accessor accession
 131
 132    refers to dbxref.accession column
 133
 134 =cut
 135
 136 has 'accession' => (
 137     isa => 'Maybe[Str]',
 138     is => 'rw',
 139 );
 140
 141 has 'is_variable' => (
 142     isa => 'Bool',
 143     is => 'rw',
 144     default => sub { return 0; },
 145     );
 146
 147 #########################################
 148
 149
 150 sub BUILD {
 151     my $self = shift;
 152
 153     my $cvterm;
 154     if ($self->cvterm_id){
 155         $cvterm = $self->schema()->resultset("Cv::Cvterm")->find({ cvterm_id => $self->cvterm_id() });
 156
 157         if ($cvterm) {
 158             my $cvterm_rel_rs = $self->schema()->resultset("Cv::CvtermRelationship")->search( { subject_id => $self->cvterm_id  });
 159             # require at least one parent to have a variable_of type
 160             #
 161             while (my $row = $cvterm_rel_rs->next()) {
 162                 #print STDERR "ROW TYPE: ".$row->type()->name()."\n";
 163                 if (uc($row->type()->name) eq uc('variable_of')) {
 164                     $self->is_variable(1);
 165                 }
 166             }
 167
 168         }
 169     } elsif ($self->accession )   {
 170         my ($db_name, $dbxref_accession) = split "\:", $self->accession;
 171
 172         #InterPro accessions have a namespace (db.name) that is different from the accession prefic
 173         if ($self->accession =~ m/^IPR*/ ) {
 174             $db_name = 'InterPro';
 175             $dbxref_accession= $self->accession;
 176         }
 177         my $dbxref = $self->schema()->resultset("General::Dbxref")->find(
 178             {
 179                 'db.name'      => $db_name,
 180                 'me.accession' => $dbxref_accession,
 181             },
 182             { join => 'db'}
 183             );
 184
 185         if ($dbxref) { $cvterm = $dbxref->cvterm ; }
 186     }
 187
 188     if (defined $cvterm) {
 189         $self->cvterm($cvterm);
 190         $self->cvterm_id($cvterm->cvterm_id);
 191         $self->name($cvterm->name);
 192         $self->definition($cvterm->definition || '' );
 193         $self->is_obsolete($cvterm->is_obsolete);
 194
 195         $self->dbxref( $self->schema()->resultset("General::Dbxref")->find({ dbxref_id=>$cvterm->dbxref_id() }) );
 196         $self->cv_id( $cvterm->cv_id);
 197         $self->cv( $self->schema()->resultset("Cv::Cv")->find( { cv_id => $cvterm->cv_id() }) );
 198         $self->db( $self->dbxref->db );
 199         $self->accession( $self->db->name . ':' . $self->dbxref->accession );
 200
 201     }
 202     return $self;
 203 }
 204
 205 =head2 function get_image_ids
 206
 207   Synopsis:     my @images = $self->get_image_ids()
 208   Arguments:    none
 209   Returns:      a list of md_image_ids
 210   Side effects: none
 211   Description:  a method for fetching all images associated with a cvterm
 212
 213 =cut
 214
 215 sub get_image_ids {
 216     my $self = shift;
 217     my @ids;
 218     my $q = "SELECT image_id FROM metadata.md_image_cvterm WHERE cvterm_id=? AND obsolete = 'f' ";
 219     my $h = $self->schema->storage->dbh()->prepare($q);
 220     $h->execute($self->cvterm_id);
 221     while (my ($image_id) = $h->fetchrow_array()){
 222         push @ids, [$image_id, 'cvterm'];
 223     }
 224     return @ids;
 225 }
 226
 227
 228
 229 =head2 function get_is_relationshiptype
 230
 231  Usage: my $is_relationshiptype = $self->get_is_relationship_type
 232  Desc:  find the database value of teh cvterm column is_relationship_type (integer 0,1)
 233  Property
 234  Side Effects:
 235  Example:
 236
 237 =cut
 238
 239 sub get_is_relationshiptype {
 240   my $self = shift;
 241   return $self->cvterm->is_relationship_type;
 242 }
 243
 244
 245
 246
 247 =head2 synonyms
 248
 249  Usage: my @synonyms = $self->synonyms()
 250  Desc:  Fetch all synonym names of a cvterm. use BCS cvterm->add_synonym and $cvterm->delete_synonym to manipulate cvtermsynonyms
 251  Ret:   an array of synonym strings
 252  Args:  none
 253  Side Effects: none
 254  Example:
 255
 256 =cut
 257
 258 sub synonyms {
 259     my $self = shift;
 260     my $cvterm = $self->cvterm;
 261     my $synonym_rs = $cvterm->cvtermsynonyms;
 262
 263     my @synonyms =() ;
 264     while ( my $s = $synonym_rs->next ) {
 265         push (@synonyms, $s->synonym)  ;
 266     }
 267     return @synonyms;
 268 }
 269
 270 =head2 get_single_synonym
 271
 272  Usage: my $single_synonym = $self->get_single_synonym;
 273  Desc: a method for fetching a single synonym, based on the synonym structure. This is ugly and it would be better if we used types and type ids
 274  Ret:  a single synonym
 275  Args: none
 276  Side Effects:
 277  Example:
 278
 279 =cut
 280
 281 sub get_single_synonym {
 282     my $self=shift;
 283     my $cvterm_id= $self->cvterm_id();
 284
 285     my $query=  "SELECT synonym FROM cvtermsynonym WHERE cvterm_id= ? AND synonym NOT LIKE '% %' AND synonym NOT LIKE '%\\_%' LIMIT 1";
 286     my $synonym_sth = $self->schema->storage->dbh->prepare($query);
 287     $synonym_sth->execute($cvterm_id);
 288
 289     my $single_synonym = $synonym_sth->fetchrow_array();
 290
 291     return $single_synonym;
 292 }
 293
 294
 295 =head2 secondary_dbxrefs
 296
 297  Usage: $self->secondary_dbxrefs
 298  Desc:  find all secondary accessions associated with the cvterm
 299         These are stored in cvterm_dbxref table
 300  Ret:   a list of full accession strings (PO:0001234)
 301  Args:  none
 302  Side Effects: none
 303  Example:
 304
 305 =cut
 306
 307 sub secondary_dbxrefs {
 308     my $self=shift;
 309     my $rs  =  $self->cvterm->search_related('cvterm_dbxrefs' , { is_for_definition => 0} );
 310     my @list;
 311     while (my $r = $rs->next) {
 312         push @list , $r->dbxref;
 313     }
 314     return @list;
 315 }
 316
 317
 318
 319
 320 =head2 def_dbxrefs
 321
 322  Usage: $self->def_dbxrefs
 323  Desc:  find all definition dbxrefs of the cvterm
 324         These are stored in cvterm_dbxref table
 325  Ret:   an array of dbxref objects
 326  Args:  none
 327  Side Effects: none
 328  Example:
 329
 330 =cut
 331
 332 sub def_dbxrefs {
 333     my $self=shift;
 334     my $cvterm = $self->cvterm;
 335     my @defs =  $cvterm->search_related('cvterm_dbxrefs' , { is_for_definition => 1} );
 336
 337     return @defs || undef ;
 338 }
 339
 340
 341 =head2 cvtermprops
 342
 343  Usage: $self->cvtermprops
 344  Desc:  find all cvtermprops (names and values) of the cvterm
 345         These are stored in cvtermprop table
 346  Ret:   hashref of arrays - key = cvtermprop type name, value = list of cvtermprop values of that type
 347  Args:  none
 348  Side Effects: none
 349  Example:
 350
 351 =cut
 352
 353 sub cvtermprops {
 354     my $self = shift;
 355     my $properties;
 356     my $cvtermprops = $self->cvterm->cvtermprops;
 357
 358     while ( my $prop =  $cvtermprops->next ) {
 359         push @{ $properties->{$prop->type->name } } ,   $prop->value ;
 360     }
 361     return $properties;
 362 }
 363
 364
 365 ########################################
 366 sub _retrieve_cvtermprop {
 367     my $self = shift;
 368     my $type = shift;
 369     my @results;
 370
 371     try {
 372         my $cvtermprop_type_id = SGN::Model::Cvterm->get_cvterm_row($self->schema, $type, 'trait_property')->cvterm_id();
 373         my $rs = $self->schema()->resultset("Cv::Cvtermprop")->search({ cvterm_id => $self->cvterm_id(), type_id => $cvtermprop_type_id }, { order_by => {-asc => 'cvtermprop_id'} });
 374
 375         while (my $r = $rs->next()){
 376             push @results, $r->value;
 377         }
 378     } catch {
 379         print STDERR "Cvterm $type does not exist in this database\n";
 380     };
 381
 382     my $res = join ',', @results;
 383     return $res;
 384 }
 385
 386 sub _remove_cvtermprop {
 387     my $self = shift;
 388     my $type = shift;
 389     my $value = shift;
 390     my $type_id = SGN::Model::Cvterm->get_cvterm_row($self->schema, $type, 'trait_property')->cvterm_id();
 391     my $rs = $self->schema()->resultset("Cv::Cvtermprop")->search( { type_id=>$type_id, cvterm_id => $self->cvterm_id(), value=>$value } );
 392
 393     if ($rs->count() == 1) {
 394         $rs->first->delete();
 395         return 1;
 396     }
 397     elsif ($rs->count() == 0) {
 398         return 0;
 399     }
 400     else {
 401         print STDERR "Error removing cvtermprop from cvterm ".$self->cvterm_id().". Please check this manually.\n";
 402         return 0;
 403     }
 404 }
 405
 406
 407 sub _store_cvtermprop {
 408     my $self = shift;
 409     my $type = shift;
 410     my $value = shift;
 411     my $cvtermprop = SGN::Model::Cvterm->get_cvterm_row($self->schema, $type, 'trait_property')->name();
 412     my $stored_cvtermprop = $self->cvterm->create_cvtermprops({ $cvtermprop => $value});
 413 }
 414
 415
 416
 417
 418 __PACKAGE__->meta->make_immutable;
 419
 420 ##########
 421 1;########
 422 ##########