lib/SGN.pm

   1
   2 =head1 NAME
   3
   4 SGN - Catalyst-based application to run the SGN website.
   5
   6 =head1 SYNOPSIS
   7
   8     script/sgn_server.pl
   9
  10 =head1 DESCRIPTION
  11
  12 This is the main class for the Sol Genomics Network main website.
  13
  14 =cut
  15
  16 package SGN;
  17 use Moose;
  18 use namespace::autoclean;
  19
  20 BEGIN {
  21     $ENV{WEB_PROJECT_NAME} = $ENV{PROJECT_NAME} = __PACKAGE__;
  22 }
  23
  24 use SGN::Exception;
  25
  26 use Catalyst::Runtime 5.80;
  27
  28 =head1 ROLES
  29
  30 Does the roles L<SGN::Role::Site::Config>,
  31 L<SGN::Role::Site::DBConnector>, L<SGN::Role::Site::DBIC>,
  32 L<SGN::Role::Site::Exceptions>, L<SGN::Role::Site::Files>,
  33 L<SGN::Role::Site::Mason>, L<SGN::Role::Site::SiteFeatures>,
  34 L<SGN::Role::Site::TestMode>
  35
  36 =cut
  37
  38 use Catalyst qw/
  39      ConfigLoader
  40      Static::Simple
  41      SmartURI
  42      Authentication
  43      +SGN::Authentication::Store
  44      Authorization::Roles
  45      +SGN::Role::Site::Config
  46      +SGN::Role::Site::DBConnector
  47      +SGN::Role::Site::DBIC
  48      +SGN::Role::Site::Exceptions
  49      +SGN::Role::Site::Files
  50      +SGN::Role::Site::Mason
  51      +SGN::Role::Site::SiteFeatures
  52      +SGN::Role::Site::TestMode
  53  /;
  54
  55 extends 'Catalyst';
  56
  57 =head1 METHODS
  58
  59 =cut
  60
  61 # configure catalyst-related things.  in general, things should not be
  62 # added here.  add them to SGN.conf, with comments.
  63 __PACKAGE__->config(
  64
  65     name => 'SGN',
  66     root => 'static',
  67
  68     disable_component_resolution_regex_fallback => 1,
  69
  70     default_view => 'Mason',
  71
  72     # Static::Simple configuration
  73     'Plugin::Static::Simple' => {
  74         dirs => [qw[ css s static img documents static_content data ]],
  75     },
  76
  77     'Plugin::ConfigLoader' => {
  78         substitutions => {
  79             UID       => sub { $> },
  80             USERNAME  => sub { (getpwuid($>))[0] },
  81             GID       => sub { $) },
  82             GROUPNAME => sub { (getgrgid($)))[0] },
  83            },
  84        },
  85
  86     # configure SGN::Role::Site::TestMode.  These are the
  87     # configuration keys that it will change so that they point into
  88     # t/data
  89     'Plugin::TestMode' => {
  90         test_data_dir => __PACKAGE__->path_to('t','data'),
  91         reroot_conf   =>
  92             [qw(
  93
  94                 blast_db_path
  95                 cluster_shared_tempdir
  96                 ftpsite_root
  97                 image_path
  98                 genefamily_dir
  99                 homepage_files_dir
 100                 intron_finder_database
 101                 solqtl
 102                 static_content_path
 103                 static_datasets_path
 104                 trace_path
 105
 106                )],
 107        },
 108
 109     'Plugin::Cache'=>{
 110         backend => {
 111             store =>"FastMmap",
 112         },
 113     },
 114
 115
 116
 117     'Plugin::Authentication' => {
 118         default_realm => 'default',
 119         realms => {
 120             default => {
 121                 credential => {
 122                     class => '+SGN::Authentication::Credentials',
 123                 },
 124
 125                 store => {
 126                     class => "+SGN::Authentication::Store",
 127                     user_class => "+SGN::Authentication::User",
 128 ###                 role_column => 'roles',
 129                 },
 130             },
 131         },
 132     },
 133
 134     ( $ENV{SGN_TEST_MODE} ? ( test_mode => 1 ) : () ),
 135 );
 136
 137
 138 # on startup, do some dynamic configuration
 139 after 'setup_finalize' => sub {
 140     my $self = shift;
 141
 142     $self->config->{basepath} = $self->config->{home};
 143
 144     # all files written by web server should be group-writable
 145     umask 000002;
 146
 147     # update the symlinks used to serve static files
 148     $self->_update_static_symlinks;
 149
 150     if(! $ENV{SGN_WEBPACK_WATCH}){
 151         my $uid = (lstat("js/package.json"))[4];
 152
 153
 154         my $user_exists = `id $uid 2>&1`;
 155     if ($user_exists =~ /no such user/) {
 156             `useradd -u $uid -m devel`;
 157         }
 158
 159         print STDERR "\n\nUSING USER ID $uid FOR npm...\n\n\n";
 160         system("cd js && sudo -u \\#$uid npm run build && cd -");
 161     }
 162 };
 163
 164 __PACKAGE__->setup;
 165
 166 sub _update_static_symlinks {
 167     my $self = shift;
 168
 169     # symlink the static_datasets and
 170     # static_content in the root dir so that
 171     # Catalyst::Plugin::Static::Simple can serve them.  in production,
 172     # these will be served directly by Apache
 173
 174     # make symlinks for static_content and static_datasets
 175     my @links =
 176         map [ $self->config->{$_.'_path'} =>
 177                $self->path_to( $self->config->{root}, $self->config->{$_.'_url'} )
 178             ],
 179         qw( static_content static_datasets );
 180
 181     for my $link (@links) {
 182         if( $self->debug ) {
 183             my $l1_rel = $link->[1]->relative( $self->path_to );
 184             $self->log->debug("symlinking static dir '$link->[0]' -> '$l1_rel'") if $self->debug;
 185         }
 186         unlink $link->[1];
 187         symlink( $link->[0], $link->[1] )
 188             or die "$! symlinking $link->[0] => $link->[1]";
 189     }
 190 }
 191
 192 =head1 SEE ALSO
 193
 194 L<SGN::Controller::Root>, L<Catalyst>
 195
 196 =head1 AUTHOR
 197
 198 The SGN team
 199
 200 =head1 LICENSE
 201
 202 This library is free software. You can redistribute it and/or modify
 203 it under the same terms as Perl itself.
 204
 205 =cut
 206
 207 1;