configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/projects/p/pidgin-sipe/r/mob/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([sys/sockio.h])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support [default=no]])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled [default=yes]])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Winit-self" \
 108                         "-Wmaybe-uninitialized" \
 109                         "-Wmissing-declarations" \
 110                         "-Wmissing-prototypes" \
 111                         "-Wnested-externs" \
 112                         "-Wpointer-arith" \
 113                         "-Wundef" \
 114                         "-Wunused-but-set-variable" \
 115          ; do
 116                  ac_save_CFLAGS=$CFLAGS
 117                  AC_MSG_CHECKING([if $CC supports $newflag])
 118                  CFLAGS="$QUALITY_CFLAGS $newflag"
 119                  AC_COMPILE_IFELSE(
 120                         [AC_LANG_SOURCE([[]])],
 121                         [AC_MSG_RESULT(yes)
 122                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 123                         [AC_MSG_RESULT(no)]
 124                  )
 125                  CFLAGS=$ac_save_CFLAGS
 126          done
 127         ])
 128 AC_SUBST(QUALITY_CFLAGS)
 129
 130 dnl Check for pkg-config before using it
 131 PKG_PROG_PKG_CONFIG
 132
 133 dnl check for valgrind (optional, only needed for debugging)
 134 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 135         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 136         [AC_MSG_RESULT(no)])
 137
 138 dnl build option: with voice & video support (for all backends)
 139 AC_ARG_WITH(vv,
 140         [AC_HELP_STRING([--with-vv],
 141                 [compile with voice and video support @<:@default=check@:>@])],
 142         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 143         [with_vv=check])
 144
 145 dnl check for Kerberos 5 support
 146 AC_ARG_WITH([krb5],
 147         [AC_HELP_STRING([--with-krb5],
 148                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 149         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 150         [with_krb5=check])
 151
 152 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 153       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 154         [AC_MSG_CHECKING(if Kerberos 5 is available)
 155          AS_IF([AC_RUN_LOG([krb5-config --version])],
 156                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 157                  KRB5_LDFLAGS=""
 158
 159                  dnl same as AC_CHECK_LIB()
 160                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 161                 [AC_MSG_RESULT(no)
 162                  with_krb5=no])],
 163       [                               dnl path specified by user
 164         KRB5_CFLAGS="-I${with_krb5}/include"
 165         KRB5_LDFLAGS="-L${with_krb5}/lib"
 166       ])
 167 AS_IF([test "x$with_krb5" != xno],
 168       [ac_save_CFLAGS="$CFLAGS"
 169        ac_save_LDFLAGS="$LDLAGS"
 170        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 171        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 172        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 173                         [],
 174                         [AC_ERROR([GSSAPI headers not found])])
 175        AC_CHECK_FUNC([gss_init_sec_context],
 176                      [],
 177                      [AC_ERROR([GSSAPI libraries not found])])
 178
 179        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 180        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 181                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 182                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 183                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 184                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 185
 186        CFLAGS="$ac_save_CFLAGS"
 187        LDFLAGS="$ac_save_LDFLAGS"
 188       ])
 189
 190 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 191 AC_SUBST(KRB5_CFLAGS)
 192 AC_SUBST(KRB5_LDFLAGS)
 193
 194 dnl check for glib
 195 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 196 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 197
 198 dnl check for gmime
 199 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 200 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 201         [ac_have_gmime=yes],
 202         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 203                 [ac_have_gmime=yes],
 204                 [ac_have_gmime=no])
 205 ])
 206 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 207 AS_IF([test "x$ac_have_gmime" = xyes],
 208         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 209
 210 dnl check for NSS
 211 PKG_CHECK_MODULES(NSS, [nss],
 212         [],
 213         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 214                 [],
 215                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 216                         [],
 217                         [AC_ERROR([nss, mozilla-nss or microb-engine-nss package is required])])
 218         ])
 219 ])
 220
 221 dnl check for libxml2
 222 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 223
 224 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 225 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 226 ac_save_CFLAGS=$CFLAGS
 227 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 228 dnl note the [[[ quoting: our code contains []!
 229 AC_RUN_IFELSE(
 230         [AC_LANG_PROGRAM(
 231                 [[
 232 #include <glib.h>
 233 #include <stdio.h>
 234
 235 /* Copied from uuid.c */
 236 typedef struct {
 237    guint32 time_low;
 238    guint16 time_mid;
 239    guint16 time_hi_and_version;
 240    guint8  clock_seq_hi_and_reserved;
 241    guint8  clock_seq_low;
 242    guint8  node[6];
 243 } uuid_t;
 244                 ]],
 245                 [[if (sizeof(uuid_t) == 16) {
 246                         return(0);
 247                  } else {
 248                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 249                         return(1);
 250                  }]])],
 251         [AC_MSG_RESULT(yes)],
 252         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 253
 254 Please notify the SIPE developers.
 255
 256 Copy & paste all lines starting with the line
 257
 258   checking that sizeof(uuid_t) is 16...
 259
 260 to the report and attach the file "config.log".
 261
 262 Compiler information:
 263
 264  host:     $host
 265  build:    $build
 266  compiler: $CC
 267 ])],
 268         [AC_MSG_WARN([cross compiling: not checking])])
 269 CFLAGS=$ac_save_CFLAGS
 270
 271 dnl build option: OCS2005 client hack
 272 AC_ARG_ENABLE([ocs2005-message-hack],
 273         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 274                                                           which causes "false" not delivered error messages
 275                                                           @<:@default=no@:>@])],
 276         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 277                    [Define to 1 to disable SIP MESSAGE timeout feature.
 278                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 279                     disabling the timeout suppresses "false" error messages])])
 280
 281 dnl build option: purple backend
 282 AC_ARG_ENABLE([purple],
 283         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 284         [],
 285         [enable_purple=yes])
 286 with_purple_vv=no
 287 AS_IF([test "x$enable_purple" != xno],
 288         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 289                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 290                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 291                  AC_SUBST(PURPLE_MAJOR_VERSION)
 292
 293                  dnl let user now if he has a 32- and 64-bit header conflict...
 294                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 295                  ac_save_CFLAGS=$CFLAGS
 296                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 297                  AC_COMPILE_IFELSE(
 298                         [AC_LANG_PROGRAM([[
 299 #include <unistd.h>
 300 #include <glib.h>
 301 #include <cipher.h>
 302 #include <version.h>
 303
 304 /* Compile some code that has caused trouble in the past */
 305 static void testfunc(unsigned long len)
 306 {
 307   PurpleCipherContext *rc4 = NULL;
 308   guchar *plaintext = NULL;
 309   gsize plaintext_length = 0;
 310   guchar *encrypted_text = NULL;
 311   gsize dummy = 0;
 312   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 313   purple_cipher_context_encrypt(rc4, plaintext, plaintext_length,
 314                                 encrypted_text,
 315 #if PURPLE_VERSION_CHECK(3,0,0)
 316                                 dummy);
 317 #else
 318                                 &dummy);
 319 #endif
 320 }
 321                                         ]],
 322                                         [[testfunc(16);]])],
 323                         [AC_MSG_RESULT(none)],
 324                         [AC_MSG_FAILURE([conflicts found.
 325
 326 Check that you have the correct glib/libpurple headers installed for
 327 your architecture or set GLIB_CFLAGS/PURPLE_CFLAGS to override the
 328 system defaults.
 329 ])
 330                         ])
 331
 332                  dnl on windows
 333                  dnl test program needs to be in the same location as libpurple
 334                  dnl installation for latter to load ssl plugin referenced by
 335                  dnl RELATIVE path.
 336                  AS_IF([test "x${os_win32}" != xyes],
 337                         [dnl purple SSL support is mandatory
 338                          AC_MSG_CHECKING([for purple SSL support])
 339                          ac_save_LIBS=$LIBS
 340                          LIBS="$PURPLE_LIBS"
 341                          AC_RUN_IFELSE(
 342                                 [AC_LANG_PROGRAM([[
 343 #include <glib.h>
 344 #include <plugin.h>
 345 #include <sslconn.h>
 346                                                 ]],
 347                                                 [[
 348         purple_plugins_init();
 349         purple_plugins_probe(G_MODULE_SUFFIX);
 350         purple_ssl_init();
 351         return(purple_ssl_is_supported()?0:1);
 352                                                 ]])],
 353                                 [AC_MSG_RESULT(ok)],
 354                                 [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 355 ])
 356                                 ],
 357                                 [AC_MSG_WARN([cross compiling: not checking])])
 358                  ])
 359
 360                  dnl check whether enable voice and video support
 361                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 362                        [test "x$with_vv" = xcheck],  dnl autodetect
 363                          [AC_MSG_CHECKING(for purple voice and video support)
 364                           AC_RUN_IFELSE(
 365                                 [AC_LANG_PROGRAM([[
 366 #include <media.h>
 367                                         ]],
 368                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 369                                 )],
 370                                 [AC_MSG_RESULT(ok)
 371                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 372                                         dnl sipe-media.c uses g_slist_free_full()
 373                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [purple >= 2.8.0],
 374                                                 [PKG_CHECK_MODULES(GSTREAMER, [gstreamer-0.10],
 375                                                         [with_purple_vv=yes],
 376                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 377                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 378                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 379                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 380                                 [AC_MSG_WARN([cross compiling: not checking])])
 381                          ])
 382
 383                  dnl check if we have TCP media transport patches in libpurple
 384                  AS_IF([test "x$with_purple_vv" != xno],
 385                         [
 386                          AC_MSG_CHECKING(for TCP media transport)
 387                          AC_COMPILE_IFELSE(
 388                                 [AC_LANG_PROGRAM([[#include <media.h>]],[[return PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_ACTIVE]])],
 389                                 [
 390                                  with_purple_tcp=yes
 391                                  AC_DEFINE(HAVE_ICE_TCP, 1, [Define if we have support for TCP media transport.])
 392                                  AC_MSG_RESULT(yes)
 393                                 ],
 394                                 [AC_MSG_RESULT(no)]
 395                          )
 396                         ])
 397
 398                  CFLAGS=$ac_save_CFLAGS
 399                  LIBS=$ac_save_LIBS],
 400                 [enable_purple=no])])
 401 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 402
 403 dnl build option: telepathy backend
 404 AC_ARG_ENABLE([telepathy],
 405         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 406         [],
 407         [enable_telepathy=yes])
 408 AS_IF([test "x$enable_telepathy" != xno],
 409         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 410                 [dnl GMIME is a build requirement
 411                  AS_IF([test "x$ac_have_gmime" = xyes],
 412                         [],
 413                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 414
 415                  dnl telepathy is based on GObject & D-Bus GLib
 416                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 417                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 418
 419                  dnl telepathy uses from gio:
 420                  dnl  - GIOStream      (>= 2.22.0)
 421                  dnl  - GResolver      (>= 2.22.0)
 422                  dnl  - GSocketClient  (>= 2.32.0)
 423                  dnl  - GTlsConnection (>= 2.28.0)
 424                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 425
 426                 ],
 427                 [enable_telepathy=no])])
 428 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 429
 430 dnl sanity check
 431 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 432         [AC_ERROR(at least one plugin must be selected
 433
 434 If you didn't use a --enable option then please check that you have
 435 the headers for the packages "purple" or "telepathy-glib" installed.
 436 )],
 437         [])
 438
 439 dnl enable voice & video support if any backend supports it
 440 AS_IF([test "x$with_purple_vv" != xno],
 441         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 442 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 443
 444 dnl these code parts rely on interfaces that require GValueArray. This
 445 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 446 dnl is no backward compatible replacement implementation possible
 447 AS_IF([test "x$with_purple_vv" != xno -o "x$enable_telepathy" != xno],
 448         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 449                    [We need GValueArray for which no replacement is available])])
 450
 451 dnl i18n
 452 AC_MSG_CHECKING([locale_CPPFLAGS])
 453 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 454 AC_SUBST([LOCALE_CPPFLAGS])
 455 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 456 AM_GLIB_GNU_GETTEXT
 457 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 458
 459 dnl codeset
 460 AM_LANGINFO_CODESET
 461
 462 dnl substitutions and generated files
 463 AC_CONFIG_HEADERS([config.h])
 464 AC_CONFIG_FILES([
 465         Makefile
 466         pixmaps/Makefile
 467         m4macros/Makefile
 468         po/Makefile.in
 469         pixmaps/16/Makefile
 470         pixmaps/22/Makefile
 471         pixmaps/24/Makefile
 472         pixmaps/32/Makefile
 473         pixmaps/48/Makefile
 474         pixmaps/scalable/Makefile
 475         src/Makefile
 476         src/core/Makefile
 477         src/api/Makefile
 478         src/purple/Makefile
 479         src/telepathy/Makefile
 480         src/telepathy/data/Makefile
 481         ])
 482
 483 dnl generate files
 484 AC_OUTPUT()
 485
 486 dnl additional info for the user
 487 AS_ECHO()
 488 AS_IF([test "x$enable_purple" = xno],
 489         [AS_ECHO("Not building purple plugin")],
 490         [AS_ECHO("Build purple plugin")
 491          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 492          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 493          AS_ECHO_N("Voice and video: ")
 494          AS_IF([test "x$with_purple_vv" = xno],
 495           [AS_ECHO("disabled")],
 496           [
 497            AS_ECHO_N("enabled")
 498            AS_IF([test "x$with_purple_tcp" = xyes], [AS_ECHO_N(" with TCP transport")])
 499            AS_ECHO()
 500           ])
 501         ])
 502 AS_ECHO()
 503 AS_IF([test "x$enable_telepathy" = xno],
 504         [AS_ECHO("Not building telepathy plugin")],
 505         [AS_ECHO("Build telepathy plugin")
 506          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 507          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 508 AS_ECHO()
 509 AS_IF([test "x$with_krb5" = xno],
 510         [AS_ECHO("Not building with Kerberos 5 support")],
 511         [AS_ECHO("Build with Kerberos 5 support")
 512          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 513          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 514 AS_ECHO()
 515 AS_IF([test "x$enable_debug" = xno],
 516         [AS_ECHO("Debugging not enabled")],
 517         [AS_ECHO("Build with debugging enabled")
 518          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 519 AS_ECHO()
 520 AS_IF([test "x$QUALITY_CFLAGS" = x],
 521         [AS_ECHO("Compiler checks disabled")],
 522         [AS_ECHO("Build with compiler checks enabled")
 523          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 524 AS_ECHO()
 525 AS_ECHO("configure complete. Now run 'make'")
 526 AS_ECHO()
 527
 528 dnl The End.