configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Wduplicate-decl-specifier" \
 108                         "-Winit-self" \
 109                         "-Wmaybe-uninitialized" \
 110                         "-Wmissing-declarations" \
 111                         "-Wmissing-prototypes" \
 112                         "-Wnested-externs" \
 113                         "-Wpointer-arith" \
 114                         "-Wundef" \
 115                         "-Wunused-but-set-variable" \
 116          ; do
 117                  ac_save_CFLAGS="$CFLAGS"
 118                  AC_MSG_CHECKING([if $CC supports $newflag])
 119                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 120                  AC_COMPILE_IFELSE(
 121                         [AC_LANG_SOURCE([[]])],
 122                         [AC_MSG_RESULT(yes)
 123                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 124                         [AC_MSG_RESULT(no)]
 125                  )
 126                  CFLAGS="$ac_save_CFLAGS"
 127          done
 128         ])
 129 AC_SUBST(QUALITY_CFLAGS)
 130
 131 dnl check for availability of addition linker flags
 132 for newflag in \
 133         "-Wl,-Bsymbolic-functions" \
 134 ; do
 135         ac_save_LDFLAGS="$LDFLAGS"
 136         AC_MSG_CHECKING([if $CC supports $newflag])
 137         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 138         AC_LINK_IFELSE(
 139                 [AC_LANG_SOURCE([[
 140 int main(int argc, char *argv[])
 141 {
 142         return(0);
 143 }
 144                  ]])],
 145                 [AC_MSG_RESULT(yes)
 146                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 147                 [AC_MSG_RESULT(no)]
 148         )
 149         LDFLAGS="$ac_save_LDFLAGS"
 150 done
 151 AC_SUBST(ADDITIONAL_LDFLAGS)
 152
 153 dnl Check for pkg-config before using it
 154 PKG_PROG_PKG_CONFIG
 155
 156 dnl check for valgrind (optional, only needed for debugging)
 157 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 158         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 159         [AC_MSG_RESULT(no)])
 160
 161 dnl build option: with voice & video support (for all backends)
 162 AC_ARG_WITH(vv,
 163         [AC_HELP_STRING([--with-vv],
 164                 [compile with voice and video support @<:@default=check@:>@])],
 165         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 166         [with_vv=check])
 167
 168 dnl check for Kerberos 5 support
 169 AC_ARG_WITH([krb5],
 170         [AC_HELP_STRING([--with-krb5],
 171                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 172         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 173         [with_krb5=check])
 174
 175 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 176       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 177         [AC_MSG_CHECKING(if Kerberos 5 is available)
 178          AS_IF([AC_RUN_LOG([krb5-config --version])],
 179                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 180                  KRB5_LDFLAGS=""
 181
 182                  dnl same as AC_CHECK_LIB()
 183                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 184                 [AC_MSG_RESULT(no)
 185                  with_krb5=no])],
 186       [                               dnl path specified by user
 187         KRB5_CFLAGS="-I${with_krb5}/include"
 188         KRB5_LDFLAGS="-L${with_krb5}/lib"
 189       ])
 190 AS_IF([test "x$with_krb5" != xno],
 191       [ac_save_CFLAGS="$CFLAGS"
 192        ac_save_LDFLAGS="$LDFLAGS"
 193        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 194        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 195        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 196                         [],
 197                         [AC_ERROR([GSSAPI headers not found])])
 198        AC_CHECK_FUNC([gss_init_sec_context],
 199                      [],
 200                      [AC_ERROR([GSSAPI libraries not found])])
 201
 202        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 203        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 204                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 205                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 206                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 207                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 208
 209        CFLAGS="$ac_save_CFLAGS"
 210        LDFLAGS="$ac_save_LDFLAGS"
 211       ])
 212
 213 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 214 AC_SUBST(KRB5_CFLAGS)
 215 AC_SUBST(KRB5_LDFLAGS)
 216
 217 dnl check for DBUS support
 218 AC_ARG_WITH([dbus],
 219         [AC_HELP_STRING([--with-dbus],
 220                 [compile with D-BUS support @<:@default=check@:>@])],
 221         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
 222         [with_dbus=check])
 223
 224 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
 225       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
 226         [PKG_CHECK_MODULES(DBUS, [dbus-1],
 227                 [with_dbus=yes],
 228                 [with_dbus=no])
 229         ])
 230 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
 231 AS_IF([test "x$with_dbus" = xyes],
 232         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
 233
 234 AC_ARG_ENABLE(gssapi_only,
 235         [AS_HELP_STRING([--enable-gssapi-only],
 236                         [disable all internal authentication code and only use
 237                          GSSAPI for authentication @<:@default=yes@:>@])],
 238         [],
 239         dnl requires Kerberos which provides GSSAPI
 240         [enable_gssapi_only=$with_krb5])
 241 AS_IF([test "x$enable_gssapi_only" != xno],
 242         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 243                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 244                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 245                         enable_gssapi_only=no])
 246         ])
 247 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 248
 249 dnl check for glib
 250 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.18.0])
 251 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.18.0])
 252
 253 dnl check for gmime
 254 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
 255         [ac_have_gmime=yes],
 256         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.6.0],
 257                 [ac_have_gmime=yes],
 258                 [ac_have_gmime=no])
 259         ])
 260 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 261 AS_IF([test "x$ac_have_gmime" = xyes],
 262         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 263
 264 dnl check for NSS
 265 AC_ARG_ENABLE(nss,
 266         [AS_HELP_STRING([--enable-nss],
 267                         [use NSS as crypto backend @<:@default=yes@:>@])],
 268         [],
 269         [enable_nss=yes])
 270 AS_IF([test "x$enable_nss" != xno],
 271         [PKG_CHECK_MODULES(NSS, [nss],
 272                 [],
 273                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 274                         [],
 275                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 276                                 [],
 277                                 [enable_nss=no])
 278                         ])
 279                 ])
 280         ])
 281
 282 dnl check for OpenSSL
 283 AC_ARG_ENABLE(openssl,
 284         [AS_HELP_STRING([--enable-openssl],
 285                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 286         [],
 287         [enable_openssl=yes])
 288 AS_IF([test "x$enable_openssl" != xno],
 289         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 290                    [],
 291                    [enable_openssl=no])
 292         ])
 293 AS_IF(
 294         [test "x$enable_nss" != xno],
 295                 [ dnl NSS has priority over OpenSSL
 296                   enable_openssl=no
 297                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 298         [test "x$enable_openssl" != xno],
 299                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 300         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 301 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 302
 303 dnl check for libxml2
 304 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 305
 306 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 307 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 308 ac_save_CFLAGS="$CFLAGS"
 309 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 310 dnl note the [[[ quoting: our code contains []!
 311 AC_RUN_IFELSE(
 312         [AC_LANG_PROGRAM(
 313                 [[
 314 #include <glib.h>
 315 #include <stdio.h>
 316
 317 /* Copied from uuid.c */
 318 typedef struct {
 319    guint32 time_low;
 320    guint16 time_mid;
 321    guint16 time_hi_and_version;
 322    guint8  clock_seq_hi_and_reserved;
 323    guint8  clock_seq_low;
 324    guint8  node[6];
 325 } uuid_t;
 326                 ]],
 327                 [[if (sizeof(uuid_t) == 16) {
 328                         return(0);
 329                  } else {
 330                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 331                         return(1);
 332                  }]])],
 333         [AC_MSG_RESULT(yes)],
 334         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 335
 336 Please notify the SIPE developers.
 337
 338 Copy & paste all lines starting with the line
 339
 340   checking that sizeof(uuid_t) is 16...
 341
 342 to the report and attach the file "config.log".
 343
 344 Compiler information:
 345
 346  host:     $host
 347  build:    $build
 348  compiler: $CC
 349 ])],
 350         [AC_MSG_WARN([cross compiling: not checking])])
 351 CFLAGS="$ac_save_CFLAGS"
 352
 353 dnl build option: OCS2005 client hack
 354 AC_ARG_ENABLE([ocs2005-message-hack],
 355         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 356                                                           which causes "false" not delivered error messages
 357                                                           @<:@default=no@:>@])],
 358         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 359                    [Define to 1 to disable SIP MESSAGE timeout feature.
 360                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 361                     disabling the timeout suppresses "false" error messages])])
 362
 363 dnl build option: purple backend
 364 AC_ARG_ENABLE([purple],
 365         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 366         [],
 367         [enable_purple=yes])
 368 ac_have_appshare=no
 369 ac_have_xdata=no
 370 with_purple_vv=no
 371 AS_IF([test "x$enable_purple" != xno],
 372         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 373                 [purple_pkgconfig=purple-3],
 374                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.7.0],
 375                         [purple_pkgconfig=purple],
 376                         [enable_purple=no])])
 377
 378          AS_IF([test "x$enable_purple" != xno],
 379                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 380
 381                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 382                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 383                  AC_SUBST(PURPLE_MAJOR_VERSION)
 384
 385                  ac_save_CFLAGS="$CFLAGS"
 386                  ac_save_LIBS="$LIBS"
 387                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 388                  LIBS="$LIBS $PURPLE_LIBS"
 389
 390                  dnl check whether enable voice and video support
 391                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 392                        [AC_MSG_CHECKING(for purple voice and video support)
 393                         purple_has_media=no
 394                         AC_RUN_IFELSE(
 395                                 [AC_LANG_PROGRAM([[
 396 #include <media.h>
 397                                         ]],
 398                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 399                                 )],
 400                                 [purple_has_media=yes
 401                                  AC_MSG_RESULT(ok)
 402                                 ],
 403                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 404                                 [AS_IF([test "x$with_vv" = xyes],
 405                                        [purple_has_media=yes
 406                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 407                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 408                                 ]
 409                         )
 410                         AS_IF([test "x$purple_has_media" = xyes],
 411                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 412                                         dnl sipe-media.c uses g_slist_free_full()
 413                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 414                                                 dnl check purple pkgconfig for gstreamer version
 415                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 416                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 417                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 418                                                                 [gstreamer_pkgconfig=1.0])])
 419                                                 AS_IF([test "x$gstreamer_pkgconfig" == x1.0],
 420                                                         [gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 421
 422                                                         AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 423                                                         PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 424                                                                 [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 425                                                                         [with_purple_vv=yes
 426
 427                                                                          AC_COMPILE_IFELSE(
 428                                                                                  [AC_LANG_PROGRAM([[
 429 #include <media.h>
 430                                                                                         ]],
 431                                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 432                                                                                  )],
 433                                                                                  [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 434                                                                         )],
 435                                                                         [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 436                                                                 [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 437                                                         [AC_MSG_NOTICE(your purple hasn't been compiled against GStreamer 1.0: disabling purple voice and video support)])],
 438                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 439                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 440                                 ])
 441                        ])
 442
 443                  dnl SRTP and XDATA require media backend
 444                  AS_IF([test "x$with_purple_vv" != xno],
 445                         [AC_LINK_IFELSE(
 446                                 [AC_LANG_PROGRAM([[
 447 #include <media.h>
 448                                         ]],
 449                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 450                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 451                                  )],
 452                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 453                          )
 454
 455                          AC_COMPILE_IFELSE(
 456                                 [AC_LANG_PROGRAM([[
 457 #include <media.h>
 458                                         ]],
 459                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 460                                  )],
 461                                  [dnl libpurple supports raw data RTP connections
 462                                   ac_have_xdata=yes
 463
 464                                   dnl gio-2.0 is mandatory for application sharing support
 465                                   PKG_CHECK_MODULES(GIO, [gio-2.0], [ac_have_appshare=yes])
 466                                  ]
 467                          )
 468                         ],
 469                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 470                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 471                          )]
 472                  )
 473
 474                  CFLAGS="$ac_save_CFLAGS"
 475                  LIBS="$ac_save_LIBS"])])
 476 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 477 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 478
 479 dnl build option: telepathy backend
 480 AC_ARG_ENABLE([telepathy],
 481         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 482         [],
 483         [enable_telepathy=yes])
 484 AS_IF([test "x$enable_telepathy" != xno],
 485         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 486                 [dnl GMIME is a build requirement
 487                  AS_IF([test "x$ac_have_gmime" = xyes],
 488                         [],
 489                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 490
 491                  dnl telepathy is based on GObject & D-Bus GLib
 492                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 493                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 494
 495                  dnl telepathy uses from gio:
 496                  dnl  - GIOStream      (>= 2.22.0)
 497                  dnl  - GResolver      (>= 2.22.0)
 498                  dnl  - GSocketClient  (>= 2.32.0)
 499                  dnl  - GTlsConnection (>= 2.28.0)
 500                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 501
 502                 ],
 503                 [enable_telepathy=no])])
 504 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 505
 506 dnl sanity check
 507 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 508         [AC_ERROR(at least one plugin must be selected
 509
 510 If you didn't use a --enable option then please check that you have
 511 the headers for the packages "purple" or "telepathy-glib" installed.
 512 )],
 513         [])
 514
 515 dnl enable voice & video support if any backend supports it
 516 AS_IF([test "x$with_purple_vv" != xno],
 517         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 518 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 519
 520 dnl raw data RTP streams enable Lync file transfer
 521 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 522 AS_IF([test "x$ac_have_xdata" == xyes],
 523         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 524
 525 dnl enable appshare support
 526 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 527 AS_IF([test "x$ac_have_appshare" == xyes],
 528         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 529
 530 dnl telepathy code parts rely on interfaces that require GValueArray. This
 531 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 532 dnl is no backward compatible replacement implementation possible
 533 AS_IF([test "x$enable_telepathy" != xno],
 534         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 535                    [We need GValueArray for which no replacement is available])])
 536
 537 dnl i18n
 538 AC_MSG_CHECKING([locale_CPPFLAGS])
 539 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 540 AC_SUBST([LOCALE_CPPFLAGS])
 541 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 542 AM_GLIB_GNU_GETTEXT
 543 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 544
 545 dnl codeset
 546 AM_LANGINFO_CODESET
 547
 548 dnl substitutions and generated files
 549 AC_CONFIG_HEADERS([config.h])
 550 AC_CONFIG_FILES([
 551         Makefile
 552         pixmaps/Makefile
 553         m4macros/Makefile
 554         po/Makefile.in
 555         pixmaps/16/Makefile
 556         pixmaps/22/Makefile
 557         pixmaps/24/Makefile
 558         pixmaps/32/Makefile
 559         pixmaps/48/Makefile
 560         pixmaps/scalable/Makefile
 561         src/Makefile
 562         src/core/Makefile
 563         src/api/Makefile
 564         src/purple/Makefile
 565         src/telepathy/Makefile
 566         src/telepathy/data/Makefile
 567         ])
 568
 569 dnl generate files
 570 AC_OUTPUT()
 571
 572 dnl additional info for the user
 573 AS_ECHO()
 574 AS_IF([test "x$enable_purple" = xno],
 575         [AS_ECHO("Not building purple plugin")],
 576         [AS_ECHO("Build purple plugin")
 577          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 578          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 579          AS_ECHO_N("Voice and video: ")
 580          AS_IF([test "x$with_purple_vv" = xno],
 581           [AS_ECHO("disabled")],
 582           [AS_ECHO("enabled")])
 583         ])
 584 AS_ECHO()
 585 AS_IF([test "x$enable_telepathy" = xno],
 586         [AS_ECHO("Not building telepathy plugin")],
 587         [AS_ECHO("Build telepathy plugin")
 588          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 589          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 590 AS_ECHO()
 591 AS_IF([test "x$with_krb5" = xno],
 592         [AS_ECHO("Not building with Kerberos 5 support")],
 593         [AS_ECHO("Build with Kerberos 5 support")
 594          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 595          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 596 AS_ECHO()
 597 AS_IF([test "x$enable_gssapi_only" = xno],
 598         [AS_ECHO("Using internal authentication implementation")],
 599         [AS_ECHO("Using only GSSAPI for authentication")])
 600 AS_ECHO()
 601 AS_IF([test "x$enable_debug" = xno],
 602         [AS_ECHO("Debugging not enabled")],
 603         [AS_ECHO("Build with debugging enabled")
 604          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 605 AS_ECHO()
 606 AS_IF([test "x$QUALITY_CFLAGS" = x],
 607         [AS_ECHO("Compiler checks disabled")],
 608         [AS_ECHO("Build with compiler checks enabled")
 609          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 610 AS_ECHO()
 611 AS_ECHO("configure complete. Now run 'make'")
 612 AS_ECHO()
 613
 614 dnl The End.