configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.69])
   3
   4 AC_CONFIG_MACRO_DIRS([m4])
   5
   6 dnl Use 'VERSION' files to get version.
   7 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   8
   9 dnl Strip off newline characters.
  10 m4_define([SIPE_VERSION],
  11         m4_substr(SIPE_VERSION_DATA,
  12                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  13
  14 dnl homepage
  15 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  16
  17 dnl initialize package name, version, bugtracker & homepage
  18 AC_INIT([pidgin-sipe], SIPE_VERSION,
  19         [https://sourceforge.net/p/sipe/bugs/], [],
  20         SIPE_HOMEPAGE)
  21
  22 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  23         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  24         [URL for submitting translations.])
  25
  26 dnl define optional git commit ID generated by autogen.sh
  27 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  28 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  29         [AC_MSG_NOTICE([set git commit])
  30          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  31 ])
  32
  33 dnl setup automake and require recent enough version
  34 AM_INIT_AUTOMAKE([1.16 dist-bzip2 dist-xz no-define tar-ustar])
  35
  36 AC_CANONICAL_HOST
  37
  38 dnl set PACKAGE_URL for autoconf < 2.64
  39 AS_IF([test "x${PACKAGE_URL}" = x],
  40         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  41          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  42 ])
  43
  44 dnl set programming language
  45 AC_LANG(C)
  46 AM_PROG_CC_C_O
  47 AM_PROG_LEX
  48 AC_HEADER_STDC
  49
  50 dnl setup shared library generation
  51 LT_INIT([disable-static])
  52
  53 dnl checks for tools
  54 IT_PROG_INTLTOOL([0.41.0])
  55 AC_PROG_INSTALL
  56
  57 dnl ******************************
  58 dnl Win32
  59 dnl ******************************
  60 AC_MSG_CHECKING([for Win32])
  61 AS_CASE(["$host"],
  62                 [*-mingw*], [os_win32=yes],
  63                 [os_win32=no])
  64 AC_MSG_RESULT([$os_win32])
  65 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  66
  67 dnl checks for header files
  68 AC_CHECK_HEADERS([])
  69
  70 dnl checks for library functions
  71 AC_CHECK_FUNCS([])
  72
  73 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  74 dnl as that is likely where libpurple will be found if it is not in the default
  75 dnl pkgconfig path
  76 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  77 export PKG_CONFIG_PATH
  78
  79 dnl debug mode
  80 AC_ARG_ENABLE(debug,
  81         [AS_HELP_STRING([--enable-debug],
  82                         [compile with debugging support @<:@default=no@:>@])],
  83         [],
  84         [enable_debug=no])
  85
  86 AS_IF([test "x$enable_debug" = xyes],
  87         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  88 AC_SUBST(DEBUG_CFLAGS)
  89
  90 dnl quality check mode
  91 dnl For people who are interested in finding bugs and not hiding them
  92 AC_ARG_ENABLE(quality-check,
  93         [AS_HELP_STRING([--enable-quality-check],
  94                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  95         [],
  96         [enable_quality_check=yes])
  97
  98 AS_IF([test "x$enable_quality_check" = xyes],
  99         [dnl default quality configuration
 100          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
 101
 102          dnl enable warnings supported by the GCC on the build system
 103          for newflag in \
 104                         "-Wextra" \
 105                         "-Waggregate-return" \
 106                         "-Wcast-align" \
 107                         "-Wcast-function-type" \
 108                         "-Wdeclaration-after-statement" \
 109                         "-Wdeprecated-declarations" \
 110                         "-Wduplicate-decl-specifier" \
 111                         "-Winit-self" \
 112                         "-Wmaybe-uninitialized" \
 113                         "-Wmissing-declarations" \
 114                         "-Wmissing-prototypes" \
 115                         "-Wnested-externs" \
 116                         "-Wpointer-arith" \
 117                         "-Wundef" \
 118                         "-Wunused-but-set-variable" \
 119          ; do
 120                  ac_save_CFLAGS="$CFLAGS"
 121                  AC_MSG_CHECKING([if $CC supports $newflag])
 122                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 123                  AC_COMPILE_IFELSE(
 124                         [AC_LANG_SOURCE([[]])],
 125                         [AC_MSG_RESULT(yes)
 126                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 127                         [AC_MSG_RESULT(no)]
 128                  )
 129                  CFLAGS="$ac_save_CFLAGS"
 130          done
 131         ])
 132 AC_SUBST(QUALITY_CFLAGS)
 133
 134 dnl check for availability of addition linker flags
 135 for newflag in \
 136         "-Wl,-Bsymbolic-functions" \
 137 ; do
 138         ac_save_LDFLAGS="$LDFLAGS"
 139         AC_MSG_CHECKING([if $CC supports $newflag])
 140         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 141         AC_LINK_IFELSE(
 142                 [AC_LANG_SOURCE([[
 143 int main(int argc, char *argv[])
 144 {
 145         return(0);
 146 }
 147                  ]])],
 148                 [AC_MSG_RESULT(yes)
 149                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 150                 [AC_MSG_RESULT(no)]
 151         )
 152         LDFLAGS="$ac_save_LDFLAGS"
 153 done
 154 AC_SUBST(ADDITIONAL_LDFLAGS)
 155
 156 dnl Check for pkg-config before using it
 157 PKG_PROG_PKG_CONFIG
 158
 159 dnl check for valgrind (optional, only needed for debugging)
 160 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 161         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 162         [AC_MSG_RESULT(no)])
 163
 164 dnl build option: with AppStream support
 165 AC_ARG_WITH(appstream,
 166         [AC_HELP_STRING([--with-appstream],
 167                 [install AppStream XML file @<:@default=yes@:>@])],
 168         [AS_IF([test "x$withval" = xno], [with_appstream=no])],
 169         [with_appstream=yes])
 170 AM_CONDITIONAL(SIPE_WITH_APPSTREAM, [test "x$with_appstream" != xno])
 171
 172 dnl build option: with voice & video support (for all backends)
 173 AC_ARG_WITH(vv,
 174         [AC_HELP_STRING([--with-vv],
 175                 [compile with voice and video support @<:@default=check@:>@])],
 176         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 177         [with_vv=check])
 178
 179 dnl check for Kerberos 5 support
 180 AC_ARG_WITH([krb5],
 181         [AC_HELP_STRING([--with-krb5],
 182                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 183         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 184         [with_krb5=check])
 185
 186 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 187       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 188         [AC_MSG_CHECKING(if Kerberos 5 is available)
 189          AS_IF([AC_RUN_LOG([krb5-config --version])],
 190                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 191                  KRB5_LDFLAGS=""
 192
 193                  dnl same as AC_CHECK_LIB()
 194                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 195                 [AC_MSG_RESULT(no)
 196                  with_krb5=no])],
 197       [                               dnl path specified by user
 198         KRB5_CFLAGS="-I${with_krb5}/include"
 199         KRB5_LDFLAGS="-L${with_krb5}/lib"
 200       ])
 201 AS_IF([test "x$with_krb5" != xno],
 202       [ac_save_CFLAGS="$CFLAGS"
 203        ac_save_LDFLAGS="$LDFLAGS"
 204        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 205        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 206        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 207                         [],
 208                         [AC_ERROR([GSSAPI headers not found])])
 209        AC_CHECK_FUNC([gss_init_sec_context],
 210                      [],
 211                      [AC_ERROR([GSSAPI libraries not found])])
 212
 213        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 214        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 215                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 216                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 217                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 218                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 219
 220        CFLAGS="$ac_save_CFLAGS"
 221        LDFLAGS="$ac_save_LDFLAGS"
 222       ])
 223
 224 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 225 AC_SUBST(KRB5_CFLAGS)
 226 AC_SUBST(KRB5_LDFLAGS)
 227
 228 dnl check for DBUS support
 229 AC_ARG_WITH([dbus],
 230         [AC_HELP_STRING([--with-dbus],
 231                 [compile with D-BUS support @<:@default=check@:>@])],
 232         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
 233         [with_dbus=check])
 234
 235 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
 236       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
 237         [PKG_CHECK_MODULES(DBUS, [dbus-1],
 238                 [with_dbus=yes],
 239                 [with_dbus=no])
 240         ])
 241 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
 242 AS_IF([test "x$with_dbus" = xyes],
 243         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
 244
 245 AC_ARG_ENABLE(gssapi_only,
 246         [AS_HELP_STRING([--enable-gssapi-only],
 247                         [disable all internal authentication code and only use
 248                          GSSAPI for authentication @<:@default=yes@:>@])],
 249         [],
 250         dnl requires Kerberos which provides GSSAPI
 251         [enable_gssapi_only=$with_krb5])
 252 AS_IF([test "x$enable_gssapi_only" != xno],
 253         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 254                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 255                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 256                         enable_gssapi_only=no])
 257         ])
 258 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 259
 260 dnl
 261 dnl oldest supported LTS release vs. package versions
 262 dnl
 263 dnl last checked: Jun-2019
 264 dnl
 265 dnl package        | Debian  | RHEL    | SLES    | Ubuntu  | win32  |
 266 dnl                | 8.0     | 6.10    | 12 SP4  | 16.04   | 2.13.x |
 267 dnl            EOL | 07/2020 | 12/2020 | 11/2024 | 04/2021 |    N/A |
 268 dnl ---------------|---------|---------|---------|---------|--------|
 269 dnl glib-2.0       |  2.42.x |  2.28.x |  2.48.x |  2.48.x | 2.18.x |
 270 dnl gmime-2.6      |     YES |      NO |     YES |     YES |     NO |
 271 dnl gss-ntlmssp    |      NO |      NO |      NO |   0.7.x |    N/A |
 272 dnl intltool       |  0.50.2 |  0.41.0 |  0.51.0 |  0.51.0 | 0.40.4 |
 273 dnl nice           | TOO OLD | TOO OLD |  0.1.13 |  0.1.13 |    N/A |
 274 dnl purple         |  2.11.x |   2.7.x |  2.12.x |  2.10.x | 2.13.x |
 275 dnl telepathy-glib |  0.24.x |      NO |  0.24.x |  0.24.x |    N/A |
 276 dnl
 277
 278 dnl check for glib
 279 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.18.0])
 280 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.18.0])
 281
 282 dnl check for gmime
 283 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
 284         [ac_have_gmime=yes],
 285         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.6.0],
 286                 [ac_have_gmime=yes],
 287                 [ac_have_gmime=no])
 288         ])
 289 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 290 AS_IF([test "x$ac_have_gmime" = xyes],
 291         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 292
 293 dnl check for NSS
 294 AC_ARG_ENABLE(nss,
 295         [AS_HELP_STRING([--enable-nss],
 296                         [use NSS as crypto backend @<:@default=yes@:>@])],
 297         [],
 298         [enable_nss=yes])
 299 AS_IF([test "x$enable_nss" != xno],
 300         [PKG_CHECK_MODULES(NSS, [nss],
 301                 [],
 302                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 303                         [],
 304                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 305                                 [],
 306                                 [enable_nss=no])
 307                         ])
 308                 ])
 309         ])
 310
 311 dnl check for OpenSSL
 312 AC_ARG_ENABLE(openssl,
 313         [AS_HELP_STRING([--enable-openssl],
 314                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 315         [],
 316         [enable_openssl=yes])
 317 AS_IF([test "x$enable_openssl" != xno],
 318         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 319                    [],
 320                    [enable_openssl=no])
 321         ])
 322 AS_IF(
 323         [test "x$enable_nss" != xno],
 324                 [ dnl NSS has priority over OpenSSL
 325                   enable_openssl=no
 326                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 327         [test "x$enable_openssl" != xno],
 328                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 329         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 330 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 331
 332 dnl check for libxml2
 333 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 334
 335 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 336 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 337 ac_save_CFLAGS="$CFLAGS"
 338 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 339 dnl note the [[[ quoting: our code contains []!
 340 AC_RUN_IFELSE(
 341         [AC_LANG_PROGRAM(
 342                 [[
 343 #include <glib.h>
 344 #include <stdio.h>
 345
 346 /* Copied from uuid.c */
 347 typedef struct {
 348    guint32 time_low;
 349    guint16 time_mid;
 350    guint16 time_hi_and_version;
 351    guint8  clock_seq_hi_and_reserved;
 352    guint8  clock_seq_low;
 353    guint8  node[6];
 354 } uuid_t;
 355                 ]],
 356                 [[if (sizeof(uuid_t) == 16) {
 357                         return(0);
 358                  } else {
 359                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 360                         return(1);
 361                  }]])],
 362         [AC_MSG_RESULT(yes)],
 363         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 364
 365 Please notify the SIPE developers.
 366
 367 Copy & paste all lines starting with the line
 368
 369   checking that sizeof(uuid_t) is 16...
 370
 371 to the report and attach the file "config.log".
 372
 373 Compiler information:
 374
 375  host:     $host
 376  build:    $build
 377  compiler: $CC
 378 ])],
 379         [AC_MSG_WARN([cross compiling: not checking])])
 380 CFLAGS="$ac_save_CFLAGS"
 381
 382 dnl build option: OCS2005 client hack
 383 AC_ARG_ENABLE([ocs2005-message-hack],
 384         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 385                                                           which causes "false" not delivered error messages
 386                                                           @<:@default=no@:>@])],
 387         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 388                    [Define to 1 to disable SIP MESSAGE timeout feature.
 389                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 390                     disabling the timeout suppresses "false" error messages])])
 391
 392 dnl build option: purple backend
 393 AC_ARG_ENABLE([purple],
 394         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 395         [],
 396         [enable_purple=yes])
 397 ac_have_appshare=no
 398 ac_have_appshare_server=no
 399 ac_have_xdata=no
 400 with_purple_vv=no
 401 AS_IF([test "x$enable_purple" != xno],
 402         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 403                 [purple_pkgconfig=purple-3],
 404                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.7.0],
 405                         [purple_pkgconfig=purple],
 406                         [enable_purple=no])])
 407
 408          AS_IF([test "x$enable_purple" != xno],
 409                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 410
 411                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 412                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 413                  AC_SUBST(PURPLE_MAJOR_VERSION)
 414
 415                  ac_save_CFLAGS="$CFLAGS"
 416                  ac_save_LIBS="$LIBS"
 417                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 418                  LIBS="$LIBS $PURPLE_LIBS"
 419
 420                  dnl check whether enable voice and video support
 421                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 422                        [AC_MSG_CHECKING(for purple voice and video support)
 423                         purple_has_media=no
 424                         AC_RUN_IFELSE(
 425                                 [AC_LANG_PROGRAM([[
 426 #include <media.h>
 427                                         ]],
 428                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 429                                 )],
 430                                 [purple_has_media=yes
 431                                  AC_MSG_RESULT(ok)
 432                                 ],
 433                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 434                                 [AS_IF([test "x$with_vv" = xyes],
 435                                        [purple_has_media=yes
 436                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 437                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 438                                 ]
 439                         )
 440                         AS_IF([test "x$purple_has_media" = xyes],
 441                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 442                                         dnl sipe-media.c uses g_slist_free_full()
 443                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 444                                                 dnl check purple pkgconfig for gstreamer version
 445                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 446                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 447                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 448                                                                 [gstreamer_pkgconfig=1.0])])
 449                                                 AS_IF([test "x$gstreamer_pkgconfig" == x1.0],
 450                                                         [gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 451
 452                                                         AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 453                                                         PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 454                                                                 [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 455                                                                         [with_purple_vv=yes
 456
 457                                                                          AC_COMPILE_IFELSE(
 458                                                                                  [AC_LANG_PROGRAM([[
 459 #include <media.h>
 460                                                                                         ]],
 461                                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 462                                                                                  )],
 463                                                                                  [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 464                                                                         )],
 465                                                                         [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 466                                                                 [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 467                                                         [AC_MSG_NOTICE(your purple hasn't been compiled against GStreamer 1.0: disabling purple voice and video support)])],
 468                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 469                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 470                                 ])
 471                        ])
 472
 473                  dnl SRTP and XDATA require media backend
 474                  AS_IF([test "x$with_purple_vv" != xno],
 475                         [AC_LINK_IFELSE(
 476                                 [AC_LANG_PROGRAM([[
 477 #include <media.h>
 478                                         ]],
 479                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 480                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 481                                  )],
 482                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 483                          )
 484
 485                          AC_COMPILE_IFELSE(
 486                                 [AC_LANG_PROGRAM([[
 487 #include <media.h>
 488                                         ]],
 489                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 490                                  )],
 491                                  [dnl libpurple supports raw data RTP connections
 492                                   ac_have_xdata=yes
 493
 494                                   dnl gio-2.0 is mandatory for application sharing support
 495                                   PKG_CHECK_MODULES(GIO, [gio-2.0],
 496                                         [ac_have_appshare=yes
 497
 498                                          dnl freerdp-shadow2 & winpr2 is mandatory for appshare server support
 499                                          PKG_CHECK_MODULES(FREERDP_SHADOW, [freerdp-shadow2 winpr2],
 500                                                 [ac_have_appshare_server=yes],
 501                                                 [ac_have_appshare_server=no])
 502                                    ])
 503                                  ]
 504                          )
 505                         ],
 506                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 507                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 508                          )]
 509                  )
 510
 511                  CFLAGS="$ac_save_CFLAGS"
 512                  LIBS="$ac_save_LIBS"])])
 513 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 514 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 515
 516 dnl build option: telepathy backend
 517 AC_ARG_ENABLE([telepathy],
 518         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 519         [],
 520         [enable_telepathy=yes])
 521 AS_IF([test "x$enable_telepathy" != xno],
 522         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.24.0],
 523                 [dnl GMIME is a build requirement
 524                  AS_IF([test "x$ac_have_gmime" = xyes],
 525                         [],
 526                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 527
 528                  dnl telepathy is based on GObject & D-Bus GLib
 529                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 530                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 531
 532                  dnl telepathy uses from gio:
 533                  dnl  - GIOStream      (>= 2.22.0)
 534                  dnl  - GResolver      (>= 2.22.0)
 535                  dnl  - GSocketClient  (>= 2.32.0)
 536                  dnl  - GTlsConnection (>= 2.28.0)
 537                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 538
 539                 ],
 540                 [enable_telepathy=no])])
 541 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 542
 543 dnl sanity check
 544 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 545         [AC_ERROR(at least one plugin must be selected
 546
 547 If you didn't use a --enable option then please check that you have
 548 the headers for the packages "purple" or "telepathy-glib" installed.
 549 )],
 550         [])
 551
 552 dnl enable voice & video support if any backend supports it
 553 AS_IF([test "x$with_purple_vv" != xno],
 554         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 555 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 556
 557 dnl raw data RTP streams enable Lync file transfer
 558 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 559 AS_IF([test "x$ac_have_xdata" == xyes],
 560         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 561
 562 dnl enable appshare support
 563 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 564 AS_IF([test "x$ac_have_appshare" == xyes],
 565         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 566
 567 dnl RDP server for sharing local desktop
 568 AM_CONDITIONAL(SIPE_HAVE_APPSHARE_SERVER, [test "x$ac_have_appshare_server" = xyes])
 569 AS_IF([test "x$ac_have_appshare_server" == xyes],
 570         [AC_DEFINE(HAVE_APPSHARE_SERVER, 1, [Define if appshare server is enabled.])])
 571
 572 dnl libpurple API relies on GParameter (deprecated in glib-2.0 >= 2.62.0)
 573 AS_IF([test "x$enable_purple" != xno],
 574         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_60,
 575                    [We need GParameter for which no replacement is available])
 576         ])
 577 dnl telepathy code parts rely on interfaces that require GValueArray. This
 578 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 579 dnl is no backward compatible replacement implementation possible
 580 dnl telepathy-glib API relies on GTimeVal (deprecated in glib-2.0 >= 2.62.0)
 581 AS_IF([test "x$enable_telepathy" != xno],
 582         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 583                    [We need GValueArray for which no replacement is available])
 584         ])
 585 dnl libpurple 2.x API relies on G_CONST_RETURN (deprecated in glib-2.0 >= 2.30.0)
 586 AS_IF([test "x$purple_pkgconfig" == xpurple],
 587         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 588                    [libpurple 2.x API uses G_CONST_RETURN])
 589         ])
 590
 591 dnl i18n
 592 AC_MSG_CHECKING([locale_CPPFLAGS])
 593 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 594 AC_SUBST([LOCALE_CPPFLAGS])
 595 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 596 AM_GNU_GETTEXT([external])
 597 AM_GNU_GETTEXT_VERSION([0.19.8])
 598 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 599
 600 dnl substitutions and generated files
 601 AC_CONFIG_HEADERS([config.h])
 602 AC_CONFIG_FILES([
 603         Makefile
 604         pixmaps/Makefile
 605         po/Makefile.in
 606         pixmaps/16/Makefile
 607         pixmaps/22/Makefile
 608         pixmaps/24/Makefile
 609         pixmaps/32/Makefile
 610         pixmaps/48/Makefile
 611         pixmaps/scalable/Makefile
 612         src/Makefile
 613         src/core/Makefile
 614         src/api/Makefile
 615         src/purple/Makefile
 616         src/telepathy/Makefile
 617         src/telepathy/data/Makefile
 618         ])
 619
 620 dnl generate files
 621 AC_OUTPUT()
 622
 623 dnl additional info for the user
 624 AS_ECHO()
 625 AS_IF([test "x$enable_purple" = xno],
 626         [AS_ECHO("Not building purple plugin")],
 627         [AS_ECHO("Build purple plugin")
 628          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 629          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 630          AS_ECHO_N("Voice and video: ")
 631          AS_IF([test "x$with_purple_vv" = xno],
 632           [AS_ECHO("disabled")],
 633           [AS_ECHO("enabled")])
 634         ])
 635 AS_ECHO()
 636 AS_IF([test "x$enable_telepathy" = xno],
 637         [AS_ECHO("Not building telepathy plugin")],
 638         [AS_ECHO("Build telepathy plugin")
 639          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 640          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 641 AS_ECHO()
 642 AS_IF([test "x$with_krb5" = xno],
 643         [AS_ECHO("Not building with Kerberos 5 support")],
 644         [AS_ECHO("Build with Kerberos 5 support")
 645          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 646          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 647 AS_ECHO()
 648 AS_IF([test "x$enable_gssapi_only" = xno],
 649         [AS_ECHO("Using internal authentication implementation")],
 650         [AS_ECHO("Using only GSSAPI for authentication")])
 651 AS_ECHO()
 652 AS_IF([test "x$enable_debug" = xno],
 653         [AS_ECHO("Debugging not enabled")],
 654         [AS_ECHO("Build with debugging enabled")
 655          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 656 AS_ECHO()
 657 AS_IF([test "x$QUALITY_CFLAGS" = x],
 658         [AS_ECHO("Compiler checks disabled")],
 659         [AS_ECHO("Build with compiler checks enabled")
 660          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 661 AS_ECHO()
 662 AS_ECHO("configure complete. Now run 'make'")
 663 AS_ECHO()
 664
 665 dnl The End.