configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Winit-self" \
 108                         "-Wmaybe-uninitialized" \
 109                         "-Wmissing-declarations" \
 110                         "-Wmissing-prototypes" \
 111                         "-Wnested-externs" \
 112                         "-Wpointer-arith" \
 113                         "-Wundef" \
 114                         "-Wunused-but-set-variable" \
 115          ; do
 116                  ac_save_CFLAGS="$CFLAGS"
 117                  AC_MSG_CHECKING([if $CC supports $newflag])
 118                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 119                  AC_COMPILE_IFELSE(
 120                         [AC_LANG_SOURCE([[]])],
 121                         [AC_MSG_RESULT(yes)
 122                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 123                         [AC_MSG_RESULT(no)]
 124                  )
 125                  CFLAGS="$ac_save_CFLAGS"
 126          done
 127         ])
 128 AC_SUBST(QUALITY_CFLAGS)
 129
 130 dnl check for availability of addition linker flags
 131 for newflag in \
 132         "-Wl,-Bsymbolic-functions" \
 133 ; do
 134         ac_save_LDFLAGS="$LDFLAGS"
 135         AC_MSG_CHECKING([if $CC supports $newflag])
 136         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 137         AC_LINK_IFELSE(
 138                 [AC_LANG_SOURCE([[
 139 int main(int argc, char *argv[])
 140 {
 141         return(0);
 142 }
 143                  ]])],
 144                 [AC_MSG_RESULT(yes)
 145                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 146                 [AC_MSG_RESULT(no)]
 147         )
 148         LDFLAGS="$ac_save_LDFLAGS"
 149 done
 150 AC_SUBST(ADDITIONAL_LDFLAGS)
 151
 152 dnl Check for pkg-config before using it
 153 PKG_PROG_PKG_CONFIG
 154
 155 dnl check for valgrind (optional, only needed for debugging)
 156 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 157         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 158         [AC_MSG_RESULT(no)])
 159
 160 dnl build option: with voice & video support (for all backends)
 161 AC_ARG_WITH(vv,
 162         [AC_HELP_STRING([--with-vv],
 163                 [compile with voice and video support @<:@default=check@:>@])],
 164         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 165         [with_vv=check])
 166
 167 dnl check for Kerberos 5 support
 168 AC_ARG_WITH([krb5],
 169         [AC_HELP_STRING([--with-krb5],
 170                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 171         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 172         [with_krb5=check])
 173
 174 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 175       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 176         [AC_MSG_CHECKING(if Kerberos 5 is available)
 177          AS_IF([AC_RUN_LOG([krb5-config --version])],
 178                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 179                  KRB5_LDFLAGS=""
 180
 181                  dnl same as AC_CHECK_LIB()
 182                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 183                 [AC_MSG_RESULT(no)
 184                  with_krb5=no])],
 185       [                               dnl path specified by user
 186         KRB5_CFLAGS="-I${with_krb5}/include"
 187         KRB5_LDFLAGS="-L${with_krb5}/lib"
 188       ])
 189 AS_IF([test "x$with_krb5" != xno],
 190       [ac_save_CFLAGS="$CFLAGS"
 191        ac_save_LDFLAGS="$LDFLAGS"
 192        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 193        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 194        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 195                         [],
 196                         [AC_ERROR([GSSAPI headers not found])])
 197        AC_CHECK_FUNC([gss_init_sec_context],
 198                      [],
 199                      [AC_ERROR([GSSAPI libraries not found])])
 200
 201        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 202        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 203                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 204                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 205                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 206                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 207
 208        CFLAGS="$ac_save_CFLAGS"
 209        LDFLAGS="$ac_save_LDFLAGS"
 210       ])
 211
 212 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 213 AC_SUBST(KRB5_CFLAGS)
 214 AC_SUBST(KRB5_LDFLAGS)
 215
 216 AC_ARG_ENABLE(gssapi_only,
 217         [AS_HELP_STRING([--enable-gssapi-only],
 218                         [disable all internal authentication code and only use
 219                          GSSAPI for authentication @<:@default=yes@:>@])],
 220         [],
 221         dnl requires Kerberos which provides GSSAPI
 222         [enable_gssapi_only=$with_krb5])
 223 AS_IF([test "x$enable_gssapi_only" != xno],
 224         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 225                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 226                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 227                         enable_gssapi_only=no])
 228         ])
 229 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 230
 231 dnl check for glib
 232 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 233 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 234
 235 dnl check for gio-2.0 optional for application sharing support
 236 PKG_CHECK_MODULES(GIO, [gio-2.0],
 237         [ac_have_gio=yes],
 238         [ac_have_gio=no])
 239 AM_CONDITIONAL(SIPE_HAVE_GIO, [test "x$ac_have_gio" == xyes])
 240 AS_IF([test "x$ac_have_gio" == xyes],
 241         [AC_DEFINE(HAVE_GIO, 1, [Define if we have GIO library.])])
 242
 243 dnl check for gmime
 244 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 245 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 246         [ac_have_gmime=yes],
 247         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 248                 [ac_have_gmime=yes],
 249                 [ac_have_gmime=no])
 250 ])
 251 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 252 AS_IF([test "x$ac_have_gmime" = xyes],
 253         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 254
 255 dnl check for NSS
 256 AC_ARG_ENABLE(nss,
 257         [AS_HELP_STRING([--enable-nss],
 258                         [use NSS as crypto backend @<:@default=yes@:>@])],
 259         [],
 260         [enable_nss=yes])
 261 AS_IF([test "x$enable_nss" != xno],
 262         [PKG_CHECK_MODULES(NSS, [nss],
 263                 [],
 264                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 265                         [],
 266                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 267                                 [],
 268                                 [enable_nss=no])
 269                         ])
 270                 ])
 271         ])
 272
 273 dnl check for OpenSSL
 274 AC_ARG_ENABLE(openssl,
 275         [AS_HELP_STRING([--enable-openssl],
 276                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 277         [],
 278         [enable_openssl=yes])
 279 AS_IF([test "x$enable_openssl" != xno],
 280         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 281                    [],
 282                    [enable_openssl=no])
 283         ])
 284 AS_IF(
 285         [test "x$enable_nss" != xno],
 286                 [ dnl NSS has priority over OpenSSL
 287                   enable_openssl=no
 288                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 289         [test "x$enable_openssl" != xno],
 290                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 291         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 292 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 293
 294 dnl check for libxml2
 295 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 296
 297 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 298 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 299 ac_save_CFLAGS="$CFLAGS"
 300 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 301 dnl note the [[[ quoting: our code contains []!
 302 AC_RUN_IFELSE(
 303         [AC_LANG_PROGRAM(
 304                 [[
 305 #include <glib.h>
 306 #include <stdio.h>
 307
 308 /* Copied from uuid.c */
 309 typedef struct {
 310    guint32 time_low;
 311    guint16 time_mid;
 312    guint16 time_hi_and_version;
 313    guint8  clock_seq_hi_and_reserved;
 314    guint8  clock_seq_low;
 315    guint8  node[6];
 316 } uuid_t;
 317                 ]],
 318                 [[if (sizeof(uuid_t) == 16) {
 319                         return(0);
 320                  } else {
 321                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 322                         return(1);
 323                  }]])],
 324         [AC_MSG_RESULT(yes)],
 325         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 326
 327 Please notify the SIPE developers.
 328
 329 Copy & paste all lines starting with the line
 330
 331   checking that sizeof(uuid_t) is 16...
 332
 333 to the report and attach the file "config.log".
 334
 335 Compiler information:
 336
 337  host:     $host
 338  build:    $build
 339  compiler: $CC
 340 ])],
 341         [AC_MSG_WARN([cross compiling: not checking])])
 342 CFLAGS="$ac_save_CFLAGS"
 343
 344 dnl build option: OCS2005 client hack
 345 AC_ARG_ENABLE([ocs2005-message-hack],
 346         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 347                                                           which causes "false" not delivered error messages
 348                                                           @<:@default=no@:>@])],
 349         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 350                    [Define to 1 to disable SIP MESSAGE timeout feature.
 351                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 352                     disabling the timeout suppresses "false" error messages])])
 353
 354 dnl build option: purple backend
 355 AC_ARG_ENABLE([purple],
 356         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 357         [],
 358         [enable_purple=yes])
 359 ac_have_xdata=no
 360 with_purple_vv=no
 361 AS_IF([test "x$enable_purple" != xno],
 362         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 363                 [purple_pkgconfig=purple-3],
 364                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 365                         [purple_pkgconfig=purple],
 366                         [enable_purple=no])])
 367
 368          AS_IF([test "x$enable_purple" != xno],
 369                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 370
 371                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 372                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 373                  AC_SUBST(PURPLE_MAJOR_VERSION)
 374
 375                  ac_save_CFLAGS="$CFLAGS"
 376                  ac_save_LIBS="$LIBS"
 377                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 378                  LIBS="$LIBS $PURPLE_LIBS"
 379
 380                  dnl check whether enable voice and video support
 381                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 382                        [AC_MSG_CHECKING(for purple voice and video support)
 383                         AC_RUN_IFELSE(
 384                                 [AC_LANG_PROGRAM([[
 385 #include <media.h>
 386                                         ]],
 387                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 388                                 )],
 389                                 [AC_MSG_RESULT(ok)
 390                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 391                                         dnl sipe-media.c uses g_slist_free_full()
 392                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 393                                                 dnl check purple pkgconfig for gstreamer version
 394                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 395                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 396                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 397                                                                 [gstreamer_pkgconfig=1.0], [gstreamer_pkgconfig=0.10])])
 398                                                 gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 399
 400                                                 AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 401                                                 PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 402                                                         [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 403                                                                 [with_purple_vv=yes
 404
 405                                                                  AC_COMPILE_IFELSE(
 406                                                                         [AC_LANG_PROGRAM([[
 407 #include <media.h>
 408                                                                                 ]],
 409                                                                                 [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 410                                                                         )],
 411                                                                         [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 412                                                                 )],
 413                                                                 [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 414                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 415                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 416                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 417                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 418                                 [AC_MSG_WARN([cross compiling: not checking])])
 419                        ])
 420
 421                  dnl SRTP and XDATA require media backend
 422                  AS_IF([test "x$with_purple_vv" != xno],
 423                         [AC_LINK_IFELSE(
 424                                 [AC_LANG_PROGRAM([[
 425 #include <media.h>
 426                                         ]],
 427                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 428                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 429                                  )],
 430                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 431                          )
 432
 433                          AC_COMPILE_IFELSE(
 434                                 [AC_LANG_PROGRAM([[
 435 #include <media.h>
 436                                         ]],
 437                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 438                                  )],
 439                                  [dnl libpurple supports raw data RTP connections
 440                                   ac_have_xdata=yes]
 441                          )
 442                         ],
 443                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 444                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 445                          )]
 446                  )
 447
 448                  CFLAGS="$ac_save_CFLAGS"
 449                  LIBS="$ac_save_LIBS"])])
 450 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 451 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 452
 453 dnl build option: telepathy backend
 454 AC_ARG_ENABLE([telepathy],
 455         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 456         [],
 457         [enable_telepathy=yes])
 458 AS_IF([test "x$enable_telepathy" != xno],
 459         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 460                 [dnl GMIME is a build requirement
 461                  AS_IF([test "x$ac_have_gmime" = xyes],
 462                         [],
 463                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 464
 465                  dnl telepathy is based on GObject & D-Bus GLib
 466                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 467                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 468
 469                  dnl telepathy uses from gio:
 470                  dnl  - GIOStream      (>= 2.22.0)
 471                  dnl  - GResolver      (>= 2.22.0)
 472                  dnl  - GSocketClient  (>= 2.32.0)
 473                  dnl  - GTlsConnection (>= 2.28.0)
 474                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 475
 476                 ],
 477                 [enable_telepathy=no])])
 478 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 479
 480 dnl sanity check
 481 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 482         [AC_ERROR(at least one plugin must be selected
 483
 484 If you didn't use a --enable option then please check that you have
 485 the headers for the packages "purple" or "telepathy-glib" installed.
 486 )],
 487         [])
 488
 489 dnl enable voice & video support if any backend supports it
 490 AS_IF([test "x$with_purple_vv" != xno],
 491         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 492 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 493
 494 dnl raw data RTP streams enable Lync file transfer
 495 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 496 AS_IF([test "x$ac_have_xdata" == xyes],
 497         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 498
 499 dnl these code parts rely on interfaces that require GValueArray. This
 500 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 501 dnl is no backward compatible replacement implementation possible
 502 AS_IF([test "x$with_purple_vv" != xno -o "x$enable_telepathy" != xno],
 503         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 504                    [We need GValueArray for which no replacement is available])])
 505
 506 dnl i18n
 507 AC_MSG_CHECKING([locale_CPPFLAGS])
 508 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 509 AC_SUBST([LOCALE_CPPFLAGS])
 510 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 511 AM_GLIB_GNU_GETTEXT
 512 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 513
 514 dnl codeset
 515 AM_LANGINFO_CODESET
 516
 517 dnl substitutions and generated files
 518 AC_CONFIG_HEADERS([config.h])
 519 AC_CONFIG_FILES([
 520         Makefile
 521         pixmaps/Makefile
 522         m4macros/Makefile
 523         po/Makefile.in
 524         pixmaps/16/Makefile
 525         pixmaps/22/Makefile
 526         pixmaps/24/Makefile
 527         pixmaps/32/Makefile
 528         pixmaps/48/Makefile
 529         pixmaps/scalable/Makefile
 530         src/Makefile
 531         src/core/Makefile
 532         src/api/Makefile
 533         src/purple/Makefile
 534         src/telepathy/Makefile
 535         src/telepathy/data/Makefile
 536         ])
 537
 538 dnl generate files
 539 AC_OUTPUT()
 540
 541 dnl additional info for the user
 542 AS_ECHO()
 543 AS_IF([test "x$enable_purple" = xno],
 544         [AS_ECHO("Not building purple plugin")],
 545         [AS_ECHO("Build purple plugin")
 546          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 547          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 548          AS_ECHO_N("Voice and video: ")
 549          AS_IF([test "x$with_purple_vv" = xno],
 550           [AS_ECHO("disabled")],
 551           [AS_ECHO("enabled")])
 552         ])
 553 AS_ECHO()
 554 AS_IF([test "x$enable_telepathy" = xno],
 555         [AS_ECHO("Not building telepathy plugin")],
 556         [AS_ECHO("Build telepathy plugin")
 557          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 558          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 559 AS_ECHO()
 560 AS_IF([test "x$with_krb5" = xno],
 561         [AS_ECHO("Not building with Kerberos 5 support")],
 562         [AS_ECHO("Build with Kerberos 5 support")
 563          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 564          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 565 AS_ECHO()
 566 AS_IF([test "x$enable_gssapi_only" = xno],
 567         [AS_ECHO("Using internal authentication implementation")],
 568         [AS_ECHO("Using only GSSAPI for authentication")])
 569 AS_ECHO()
 570 AS_IF([test "x$enable_debug" = xno],
 571         [AS_ECHO("Debugging not enabled")],
 572         [AS_ECHO("Build with debugging enabled")
 573          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 574 AS_ECHO()
 575 AS_IF([test "x$QUALITY_CFLAGS" = x],
 576         [AS_ECHO("Compiler checks disabled")],
 577         [AS_ECHO("Build with compiler checks enabled")
 578          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 579 AS_ECHO()
 580 AS_ECHO("configure complete. Now run 'make'")
 581 AS_ECHO()
 582
 583 dnl The End.