configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use `VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9           m4_substr(SIPE_VERSION_DATA,
  10                     [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/tracker/?atid=949931&group_id=194563], [],
  18         SIPE_HOMEPAGE)
  19
  20 dnl setup automake and require recent enough version
  21 AM_INIT_AUTOMAKE([1.9 dist-bzip2 no-define tar-ustar])
  22
  23 dnl set PACKAGE_URL for autoconf < 2.64
  24 AS_IF([test "x${PACKAGE_URL}" = x],
  25         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  26          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  27 ])
  28
  29 dnl set programming language
  30 AC_LANG(C)
  31 AM_PROG_CC_C_O
  32 AC_HEADER_STDC
  33
  34 dnl setup shared library generation
  35 LT_INIT([disable-static])
  36
  37 dnl checks for tools
  38 IT_PROG_INTLTOOL([0.35.0])
  39 AC_PROG_INSTALL
  40 AC_PROG_RANLIB
  41
  42 dnl checks for header files
  43 AC_CHECK_HEADERS([sys/sockio.h])
  44
  45 dnl checks for library functions
  46 AC_CHECK_FUNCS([])
  47
  48 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  49 dnl as that is likely where libpurple will be found if it is not in the default
  50 dnl pkgconfig path
  51 PREFIX=$ac_default_prefix
  52 AS_IF([test "x$prefix" != xNONE],
  53         [PREFIX=$prefix])
  54
  55 PKG_CONFIG_PATH="$PKG_CONFIG_PATH":"$PREFIX/lib/pkgconfig"
  56 export PKG_CONFIG_PATH
  57
  58 dnl debug mode
  59 AC_ARG_ENABLE(debug,
  60         [AS_HELP_STRING([--enable-debug],
  61                         [compile with debugging support [default=no]])],
  62         [],
  63         [enable_debug=no])
  64
  65 AS_IF([test "x$enable_debug" = xyes],
  66         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  67 AC_SUBST(DEBUG_CFLAGS)
  68
  69 dnl quality check mode
  70 dnl For people who are interested in finding bugs and not hiding them
  71 AC_ARG_ENABLE(quality-check,
  72         [AS_HELP_STRING([--enable-quality-check],
  73                         [compile with compiler checks enabled [default=yes]])],
  74         [],
  75         [enable_quality_check=yes])
  76
  77 AS_IF([test "x$enable_quality_check" = xyes],
  78         [QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  79          ac_save_CFLAGS=$CFLAGS
  80
  81          dnl GCC >= 3.4
  82          AC_MSG_CHECKING([if $CC supports -Wextra])
  83          CFLAGS="$QUALITY_CFLAGS -Wextra"
  84          AC_COMPILE_IFELSE(
  85                 AC_LANG_PROGRAM(),
  86                 [AC_MSG_RESULT(yes)
  87                  QUALITY_CFLAGS="$QUALITY_CFLAGS -Wextra"],
  88                 [AC_MSG_RESULT(no)]
  89          )
  90
  91          dnl declaration-after-statement (ISO C90 behaviour, as on Windows & GCC < 3)
  92          AC_MSG_CHECKING([if $CC supports -Werror=declaration-after-statement])
  93          CFLAGS="$QUALITY_CFLAGS -Werror=declaration-after-statement"
  94          AC_COMPILE_IFELSE(
  95                 AC_LANG_PROGRAM(),
  96                 [AC_MSG_RESULT(yes)
  97                  QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror=declaration-after-statement"],
  98                 [AC_MSG_RESULT(no)]
  99          )
 100          CFLAGS=$ac_save_CFLAGS])
 101 AC_SUBST(QUALITY_CFLAGS)
 102
 103 dnl Check for pkg-config before using it
 104 PKG_PROG_PKG_CONFIG
 105
 106 dnl build option: with voice & video support (for all backends)
 107 AC_ARG_WITH(vv,
 108         [AC_HELP_STRING([--with-vv],
 109                 [compile with voice and video support @<:@default=check@:>@])],
 110         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 111         [with_vv=check])
 112
 113 dnl check for Kerberos 5 support
 114 AC_ARG_WITH([krb5],
 115         [AC_HELP_STRING([--with-krb5],
 116                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 117         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 118         [with_krb5=check])
 119
 120 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 121       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 122         [AC_MSG_CHECKING(if Kerberos 5 is available)
 123          AS_IF([AC_RUN_LOG([krb5-config --version])],
 124                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 125                  KRB5_LDFLAGS=""
 126
 127                  dnl same as AC_CHECK_LIB()
 128                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"
 129                  AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5)])],
 130                 [AC_MSG_RESULT(no)
 131                  with_krb5=no])],
 132       [                               dnl path specified by user
 133         KRB5_CFLAGS="-I${with_krb5}/include"
 134         KRB5_LDFLAGS="-L${with_krb5}/lib"
 135         ac_save_LDFLAGS="$LDLAGS"
 136         LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 137         AC_CHECK_LIB(krb5, krb5_rd_req,          [],
 138                 [AC_CHECK_LIB(krb5, krb5_rd_req, [],
 139                         [AC_ERROR(Kerberos 5 libraries not found)])])
 140         AC_CHECK_LIB(gssapi_krb5, gss_krb5_export_lucid_sec_context, [],
 141                         [AC_ERROR(GSSAPI Kerberos 5 libraries not found)])
 142         LDFLAGS="$ac_save_LDFLAGS"])
 143 AM_CONDITIONAL(SIP_SEC_KRB5, [test "x$with_krb5" != xno])
 144 AC_SUBST(KRB5_CFLAGS)
 145 AC_SUBST(KRB5_LDFLAGS)
 146
 147 dnl check for glib
 148 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 149 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 150
 151 dnl check for gmime
 152 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 153 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 154         [ac_have_gmime=yes],
 155         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 156                 [ac_have_gmime=yes],
 157                 [ac_have_gmime=no])
 158 ])
 159 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 160 AS_IF([test "x$ac_have_gmime" = xyes],
 161         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 162
 163 dnl check for NSS
 164 PKG_CHECK_MODULES(NSS, [nss],
 165         [ac_have_nss=yes],
 166         [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 167                 [ac_have_nss=yes],
 168                 [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 169                         [ac_have_nss=yes],
 170                         [ac_have_nss=no])
 171         ])
 172 ])
 173 AM_CONDITIONAL(SIPE_CRYPTO_NSS, [test "x$ac_have_nss" = xyes])
 174 AS_IF([test "x$ac_have_nss" = xyes],
 175         [AC_DEFINE(HAVE_NSS, 1, [Define if nss should be used in sipe.])])
 176
 177 dnl check for libxml2
 178 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 179
 180 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 181 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 182 ac_save_CFLAGS=$CFLAGS
 183 CFLAGS="$GLIB_CFLAGS $QUALITY_CFLAGS"
 184 dnl note the [[[ quoting: our code contains []!
 185 AC_RUN_IFELSE(
 186         AC_LANG_PROGRAM(
 187                 [[[
 188 #include <glib.h>
 189 #include <stdio.h>
 190
 191 /* Copied from uuid.c */
 192 typedef struct {
 193    guint32 time_low;
 194    guint16 time_mid;
 195    guint16 time_hi_and_version;
 196    guint8  clock_seq_hi_and_reserved;
 197    guint8  clock_seq_low;
 198    guint8  node[6];
 199 } uuid_t;
 200                 ]]],
 201                 [return(sizeof(uuid_t) == 16 ? 0 : 1);]),
 202         [AC_MSG_RESULT(yes)],
 203         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 204
 205 Please notify the SIPE developers and provide the following information:
 206
 207  host:     $host
 208  build:    $build
 209  compiler: $CC
 210 ])])
 211 CFLAGS=$ac_save_CFLAGS
 212
 213 dnl build option: purple backend
 214 AC_ARG_ENABLE([purple],
 215         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 216         [],
 217         [enable_purple=yes])
 218 with_purple_vv=no
 219 AS_IF([test "x$enable_purple" != xno],
 220         [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 221                 [dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 222                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion purple | cut -d. -f 1`
 223                  AC_SUBST(PURPLE_MAJOR_VERSION)
 224
 225                  dnl let user now if he has a 32- and 64-bit header conflict...
 226                  AC_MSG_CHECKING([for 32- and 64-bit header conflicts])
 227                  ac_save_CFLAGS=$CFLAGS
 228                  CFLAGS="$PURPLE_CFLAGS $QUALITY_CFLAGS"
 229                  AC_COMPILE_IFELSE(
 230                         AC_LANG_PROGRAM([
 231 #include <glib.h>
 232 #include <cipher.h>
 233
 234 /* Compile some code that has caused trouble in the past */
 235 void testfunc(unsigned long len)
 236 {
 237   PurpleCipherContext *rc4 = NULL;
 238   purple_cipher_context_set_option(rc4, "key_len", GUINT_TO_POINTER(len));
 239 }
 240                                         ],
 241                                         [testfunc(16);]),
 242                         [AC_MSG_RESULT(none)],
 243                         [AC_MSG_FAILURE([conflicts found.
 244
 245 Check that you have the correct glib/libpurple headers installed for
 246 your architecture or set PURPLE_CFLAGS to override the system defaults.
 247 ])
 248                         ])
 249
 250                  dnl purple SSL support is mandatory
 251                  AC_MSG_CHECKING([for purple SSL support])
 252                  ac_save_LIBS=$LIBS
 253                  LIBS="$PURPLE_LIBS"
 254                  AC_RUN_IFELSE(
 255                         AC_LANG_PROGRAM([
 256 #include <glib.h>
 257 #include <plugin.h>
 258 #include <sslconn.h>
 259 ],
 260                                         [
 261         purple_plugins_init();
 262         purple_plugins_probe(G_MODULE_SUFFIX);
 263         purple_ssl_init();
 264         return(purple_ssl_is_supported()?0:1);
 265                                         ]),
 266                         [AC_MSG_RESULT(ok)],
 267                         [AC_MSG_FAILURE([your purple hasn't been compiled with SSL support.
 268 ])
 269                         ])
 270
 271                  dnl check whether enable voice and video support
 272                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 273                        [test "x$with_vv" = xcheck],  dnl autodetect
 274                          [AC_MSG_CHECKING(for purple voice and video support)
 275                           AC_RUN_IFELSE(
 276                                 AC_LANG_PROGRAM(
 277                                         [[[
 278 #include <libpurple/media.h>
 279                                         ]]],
 280                                         [return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);
 281                                          purple_media_get_active_local_candidates(NULL, NULL, NULL);
 282                                          purple_media_get_active_remote_candidates(NULL, NULL, NULL);]
 283                                 ),
 284                                 [AC_MSG_RESULT(ok)
 285                                  PKG_CHECK_MODULES(NICE, [nice >= 0.0.12],
 286                                         [with_purple_vv=yes],
 287                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 288                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)])
 289                          ])
 290                  CFLAGS=$ac_save_CFLAGS
 291                  LIBS=$ac_save_LIBS],
 292                 [enable_purple=no])])
 293 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 294
 295 dnl build option: telepathy backend
 296 AC_ARG_ENABLE([telepathy],
 297         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 298         [],
 299         [enable_telepathy=yes])
 300 AS_IF([test "x$enable_telepathy" != xno],
 301         [PKG_CHECK_MODULES(TELEPATHY, [telepathy-glib],
 302                 [dnl GMIME is a build requirement
 303                  AS_IF([test "x$ac_have_gmime" = xyes],
 304                         [],
 305                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 306
 307                  dnl NSS is a build requirement
 308                  AS_IF([test "x$ac_have_nss" = xyes],
 309                         [],
 310                         [AC_ERROR(NSS package is required for telepathy plugin)])
 311
 312                  dnl NOTHING IMPLEMENTED YET!!!
 313                 ],
 314                 [enable_telepathy=no])])
 315 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 316
 317 dnl build option: kopete backend
 318 AC_ARG_ENABLE([kopete],
 319         [AC_HELP_STRING([--enable-kopete], [build kopete plugin @<:@default=no@:>@])],
 320         [],
 321         [enable_kopete=no])
 322 AS_IF([test "x$enable_kopete" != xno],
 323         [dnl GMIME is a build requirement
 324          AS_IF([test "x$ac_have_gmime" = xyes],
 325                 [],
 326                 [AC_ERROR(GMIME package is required for kopete plugin)])
 327
 328          dnl NSS is a build requirement
 329          AS_IF([test "x$ac_have_nss" = xyes],
 330                 [],
 331                 [AC_ERROR(NSS package is required for kopete plugin)])
 332
 333          dnl NOTHING IMPLEMENTED YET!!!
 334         ],
 335         [enable_kopete=no])
 336 AM_CONDITIONAL(SIPE_INCLUDE_KOPETE, [test "x$enable_kopete" != xno])
 337
 338 dnl sanity check
 339 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno -a "x$enable_kopete" = xno],
 340         [AC_ERROR(at least one plugin must be selected
 341
 342 If you didn't use a --enable option then please check that you have
 343 the headers for the packages "purple" or "telepathy-glib" installed.
 344 )],
 345         [])
 346
 347 dnl enable voice & video support if any backend supports it
 348 AS_IF([test "x$with_purple_vv" != xno],
 349         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 350 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 351
 352 dnl i18n
 353 AC_MSG_CHECKING([locale_CPPFLAGS])
 354 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(prefix)/$(DATADIRNAME)/locale\"'
 355 AC_SUBST([LOCALE_CPPFLAGS])
 356 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 357 AM_GLIB_GNU_GETTEXT
 358 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 359
 360 dnl codeset
 361 AM_LANGINFO_CODESET
 362
 363 dnl substitutions and generated files
 364 AC_CONFIG_HEADERS([config.h])
 365 AC_CONFIG_FILES([
 366         Makefile
 367         pixmaps/Makefile
 368         m4macros/Makefile
 369         po/Makefile.in
 370         pixmaps/16/Makefile
 371         pixmaps/22/Makefile
 372         pixmaps/48/Makefile
 373         pixmaps/scalable/Makefile
 374         src/Makefile
 375         src/core/Makefile
 376         src/api/Makefile
 377         src/purple/Makefile
 378         src/telepathy/Makefile
 379         src/kopete/Makefile
 380         ])
 381
 382 dnl generate files
 383 AC_OUTPUT()
 384
 385 dnl additional info for the user
 386 AS_ECHO()
 387 AS_IF([test "x$enable_purple" = xno],
 388         [AS_ECHO("Not building purple plugin")],
 389         [AS_ECHO("Build purple plugin")
 390          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 391          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 392          AS_IF([test "x$with_purple_vv" = xno],
 393           [AS_ECHO("Voice and video: disabled")],
 394           [AS_ECHO("Voice and video: enabled")])
 395         ])
 396 AS_ECHO()
 397 AS_IF([test "x$enable_telepathy" = xno],
 398         [AS_ECHO("Not building telepathy plugin")],
 399         [AS_ECHO("Build telepathy plugin")
 400          AS_ECHO()
 401          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 402          AS_ECHO()
 403          AS_ECHO("TELEPATHY_CFLAGS: $TELEPATHY_CFLAGS")
 404          AS_ECHO("TELEPATHY_LIBS  : $TELEPATHY_LIBS")])
 405 AS_ECHO()
 406 AS_IF([test "x$enable_kopete" = xno],
 407         [AS_ECHO("Not building kopete plugin")],
 408         [AS_ECHO("Build kopete plugin")
 409          AS_ECHO()
 410          AS_ECHO("NOTHING IMPLEMENTED YET!!!")
 411          AS_ECHO()])
 412 AS_ECHO()
 413 AS_IF([test "x$with_krb5" = xno],
 414         [AS_ECHO("Not building with Kerberos 5 support")],
 415         [AS_ECHO("Build with Kerberos 5 support")
 416          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 417          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 418 AS_ECHO()
 419 AS_IF([test "x$enable_debug" = xno],
 420         [AS_ECHO("Debugging not enabled")],
 421         [AS_ECHO("Build with debugging enabled")
 422          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 423 AS_ECHO()
 424 AS_IF([test "x$QUALITY_CFLAGS" = x],
 425         [AS_ECHO("Compiler checks disabled")],
 426         [AS_ECHO("Build with compiler checks enabled")
 427          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 428 AS_ECHO()
 429 AS_ECHO("configure complete. Now run 'make'")
 430 AS_ECHO()
 431
 432 dnl The End.