configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wcast-function-type" \
 106                         "-Wdeclaration-after-statement" \
 107                         "-Wdeprecated-declarations" \
 108                         "-Wduplicate-decl-specifier" \
 109                         "-Winit-self" \
 110                         "-Wmaybe-uninitialized" \
 111                         "-Wmissing-declarations" \
 112                         "-Wmissing-prototypes" \
 113                         "-Wnested-externs" \
 114                         "-Wpointer-arith" \
 115                         "-Wundef" \
 116                         "-Wunused-but-set-variable" \
 117          ; do
 118                  ac_save_CFLAGS="$CFLAGS"
 119                  AC_MSG_CHECKING([if $CC supports $newflag])
 120                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 121                  AC_COMPILE_IFELSE(
 122                         [AC_LANG_SOURCE([[]])],
 123                         [AC_MSG_RESULT(yes)
 124                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 125                         [AC_MSG_RESULT(no)]
 126                  )
 127                  CFLAGS="$ac_save_CFLAGS"
 128          done
 129         ])
 130 AC_SUBST(QUALITY_CFLAGS)
 131
 132 dnl check for availability of addition linker flags
 133 for newflag in \
 134         "-Wl,-Bsymbolic-functions" \
 135 ; do
 136         ac_save_LDFLAGS="$LDFLAGS"
 137         AC_MSG_CHECKING([if $CC supports $newflag])
 138         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 139         AC_LINK_IFELSE(
 140                 [AC_LANG_SOURCE([[
 141 int main(int argc, char *argv[])
 142 {
 143         return(0);
 144 }
 145                  ]])],
 146                 [AC_MSG_RESULT(yes)
 147                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 148                 [AC_MSG_RESULT(no)]
 149         )
 150         LDFLAGS="$ac_save_LDFLAGS"
 151 done
 152 AC_SUBST(ADDITIONAL_LDFLAGS)
 153
 154 dnl Check for pkg-config before using it
 155 PKG_PROG_PKG_CONFIG
 156
 157 dnl check for valgrind (optional, only needed for debugging)
 158 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 159         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 160         [AC_MSG_RESULT(no)])
 161
 162 dnl build option: with voice & video support (for all backends)
 163 AC_ARG_WITH(vv,
 164         [AC_HELP_STRING([--with-vv],
 165                 [compile with voice and video support @<:@default=check@:>@])],
 166         [AS_IF([test "x$withval" = xyes], [with_vv=yes])],
 167         [with_vv=check])
 168
 169 dnl check for Kerberos 5 support
 170 AC_ARG_WITH([krb5],
 171         [AC_HELP_STRING([--with-krb5],
 172                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 173         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 174         [with_krb5=check])
 175
 176 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 177       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 178         [AC_MSG_CHECKING(if Kerberos 5 is available)
 179          AS_IF([AC_RUN_LOG([krb5-config --version])],
 180                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 181                  KRB5_LDFLAGS=""
 182
 183                  dnl same as AC_CHECK_LIB()
 184                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 185                 [AC_MSG_RESULT(no)
 186                  with_krb5=no])],
 187       [                               dnl path specified by user
 188         KRB5_CFLAGS="-I${with_krb5}/include"
 189         KRB5_LDFLAGS="-L${with_krb5}/lib"
 190       ])
 191 AS_IF([test "x$with_krb5" != xno],
 192       [ac_save_CFLAGS="$CFLAGS"
 193        ac_save_LDFLAGS="$LDFLAGS"
 194        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 195        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 196        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 197                         [],
 198                         [AC_ERROR([GSSAPI headers not found])])
 199        AC_CHECK_FUNC([gss_init_sec_context],
 200                      [],
 201                      [AC_ERROR([GSSAPI libraries not found])])
 202
 203        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 204        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 205                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 206                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 207                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 208                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 209
 210        CFLAGS="$ac_save_CFLAGS"
 211        LDFLAGS="$ac_save_LDFLAGS"
 212       ])
 213
 214 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 215 AC_SUBST(KRB5_CFLAGS)
 216 AC_SUBST(KRB5_LDFLAGS)
 217
 218 dnl check for DBUS support
 219 AC_ARG_WITH([dbus],
 220         [AC_HELP_STRING([--with-dbus],
 221                 [compile with D-BUS support @<:@default=check@:>@])],
 222         [AS_IF([test "x$withval" = xyes], [with_dbus=check])],
 223         [with_dbus=check])
 224
 225 AS_IF([test "x$with_dbus" = xno], [], dnl disabled by user
 226       [test "x$with_dbus" = xcheck],  dnl autodetect with pkg-config
 227         [PKG_CHECK_MODULES(DBUS, [dbus-1],
 228                 [with_dbus=yes],
 229                 [with_dbus=no])
 230         ])
 231 AM_CONDITIONAL(SIPE_DBUS, [test "x$with_dbus" = xyes])
 232 AS_IF([test "x$with_dbus" = xyes],
 233         [AC_DEFINE(HAVE_DBUS, 1, [Define if D-BUS should be used in sipe.])])
 234
 235 AC_ARG_ENABLE(gssapi_only,
 236         [AS_HELP_STRING([--enable-gssapi-only],
 237                         [disable all internal authentication code and only use
 238                          GSSAPI for authentication @<:@default=yes@:>@])],
 239         [],
 240         dnl requires Kerberos which provides GSSAPI
 241         [enable_gssapi_only=$with_krb5])
 242 AS_IF([test "x$enable_gssapi_only" != xno],
 243         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 244                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 245                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 246                         enable_gssapi_only=no])
 247         ])
 248 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 249
 250 dnl check for glib
 251 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.18.0])
 252 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.18.0])
 253
 254 dnl check for gmime
 255 PKG_CHECK_MODULES(GMIME, [gmime-3.0 >= 3.0.0],
 256         [ac_have_gmime=yes],
 257         [PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.6.0],
 258                 [ac_have_gmime=yes],
 259                 [ac_have_gmime=no])
 260         ])
 261 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 262 AS_IF([test "x$ac_have_gmime" = xyes],
 263         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 264
 265 dnl check for NSS
 266 AC_ARG_ENABLE(nss,
 267         [AS_HELP_STRING([--enable-nss],
 268                         [use NSS as crypto backend @<:@default=yes@:>@])],
 269         [],
 270         [enable_nss=yes])
 271 AS_IF([test "x$enable_nss" != xno],
 272         [PKG_CHECK_MODULES(NSS, [nss],
 273                 [],
 274                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 275                         [],
 276                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 277                                 [],
 278                                 [enable_nss=no])
 279                         ])
 280                 ])
 281         ])
 282
 283 dnl check for OpenSSL
 284 AC_ARG_ENABLE(openssl,
 285         [AS_HELP_STRING([--enable-openssl],
 286                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 287         [],
 288         [enable_openssl=yes])
 289 AS_IF([test "x$enable_openssl" != xno],
 290         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 291                    [],
 292                    [enable_openssl=no])
 293         ])
 294 AS_IF(
 295         [test "x$enable_nss" != xno],
 296                 [ dnl NSS has priority over OpenSSL
 297                   enable_openssl=no
 298                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 299         [test "x$enable_openssl" != xno],
 300                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 301         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 302 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 303
 304 dnl check for libxml2
 305 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 306
 307 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 308 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 309 ac_save_CFLAGS="$CFLAGS"
 310 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 311 dnl note the [[[ quoting: our code contains []!
 312 AC_RUN_IFELSE(
 313         [AC_LANG_PROGRAM(
 314                 [[
 315 #include <glib.h>
 316 #include <stdio.h>
 317
 318 /* Copied from uuid.c */
 319 typedef struct {
 320    guint32 time_low;
 321    guint16 time_mid;
 322    guint16 time_hi_and_version;
 323    guint8  clock_seq_hi_and_reserved;
 324    guint8  clock_seq_low;
 325    guint8  node[6];
 326 } uuid_t;
 327                 ]],
 328                 [[if (sizeof(uuid_t) == 16) {
 329                         return(0);
 330                  } else {
 331                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 332                         return(1);
 333                  }]])],
 334         [AC_MSG_RESULT(yes)],
 335         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 336
 337 Please notify the SIPE developers.
 338
 339 Copy & paste all lines starting with the line
 340
 341   checking that sizeof(uuid_t) is 16...
 342
 343 to the report and attach the file "config.log".
 344
 345 Compiler information:
 346
 347  host:     $host
 348  build:    $build
 349  compiler: $CC
 350 ])],
 351         [AC_MSG_WARN([cross compiling: not checking])])
 352 CFLAGS="$ac_save_CFLAGS"
 353
 354 dnl build option: OCS2005 client hack
 355 AC_ARG_ENABLE([ocs2005-message-hack],
 356         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 357                                                           which causes "false" not delivered error messages
 358                                                           @<:@default=no@:>@])],
 359         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 360                    [Define to 1 to disable SIP MESSAGE timeout feature.
 361                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 362                     disabling the timeout suppresses "false" error messages])])
 363
 364 dnl build option: purple backend
 365 AC_ARG_ENABLE([purple],
 366         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 367         [],
 368         [enable_purple=yes])
 369 ac_have_appshare=no
 370 ac_have_xdata=no
 371 with_purple_vv=no
 372 AS_IF([test "x$enable_purple" != xno],
 373         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 374                 [purple_pkgconfig=purple-3],
 375                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.7.0],
 376                         [purple_pkgconfig=purple],
 377                         [enable_purple=no])])
 378
 379          AS_IF([test "x$enable_purple" != xno],
 380                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 381
 382                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 383                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 384                  AC_SUBST(PURPLE_MAJOR_VERSION)
 385
 386                  ac_save_CFLAGS="$CFLAGS"
 387                  ac_save_LIBS="$LIBS"
 388                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 389                  LIBS="$LIBS $PURPLE_LIBS"
 390
 391                  dnl check whether enable voice and video support
 392                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 393                        [AC_MSG_CHECKING(for purple voice and video support)
 394                         purple_has_media=no
 395                         AC_RUN_IFELSE(
 396                                 [AC_LANG_PROGRAM([[
 397 #include <media.h>
 398                                         ]],
 399                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 400                                 )],
 401                                 [purple_has_media=yes
 402                                  AC_MSG_RESULT(ok)
 403                                 ],
 404                                 [AC_MSG_RESULT([no - your purple hasn't been compiled with voice and video support.])],
 405                                 [AS_IF([test "x$with_vv" = xyes],
 406                                        [purple_has_media=yes
 407                                         AC_MSG_RESULT([yes - enabling voice and video support for cross compiling on users' request.])],
 408                                        [AC_MSG_RESULT([no - disabled for cross compiling.])])
 409                                 ]
 410                         )
 411                         AS_IF([test "x$purple_has_media" = xyes],
 412                                 [PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 413                                         dnl sipe-media.c uses g_slist_free_full()
 414                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 415                                                 dnl check purple pkgconfig for gstreamer version
 416                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 417                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 418                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 419                                                                 [gstreamer_pkgconfig=1.0])])
 420                                                 AS_IF([test "x$gstreamer_pkgconfig" == x1.0],
 421                                                         [gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 422
 423                                                         AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 424                                                         PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig],
 425                                                                 [PKG_CHECK_MODULES(FARSTREAM, [farstream-0.2],
 426                                                                         [with_purple_vv=yes
 427
 428                                                                          AC_COMPILE_IFELSE(
 429                                                                                  [AC_LANG_PROGRAM([[
 430 #include <media.h>
 431                                                                                         ]],
 432                                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 433                                                                                  )],
 434                                                                                  [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 435                                                                         )],
 436                                                                         [AC_MSG_NOTICE(Farstream required: disabling purple voice and video support)])],
 437                                                                 [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 438                                                         [AC_MSG_NOTICE(your purple hasn't been compiled against GStreamer 1.0: disabling purple voice and video support)])],
 439                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 440                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])
 441                                 ])
 442                        ])
 443
 444                  dnl SRTP and XDATA require media backend
 445                  AS_IF([test "x$with_purple_vv" != xno],
 446                         [AC_LINK_IFELSE(
 447                                 [AC_LANG_PROGRAM([[
 448 #include <media.h>
 449                                         ]],
 450                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 451                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 452                                  )],
 453                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 454                          )
 455
 456                          AC_COMPILE_IFELSE(
 457                                 [AC_LANG_PROGRAM([[
 458 #include <media.h>
 459                                         ]],
 460                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 461                                  )],
 462                                  [dnl libpurple supports raw data RTP connections
 463                                   ac_have_xdata=yes
 464
 465                                   dnl gio-2.0 is mandatory for application sharing support
 466                                   PKG_CHECK_MODULES(GIO, [gio-2.0], [ac_have_appshare=yes])
 467                                  ]
 468                          )
 469                         ],
 470                         [AS_IF([test "x$with_vv" = xyes], dnl explicitly requested by user
 471                                 [AC_ERROR([Voice and video support explicitly requested, but not available])]
 472                          )]
 473                  )
 474
 475                  CFLAGS="$ac_save_CFLAGS"
 476                  LIBS="$ac_save_LIBS"])])
 477 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 478 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 479
 480 dnl build option: telepathy backend
 481 AC_ARG_ENABLE([telepathy],
 482         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 483         [],
 484         [enable_telepathy=yes])
 485 AS_IF([test "x$enable_telepathy" != xno],
 486         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 487                 [dnl GMIME is a build requirement
 488                  AS_IF([test "x$ac_have_gmime" = xyes],
 489                         [],
 490                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 491
 492                  dnl telepathy is based on GObject & D-Bus GLib
 493                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 494                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 495
 496                  dnl telepathy uses from gio:
 497                  dnl  - GIOStream      (>= 2.22.0)
 498                  dnl  - GResolver      (>= 2.22.0)
 499                  dnl  - GSocketClient  (>= 2.32.0)
 500                  dnl  - GTlsConnection (>= 2.28.0)
 501                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 502
 503                 ],
 504                 [enable_telepathy=no])])
 505 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 506
 507 dnl sanity check
 508 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 509         [AC_ERROR(at least one plugin must be selected
 510
 511 If you didn't use a --enable option then please check that you have
 512 the headers for the packages "purple" or "telepathy-glib" installed.
 513 )],
 514         [])
 515
 516 dnl enable voice & video support if any backend supports it
 517 AS_IF([test "x$with_purple_vv" != xno],
 518         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 519 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 520
 521 dnl raw data RTP streams enable Lync file transfer
 522 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 523 AS_IF([test "x$ac_have_xdata" == xyes],
 524         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 525
 526 dnl enable appshare support
 527 AM_CONDITIONAL(SIPE_HAVE_APPSHARE, [test "x$ac_have_appshare" == xyes])
 528 AS_IF([test "x$ac_have_appshare" == xyes],
 529         [AC_DEFINE(HAVE_APPSHARE, 1, [Define to 1 if we have appshare support.])])
 530
 531 dnl telepathy code parts rely on interfaces that require GValueArray. This
 532 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 533 dnl is no backward compatible replacement implementation possible
 534 AS_IF([test "x$enable_telepathy" != xno],
 535         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_30,
 536                    [We need GValueArray for which no replacement is available])])
 537
 538 dnl i18n
 539 AC_MSG_CHECKING([locale_CPPFLAGS])
 540 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 541 AC_SUBST([LOCALE_CPPFLAGS])
 542 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 543 AM_GLIB_GNU_GETTEXT
 544 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 545
 546 dnl codeset
 547 AM_LANGINFO_CODESET
 548
 549 dnl substitutions and generated files
 550 AC_CONFIG_HEADERS([config.h])
 551 AC_CONFIG_FILES([
 552         Makefile
 553         pixmaps/Makefile
 554         m4macros/Makefile
 555         po/Makefile.in
 556         pixmaps/16/Makefile
 557         pixmaps/22/Makefile
 558         pixmaps/24/Makefile
 559         pixmaps/32/Makefile
 560         pixmaps/48/Makefile
 561         pixmaps/scalable/Makefile
 562         src/Makefile
 563         src/core/Makefile
 564         src/api/Makefile
 565         src/purple/Makefile
 566         src/telepathy/Makefile
 567         src/telepathy/data/Makefile
 568         ])
 569
 570 dnl generate files
 571 AC_OUTPUT()
 572
 573 dnl additional info for the user
 574 AS_ECHO()
 575 AS_IF([test "x$enable_purple" = xno],
 576         [AS_ECHO("Not building purple plugin")],
 577         [AS_ECHO("Build purple plugin")
 578          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 579          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 580          AS_ECHO_N("Voice and video: ")
 581          AS_IF([test "x$with_purple_vv" = xno],
 582           [AS_ECHO("disabled")],
 583           [AS_ECHO("enabled")])
 584         ])
 585 AS_ECHO()
 586 AS_IF([test "x$enable_telepathy" = xno],
 587         [AS_ECHO("Not building telepathy plugin")],
 588         [AS_ECHO("Build telepathy plugin")
 589          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 590          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 591 AS_ECHO()
 592 AS_IF([test "x$with_krb5" = xno],
 593         [AS_ECHO("Not building with Kerberos 5 support")],
 594         [AS_ECHO("Build with Kerberos 5 support")
 595          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 596          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 597 AS_ECHO()
 598 AS_IF([test "x$enable_gssapi_only" = xno],
 599         [AS_ECHO("Using internal authentication implementation")],
 600         [AS_ECHO("Using only GSSAPI for authentication")])
 601 AS_ECHO()
 602 AS_IF([test "x$enable_debug" = xno],
 603         [AS_ECHO("Debugging not enabled")],
 604         [AS_ECHO("Build with debugging enabled")
 605          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 606 AS_ECHO()
 607 AS_IF([test "x$QUALITY_CFLAGS" = x],
 608         [AS_ECHO("Compiler checks disabled")],
 609         [AS_ECHO("Build with compiler checks enabled")
 610          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 611 AS_ECHO()
 612 AS_ECHO("configure complete. Now run 'make'")
 613 AS_ECHO()
 614
 615 dnl The End.