configure.ac

   1 dnl ensure recent enough version of Autoconf
   2 AC_PREREQ([2.50])
   3
   4 dnl Use 'VERSION' files to get version.
   5 m4_define([SIPE_VERSION_DATA], m4_include([VERSION]))
   6
   7 dnl Strip off newline characters.
   8 m4_define([SIPE_VERSION],
   9         m4_substr(SIPE_VERSION_DATA,
  10                   [0], m4_decr(m4_len(SIPE_VERSION_DATA))))
  11
  12 dnl homepage
  13 m4_define([SIPE_HOMEPAGE], [http://sipe.sourceforge.net/])
  14
  15 dnl initialize package name, version, bugtracker & homepage
  16 AC_INIT([pidgin-sipe], SIPE_VERSION,
  17         [https://sourceforge.net/p/sipe/bugs/], [],
  18         SIPE_HOMEPAGE)
  19
  20 AC_DEFINE([SIPE_TRANSLATIONS_URL],
  21         ["https://www.transifex.com/stefanb/pidgin-sipe/"],
  22         [URL for submitting translations.])
  23
  24 dnl define optional git commit ID generated by autogen.sh
  25 m4_define([SIPE_GIT_COMMIT], m4_sinclude([GITVERSION]))
  26 AS_IF([test "x"SIPE_GIT_COMMIT != x],
  27         [AC_MSG_NOTICE([set git commit])
  28          AC_DEFINE(PACKAGE_GIT_COMMIT, "SIPE_GIT_COMMIT", [Define to the git commit for this package.])
  29 ])
  30
  31 dnl setup automake and require recent enough version
  32 AM_INIT_AUTOMAKE([1.9 dist-bzip2 dist-xz no-define tar-ustar])
  33
  34 AC_CANONICAL_HOST
  35
  36 dnl set PACKAGE_URL for autoconf < 2.64
  37 AS_IF([test "x${PACKAGE_URL}" = x],
  38         [AC_MSG_NOTICE([set PACKAGE_URL for autoconf < 2.64])
  39          AC_DEFINE(PACKAGE_URL, "SIPE_HOMEPAGE", [Define to the home page for this package.])
  40 ])
  41
  42 dnl set programming language
  43 AC_LANG(C)
  44 AM_PROG_CC_C_O
  45 AC_HEADER_STDC
  46
  47 dnl setup shared library generation
  48 LT_INIT([disable-static])
  49
  50 dnl checks for tools
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AC_PROG_INSTALL
  53 AC_PROG_RANLIB
  54
  55 dnl ******************************
  56 dnl Win32
  57 dnl ******************************
  58 AC_MSG_CHECKING([for Win32])
  59 AS_CASE(["$host"],
  60                 [*-mingw*], [os_win32=yes],
  61                 [os_win32=no])
  62 AC_MSG_RESULT([$os_win32])
  63 AM_CONDITIONAL(SIPE_OS_WIN32, [test "x${os_win32}" = xyes])
  64
  65 dnl checks for header files
  66 AC_CHECK_HEADERS([sys/sockio.h])
  67
  68 dnl checks for library functions
  69 AC_CHECK_FUNCS([])
  70
  71 dnl tell pkgconfig to look in the same prefix where we're installing this to,
  72 dnl as that is likely where libpurple will be found if it is not in the default
  73 dnl pkgconfig path
  74 PKG_CONFIG_PATH="${PKG_CONFIG_PATH}:${libdir}/pkgconfig"
  75 export PKG_CONFIG_PATH
  76
  77 dnl debug mode
  78 AC_ARG_ENABLE(debug,
  79         [AS_HELP_STRING([--enable-debug],
  80                         [compile with debugging support @<:@default=no@:>@])],
  81         [],
  82         [enable_debug=no])
  83
  84 AS_IF([test "x$enable_debug" = xyes],
  85         [AC_DEFINE(DEBUG, 1, [Define if debugging is enabled.])])
  86 AC_SUBST(DEBUG_CFLAGS)
  87
  88 dnl quality check mode
  89 dnl For people who are interested in finding bugs and not hiding them
  90 AC_ARG_ENABLE(quality-check,
  91         [AS_HELP_STRING([--enable-quality-check],
  92                         [compile with compiler checks enabled @<:@default=yes@:>@])],
  93         [],
  94         [enable_quality_check=yes])
  95
  96 AS_IF([test "x$enable_quality_check" = xyes],
  97         [dnl default quality configuration
  98          QUALITY_CFLAGS="$QUALITY_CFLAGS -Werror -Wall"
  99
 100          dnl enable warnings supported by the GCC on the build system
 101          for newflag in \
 102                         "-Wextra" \
 103                         "-Waggregate-return" \
 104                         "-Wcast-align" \
 105                         "-Wdeclaration-after-statement" \
 106                         "-Wdeprecated-declarations" \
 107                         "-Winit-self" \
 108                         "-Wmaybe-uninitialized" \
 109                         "-Wmissing-declarations" \
 110                         "-Wmissing-prototypes" \
 111                         "-Wnested-externs" \
 112                         "-Wpointer-arith" \
 113                         "-Wundef" \
 114                         "-Wunused-but-set-variable" \
 115          ; do
 116                  ac_save_CFLAGS="$CFLAGS"
 117                  AC_MSG_CHECKING([if $CC supports $newflag])
 118                  CFLAGS="$CFLAGS $QUALITY_CFLAGS $newflag"
 119                  AC_COMPILE_IFELSE(
 120                         [AC_LANG_SOURCE([[]])],
 121                         [AC_MSG_RESULT(yes)
 122                          QUALITY_CFLAGS="$QUALITY_CFLAGS $newflag"],
 123                         [AC_MSG_RESULT(no)]
 124                  )
 125                  CFLAGS="$ac_save_CFLAGS"
 126          done
 127         ])
 128 AC_SUBST(QUALITY_CFLAGS)
 129
 130 dnl check for availability of addition linker flags
 131 for newflag in \
 132         "-Wl,-Bsymbolic-functions" \
 133 ; do
 134         ac_save_LDFLAGS="$LDFLAGS"
 135         AC_MSG_CHECKING([if $CC supports $newflag])
 136         LDFLAGS="$LDFLAGS $ADDITIONAL_LDFLAGS $newflag"
 137         AC_LINK_IFELSE(
 138                 [AC_LANG_SOURCE([[
 139 int main(int argc, char *argv[])
 140 {
 141         return(0);
 142 }
 143                  ]])],
 144                 [AC_MSG_RESULT(yes)
 145                  ADDITIONAL_LDFLAGS="$ADDITIONAL_LDFLAGS $newflag"],
 146                 [AC_MSG_RESULT(no)]
 147         )
 148         LDFLAGS="$ac_save_LDFLAGS"
 149 done
 150 AC_SUBST(ADDITIONAL_LDFLAGS)
 151
 152 dnl Check for pkg-config before using it
 153 PKG_PROG_PKG_CONFIG
 154
 155 dnl check for valgrind (optional, only needed for debugging)
 156 PKG_CHECK_MODULES(VALGRIND, [valgrind],
 157         [AC_DEFINE(HAVE_VALGRIND, 1, [Define to 1 if you have the valgrind headers])],
 158         [AC_MSG_RESULT(no)])
 159
 160 dnl build option: with voice & video support (for all backends)
 161 AC_ARG_WITH(vv,
 162         [AC_HELP_STRING([--with-vv],
 163                 [compile with voice and video support @<:@default=check@:>@])],
 164         [AS_IF([test "x$withval" = xyes], [with_vv=check])],
 165         [with_vv=check])
 166
 167 dnl check for Kerberos 5 support
 168 AC_ARG_WITH([krb5],
 169         [AC_HELP_STRING([--with-krb5],
 170                 [compile with Kerberos 5 support @<:@default=check@:>@])],
 171         [AS_IF([test "x$withval" = xyes], [with_krb5=check])],
 172         [with_krb5=check])
 173
 174 AS_IF([test "x$with_krb5" = xno], [], dnl disabled by user
 175       [test "x$with_krb5" = xcheck],  dnl autodetect with krb5-config
 176         [AC_MSG_CHECKING(if Kerberos 5 is available)
 177          AS_IF([AC_RUN_LOG([krb5-config --version])],
 178                 [KRB5_CFLAGS=`krb5-config --cflags 2>/dev/null`
 179                  KRB5_LDFLAGS=""
 180
 181                  dnl same as AC_CHECK_LIB()
 182                  LIBS="$LIBS `krb5-config --libs gssapi 2>/dev/null`"],
 183                 [AC_MSG_RESULT(no)
 184                  with_krb5=no])],
 185       [                               dnl path specified by user
 186         KRB5_CFLAGS="-I${with_krb5}/include"
 187         KRB5_LDFLAGS="-L${with_krb5}/lib"
 188       ])
 189 AS_IF([test "x$with_krb5" != xno],
 190       [ac_save_CFLAGS="$CFLAGS"
 191        ac_save_LDFLAGS="$LDFLAGS"
 192        CFLAGS="$CFLAGS $KRB5_CFLAGS"
 193        LDFLAGS="$LDFLAGS $KRB5_LDFLAGS"
 194        AC_CHECK_HEADERS([gssapi/gssapi.h gssapi/gssapi_krb5.h],
 195                         [],
 196                         [AC_ERROR([GSSAPI headers not found])])
 197        AC_CHECK_FUNC([gss_init_sec_context],
 198                      [],
 199                      [AC_ERROR([GSSAPI libraries not found])])
 200
 201        dnl older GSSAPI releases don't have gss_acquire_cred_with_passwd()
 202        AC_CHECK_HEADER([gssapi/gssapi_ext.h],
 203                        [AC_CHECK_FUNC([gss_acquire_cred_with_password],
 204                                       [AC_DEFINE(HAVE_GSSAPI_PASSWORD_SUPPORT, 1, [Define to 1 if gssapi has gss_acquire_cred_with_passwd()])],
 205                                       [AC_MSG_NOTICE([gss_acquire_cred_with_passwd() required: disabling GSSAPI non-SSO support])])],
 206                        [AC_MSG_NOTICE([gssapi/gssapi_ext.h required: disabling GSSAPI non-SSO support])])
 207
 208        CFLAGS="$ac_save_CFLAGS"
 209        LDFLAGS="$ac_save_LDFLAGS"
 210       ])
 211
 212 AM_CONDITIONAL(SIP_SEC_GSSAPI, [test "x$with_krb5" != xno])
 213 AC_SUBST(KRB5_CFLAGS)
 214 AC_SUBST(KRB5_LDFLAGS)
 215
 216 AC_ARG_ENABLE(gssapi_only,
 217         [AS_HELP_STRING([--enable-gssapi-only],
 218                         [disable all internal authentication code and only use
 219                          GSSAPI for authentication @<:@default=yes@:>@])],
 220         [],
 221         dnl requires Kerberos which provides GSSAPI
 222         [enable_gssapi_only=$with_krb5])
 223 AS_IF([test "x$enable_gssapi_only" != xno],
 224         [AC_CHECK_HEADER([gssapi/gssapi_ntlmssp.h],
 225                        [AC_DEFINE(HAVE_GSSAPI_ONLY, 1, [Define to 1 to enable GSSAPI-only mode])],
 226                        [AC_MSG_NOTICE([gssapi/gssapi_ntlm.h required: falling back to internal authentication implementation])
 227                         enable_gssapi_only=no])
 228         ])
 229 AM_CONDITIONAL(SIP_SEC_GSSAPI_ONLY, [test "x$enable_gssapi_only" != xno])
 230
 231 dnl check for glib
 232 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.12.0])
 233 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0 >= 2.12.0])
 234
 235 dnl check for gmime
 236 dnl See also: https://bugzilla.gnome.org/show_bug.cgi?id=613653#c8
 237 PKG_CHECK_MODULES(GMIME, [gmime-2.6 >= 2.5.2],
 238         [ac_have_gmime=yes],
 239         [PKG_CHECK_MODULES(GMIME, [gmime-2.4 >= 2.4.16],
 240                 [ac_have_gmime=yes],
 241                 [ac_have_gmime=no])
 242 ])
 243 AM_CONDITIONAL(SIPE_MIME_GMIME, [test "x$ac_have_gmime" = xyes])
 244 AS_IF([test "x$ac_have_gmime" = xyes],
 245         [AC_DEFINE(HAVE_GMIME, 1, [Define if gmime should be used in sipe.])])
 246
 247 dnl check for NSS
 248 AC_ARG_ENABLE(nss,
 249         [AS_HELP_STRING([--enable-nss],
 250                         [use NSS as crypto backend @<:@default=yes@:>@])],
 251         [],
 252         [enable_nss=yes])
 253 AS_IF([test "x$enable_nss" != xno],
 254         [PKG_CHECK_MODULES(NSS, [nss],
 255                 [],
 256                 [PKG_CHECK_MODULES(NSS, [mozilla-nss],
 257                         [],
 258                         [PKG_CHECK_MODULES(NSS, [microb-engine-nss],
 259                                 [],
 260                                 [enable_nss=no])
 261                         ])
 262                 ])
 263         ])
 264
 265 dnl check for OpenSSL
 266 AC_ARG_ENABLE(openssl,
 267         [AS_HELP_STRING([--enable-openssl],
 268                         [use OpenSSL as crypto backend @<:@default=yes@:>@])],
 269         [],
 270         [enable_openssl=yes])
 271 AS_IF([test "x$enable_openssl" != xno],
 272         [PKG_CHECK_MODULES(OPENSSL, [libcrypto],
 273                    [],
 274                    [enable_openssl=no])
 275         ])
 276 AS_IF(
 277         [test "x$enable_nss" != xno],
 278                 [ dnl NSS has priority over OpenSSL
 279                   enable_openssl=no
 280                   AC_MSG_NOTICE([using NSS as crypto backend.])],
 281         [test "x$enable_openssl" != xno],
 282                 [AC_MSG_NOTICE([using OpenSSL as crypto backend.])],
 283         [AC_ERROR([nss, mozilla-nss, microb-engine-nss or libcrypto package is required])])
 284 AM_CONDITIONAL(SIPE_OPENSSL, [test "x$enable_openssl" != xno])
 285
 286 dnl check for libxml2
 287 PKG_CHECK_MODULES(LIBXML2, [libxml-2.0])
 288
 289 dnl assumption check: sizof(uuid_t) must be 16 (see uuid.c)
 290 AC_MSG_CHECKING([that sizeof(uuid_t) is 16])
 291 ac_save_CFLAGS="$CFLAGS"
 292 CFLAGS="$CFLAGS $GLIB_CFLAGS $QUALITY_CFLAGS"
 293 dnl note the [[[ quoting: our code contains []!
 294 AC_RUN_IFELSE(
 295         [AC_LANG_PROGRAM(
 296                 [[
 297 #include <glib.h>
 298 #include <stdio.h>
 299
 300 /* Copied from uuid.c */
 301 typedef struct {
 302    guint32 time_low;
 303    guint16 time_mid;
 304    guint16 time_hi_and_version;
 305    guint8  clock_seq_hi_and_reserved;
 306    guint8  clock_seq_low;
 307    guint8  node[6];
 308 } uuid_t;
 309                 ]],
 310                 [[if (sizeof(uuid_t) == 16) {
 311                         return(0);
 312                  } else {
 313                         printf("\n\nOoops, sizeof(uuid_t) is %" G_GSIZE_FORMAT ".\n\n", sizeof(uuid_t));
 314                         return(1);
 315                  }]])],
 316         [AC_MSG_RESULT(yes)],
 317         [AC_MSG_FAILURE([sizeof(uuid_t) is not 16
 318
 319 Please notify the SIPE developers.
 320
 321 Copy & paste all lines starting with the line
 322
 323   checking that sizeof(uuid_t) is 16...
 324
 325 to the report and attach the file "config.log".
 326
 327 Compiler information:
 328
 329  host:     $host
 330  build:    $build
 331  compiler: $CC
 332 ])],
 333         [AC_MSG_WARN([cross compiling: not checking])])
 334 CFLAGS="$ac_save_CFLAGS"
 335
 336 dnl build option: OCS2005 client hack
 337 AC_ARG_ENABLE([ocs2005-message-hack],
 338         [AC_HELP_STRING([--enable-ocs2005-message-hack], [disable message timeout for OCS2005 clients
 339                                                           which causes "false" not delivered error messages
 340                                                           @<:@default=no@:>@])],
 341         [AC_DEFINE([ENABLE_OCS2005_MESSAGE_HACK], [1],
 342                    [Define to 1 to disable SIP MESSAGE timeout feature.
 343                     OCS2005 clients don't seem to acknowledge MESSAGEs and
 344                     disabling the timeout suppresses "false" error messages])])
 345
 346 dnl build option: purple backend
 347 AC_ARG_ENABLE([purple],
 348         [AC_HELP_STRING([--enable-purple], [build purple plugin @<:@default=yes@:>@])],
 349         [],
 350         [enable_purple=yes])
 351 ac_have_xdata=no
 352 with_purple_vv=no
 353 AS_IF([test "x$enable_purple" != xno],
 354         [PKG_CHECK_MODULES(PURPLE, [purple-3],
 355                 [purple_pkgconfig=purple-3],
 356                 [PKG_CHECK_MODULES(PURPLE, [purple >= 2.4.0],
 357                         [purple_pkgconfig=purple],
 358                         [enable_purple=no])])
 359
 360          AS_IF([test "x$enable_purple" != xno],
 361                 [AC_MSG_NOTICE([using package "$purple_pkgconfig".])
 362
 363                  dnl unfortunately PURPLE_MAJOR_VERSION is not exported by purple.m4
 364                  PURPLE_MAJOR_VERSION=`$PKG_CONFIG --modversion $purple_pkgconfig | cut -d. -f 1`
 365                  AC_SUBST(PURPLE_MAJOR_VERSION)
 366
 367                  ac_save_CFLAGS="$CFLAGS"
 368                  ac_save_LIBS="$LIBS"
 369                  CFLAGS="$CFLAGS $PURPLE_CFLAGS $QUALITY_CFLAGS"
 370                  LIBS="$LIBS $PURPLE_LIBS"
 371
 372                  dnl check whether enable voice and video support
 373                  AS_IF([test "x$with_vv" = xno], [], dnl disabled by user
 374                        [test "x$with_vv" = xcheck],  dnl autodetect
 375                          [AC_MSG_CHECKING(for purple voice and video support)
 376                           AC_RUN_IFELSE(
 377                                 [AC_LANG_PROGRAM([[
 378 #include <media.h>
 379                                         ]],
 380                                         [[return (purple_media_get_type() == G_TYPE_NONE ? 1 : 0);]]
 381                                 )],
 382                                 [AC_MSG_RESULT(ok)
 383                                  PKG_CHECK_MODULES(NICE, [nice >= 0.1.0],
 384                                         dnl sipe-media.c uses g_slist_free_full()
 385                                         [PKG_CHECK_MODULES(_SIPE_MEDIA_RECHECK_PLEASE_IGNORE, [$purple_pkgconfig >= 2.8.0],
 386                                                 dnl check purple pkgconfig for gstreamer version
 387                                                 [gstreamer_pkgconfig=`$PKG_CONFIG --variable=gstreamer $purple_pkgconfig`
 388                                                 AS_IF([test "x$gstreamer_pkgconfig" == x],
 389                                                         [AS_IF([test "x$purple_pkgconfig" == xpurple-3],
 390                                                                 [gstreamer_pkgconfig=1.0], [gstreamer_pkgconfig=0.10])])
 391                                                 gstreamer_pkgconfig="gstreamer-$gstreamer_pkgconfig gstreamer-rtp-$gstreamer_pkgconfig"
 392
 393                                                 AC_MSG_NOTICE([using packages "$gstreamer_pkgconfig".])
 394                                                 PKG_CHECK_MODULES(GSTREAMER, [$gstreamer_pkgconfig farstream-0.2],
 395                                                         [with_purple_vv=yes
 396
 397                                                          AC_COMPILE_IFELSE(
 398                                                                 [AC_LANG_PROGRAM([[
 399 #include <media.h>
 400                                                                         ]],
 401                                                                         [[return (PURPLE_MEDIA_NETWORK_PROTOCOL_TCP_PASSIVE);]]
 402                                                                 )],
 403                                                                 [AC_DEFINE(HAVE_PURPLE_NEW_TCP_ENUMS, 1, [Define if libpurple has new TCP enums in media backend.])]
 404                                                         )],
 405                                                         [AC_MSG_NOTICE(GStreamer required: disabling purple voice and video support)])],
 406                                                 [AC_MSG_NOTICE(libpurple >= 2.8.0 required: disabling purple voice and video support)])],
 407                                         [AC_MSG_NOTICE(libnice required: disabling purple voice and video support)])],
 408                                 [AC_MSG_RESULT(no - your purple hasn't been compiled with voice and video support.)],
 409                                 [AC_MSG_WARN([cross compiling: not checking])])
 410                          ])
 411
 412                  dnl SRTP and XDATA require media backend
 413                  AS_IF([test "x$with_purple_vv" != xno],
 414                         [AC_LINK_IFELSE(
 415                                 [AC_LANG_PROGRAM([[
 416 #include <media.h>
 417                                         ]],
 418                                         [[purple_media_set_encryption_parameters(NULL, "", "", "", "", 0);
 419                                           purple_media_set_decryption_parameters(NULL, "", "", "", "", "", 0);]]
 420                                  )],
 421                                  [AC_DEFINE(HAVE_SRTP, 1, [Define if we have SRTP support in media backend.])]
 422                          )
 423
 424                          AC_COMPILE_IFELSE(
 425                                 [AC_LANG_PROGRAM([[
 426 #include <media.h>
 427                                         ]],
 428                                         [[return (PURPLE_MEDIA_APPLICATION);]]
 429                                  )],
 430                                  [dnl libpurple supports raw data RTP connections
 431                                   ac_have_xdata=yes]
 432                          )
 433                         ])
 434
 435                  CFLAGS="$ac_save_CFLAGS"
 436                  LIBS="$ac_save_LIBS"])])
 437 AM_CONDITIONAL(SIPE_INCLUDE_PURPLE, [test "x$enable_purple" != xno])
 438 AM_CONDITIONAL(SIPE_PURPLE3, [test "x$purple_pkgconfig" = xpurple-3])
 439
 440 dnl build option: telepathy backend
 441 AC_ARG_ENABLE([telepathy],
 442         [AC_HELP_STRING([--enable-telepathy], [build telepathy plugin @<:@default=yes@:>@])],
 443         [],
 444         [enable_telepathy=yes])
 445 AS_IF([test "x$enable_telepathy" != xno],
 446         [PKG_CHECK_MODULES(TELEPATHY_GLIB, [telepathy-glib >= 0.18.0],
 447                 [dnl GMIME is a build requirement
 448                  AS_IF([test "x$ac_have_gmime" = xyes],
 449                         [],
 450                         [AC_ERROR(GMIME package is required for telepathy plugin)])
 451
 452                  dnl telepathy is based on GObject & D-Bus GLib
 453                  PKG_CHECK_MODULES(GOBJECT, [gobject-2.0])
 454                  PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1])
 455
 456                  dnl telepathy uses from gio:
 457                  dnl  - GIOStream      (>= 2.22.0)
 458                  dnl  - GResolver      (>= 2.22.0)
 459                  dnl  - GSocketClient  (>= 2.32.0)
 460                  dnl  - GTlsConnection (>= 2.28.0)
 461                  PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.32.0])
 462
 463                 ],
 464                 [enable_telepathy=no])])
 465 AM_CONDITIONAL(SIPE_INCLUDE_TELEPATHY, [test "x$enable_telepathy" != xno])
 466
 467 dnl sanity check
 468 AS_IF([test "x$enable_purple" = xno -a "x$enable_telepathy" = xno],
 469         [AC_ERROR(at least one plugin must be selected
 470
 471 If you didn't use a --enable option then please check that you have
 472 the headers for the packages "purple" or "telepathy-glib" installed.
 473 )],
 474         [])
 475
 476 dnl enable voice & video support if any backend supports it
 477 AS_IF([test "x$with_purple_vv" != xno],
 478         [AC_DEFINE(HAVE_VV, 1, [Define if voice & video is enabled.])])
 479 AM_CONDITIONAL(SIPE_WITH_VV, [test "x$with_purple_vv" != xno])
 480
 481 dnl raw data RTP streams enable Lync file transfer
 482 AM_CONDITIONAL(SIPE_HAVE_XDATA, [test "x$ac_have_xdata" == xyes])
 483 AS_IF([test "x$ac_have_xdata" == xyes],
 484         [AC_DEFINE(HAVE_XDATA, 1, [Define if we have raw data RTP in media backend.])])
 485
 486 dnl these code parts rely on interfaces that require GValueArray. This
 487 dnl type has been declared "deprectated" in glib-2.0 >= 2.32.0, but there
 488 dnl is no backward compatible replacement implementation possible
 489 AS_IF([test "x$with_purple_vv" != xno -o "x$enable_telepathy" != xno],
 490         [AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_28,
 491                    [We need GValueArray for which no replacement is available])])
 492
 493 dnl i18n
 494 AC_MSG_CHECKING([locale_CPPFLAGS])
 495 LOCALE_CPPFLAGS='-DLOCALEDIR=\"$(datadir)/locale\"'
 496 AC_SUBST([LOCALE_CPPFLAGS])
 497 AC_MSG_RESULT([$LOCALE_CPPFLAGS])
 498 AM_GLIB_GNU_GETTEXT
 499 AC_SUBST(GETTEXT_PACKAGE, "${PACKAGE_NAME}")
 500
 501 dnl codeset
 502 AM_LANGINFO_CODESET
 503
 504 dnl substitutions and generated files
 505 AC_CONFIG_HEADERS([config.h])
 506 AC_CONFIG_FILES([
 507         Makefile
 508         pixmaps/Makefile
 509         m4macros/Makefile
 510         po/Makefile.in
 511         pixmaps/16/Makefile
 512         pixmaps/22/Makefile
 513         pixmaps/24/Makefile
 514         pixmaps/32/Makefile
 515         pixmaps/48/Makefile
 516         pixmaps/scalable/Makefile
 517         src/Makefile
 518         src/core/Makefile
 519         src/api/Makefile
 520         src/purple/Makefile
 521         src/telepathy/Makefile
 522         src/telepathy/data/Makefile
 523         ])
 524
 525 dnl generate files
 526 AC_OUTPUT()
 527
 528 dnl additional info for the user
 529 AS_ECHO()
 530 AS_IF([test "x$enable_purple" = xno],
 531         [AS_ECHO("Not building purple plugin")],
 532         [AS_ECHO("Build purple plugin")
 533          AS_ECHO("PURPLE_CFLAGS  : $PURPLE_CFLAGS")
 534          AS_ECHO("PURPLE_LIBS    : $PURPLE_LIBS")
 535          AS_ECHO_N("Voice and video: ")
 536          AS_IF([test "x$with_purple_vv" = xno],
 537           [AS_ECHO("disabled")],
 538           [AS_ECHO("enabled")])
 539         ])
 540 AS_ECHO()
 541 AS_IF([test "x$enable_telepathy" = xno],
 542         [AS_ECHO("Not building telepathy plugin")],
 543         [AS_ECHO("Build telepathy plugin")
 544          AS_ECHO("TELEPATHY_GLIB_CFLAGS: $TELEPATHY_GLIB_CFLAGS")
 545          AS_ECHO("TELEPATHY_GLIB_LIBS  : $TELEPATHY_GLIB_LIBS")])
 546 AS_ECHO()
 547 AS_IF([test "x$with_krb5" = xno],
 548         [AS_ECHO("Not building with Kerberos 5 support")],
 549         [AS_ECHO("Build with Kerberos 5 support")
 550          AS_ECHO("KRB5_CFLAGS    : $KRB5_CFLAGS")
 551          AS_ECHO("KRB5_LDFLAGS   : $KRB5_LDFLAGS")])
 552 AS_ECHO()
 553 AS_IF([test "x$enable_gssapi_only" = xno],
 554         [AS_ECHO("Using internal authentication implementation")],
 555         [AS_ECHO("Using only GSSAPI for authentication")])
 556 AS_ECHO()
 557 AS_IF([test "x$enable_debug" = xno],
 558         [AS_ECHO("Debugging not enabled")],
 559         [AS_ECHO("Build with debugging enabled")
 560          AS_ECHO("DEBUG_CFLAGS   : $DEBUG_CFLAGS")])
 561 AS_ECHO()
 562 AS_IF([test "x$QUALITY_CFLAGS" = x],
 563         [AS_ECHO("Compiler checks disabled")],
 564         [AS_ECHO("Build with compiler checks enabled")
 565          AS_ECHO("QUALITY_CFLAGS : $QUALITY_CFLAGS")])
 566 AS_ECHO()
 567 AS_ECHO("configure complete. Now run 'make'")
 568 AS_ECHO()
 569
 570 dnl The End.