HelpSource/Classes/Gendy1.schelp

   1 class:: Gendy1
   2 summary:: Dynamic stochastic synthesis generator.
   3 related:: Classes/Gendy2, Classes/Gendy3
   4 categories::  UGens>Generators>Stochastic
   5
   6
   7 Description::
   8
   9 An implementation of the dynamic stochastic synthesis generator conceived
  10 by Iannis Xenakis and described in  emphasis::Formalized Music (1992, Stuyvesant, NY: Pendragon Press) chapter 9 (pp 246-254) and chapters 13 and 14 (pp 289-322)::.
  11
  12 The BASIC program in the book was written by Marie-Helene Serra so I
  13 think it helpful to credit her too.
  14
  15 The program code has been adapted to avoid infinities in the probability
  16 distribution functions.
  17
  18 The distributions are hard-coded in C but there is an option to have new
  19 amplitude or time breakpoints sampled from a continuous controller input.
  20
  21 subsection:: Technical notes
  22 X's plan as described in chapter 13 allows the 12 segments in the period to be successively modified with each new period.
  23 Yet the period is allowed to vary as the sum of the segment durations, as figure 1 demonstrates.
  24 We can setup some memory of n (conventionally 12) points, or even simply vary successively a single point's ordinate and
  25 duration. There are thus various schemes available to us. In one, fix period T and only move the (ti, Ei) within the period. In another, have a memory of 12 segments but allow continuous modification of the inter point intervals and the amplitudes.
  26 In yet another, just have one point and random walk its amplitude and duration based on the probability distribution.
  27 In this implementation I allow the user to initialise a certain number of memory points which is up to them.
  28 To restrict the period to be unchanging, you must set rate variation to zero (dscale=0).
  29
  30 SuperCollider implementation by Nick Collins.
  31
  32
  33 classmethods::
  34
  35 method::ar, kr
  36
  37 discussion::
  38 All parameters can be modulated at control rate except for code::initCPs:: which is used only at initialisation.
  39
  40 argument::ampdist
  41
  42 Choice of probability distribution for the next perturbation of
  43 the amplitude of a control point.
  44
  45 The distributions are (adapted from the GENDYN program in Formalized Music):
  46
  47 table::
  48 ## 0: || LINEAR.
  49 ## 1: || CAUCHY.
  50 ## 2: || LOGIST.
  51 ## 3: || HYPERBCOS.
  52 ## 4: || ARCSINE.
  53 ## 5: || EXPON.
  54 ## 6: || SINUS.
  55 ::
  56
  57 Where the sinus (Xenakis' name) is in this implementation taken
  58 as sampling from a third party oscillator. See example below.
  59
  60
  61 argument::durdist
  62
  63 Choice of distribution for the perturbation of the current inter
  64 control point duration.
  65
  66
  67 argument::adparam
  68
  69 A parameter for the shape of the amplitude probability
  70 distribution, requires values in the range 0.0001 to 1 (there are
  71 safety checks in the code so don't worry too much if you want to
  72 modulate!).
  73
  74
  75 argument::ddparam
  76
  77 A parameter for the shape of the duration probability
  78 distribution, requires values in the range 0.0001 to 1.
  79
  80
  81 argument::minfreq
  82
  83 Minimum allowed frequency of oscillation for the Gendy1
  84 oscillator, so gives the largest period the duration is allowed
  85 to take on.
  86
  87
  88 argument::maxfreq
  89
  90 Maximum allowed frequency of oscillation for the Gendy1
  91 oscillator, so gives the smallest period the duration is allowed
  92 to take on.
  93
  94
  95 argument::ampscale
  96
  97 Normally 0.0 to 1.0, multiplier for the distribution's delta
  98 value for amplitude. An ampscale of 1.0 allows the full range
  99 of  -1 to 1 for a change of amplitude.
 100
 101
 102 argument::durscale
 103
 104 Normally 0.0 to 1.0, multiplier for the distribution's delta
 105 value for duration. An ampscale of 1.0 allows the full range of
 106 -1 to 1 for a change of duration.
 107
 108
 109 argument::initCPs
 110
 111 Initialise the number of control points in the memory.
 112 Xenakis specifies 12. There would be this number of control
 113 points per cycle of the oscillator, though the oscillator's
 114 period will constantly change due to the duration distribution.
 115
 116
 117 argument::knum
 118
 119 Current number of utilised control points, allows modulation.
 120
 121
 122 Examples::
 123
 124 warning::
 125 if you have lots of CPs and you have fast frequencies, the CPU cost goes up a lot because a new CP move happens every sample!
 126 ::
 127
 128 code::
 129 //defaults
 130 {Pan2.ar(Gendy1.ar)}.play
 131
 132 //wandering bass/ powerline
 133 {Pan2.ar(Gendy1.ar(1,1,1.0,1.0,30,100,0.3,0.05,5))}.play
 134
 135 //play me
 136 {Pan2.ar(RLPF.ar(Gendy1.ar(2,3,minfreq:20,maxfreq:MouseX.kr(100,1000),durscale:0.0,initCPs:40),500,0.3,0.2),0.0)}.play
 137
 138 //scream! - careful with your ears for this one!
 139 (
 140 {
 141     var mx, my;
 142
 143     mx= MouseX.kr(220,440);
 144     my= MouseY.kr(0.0,1.0);
 145
 146     Pan2.ar(Gendy1.ar(2,3,1,1,minfreq:mx, maxfreq:8*mx, ampscale:my, durscale:my, initCPs:7, mul:0.3), 0.0)
 147 }.play
 148 )
 149
 150
 151 //1 CP = random noise effect
 152 {Pan2.ar(Gendy1.ar(initCPs:1))}.play
 153
 154 //2 CPs = suudenly an oscillator (though a fast modulating one here)
 155 {Pan2.ar(Gendy1.ar(initCPs:2))}.play
 156
 157
 158 //used as an LFO
 159 (
 160 {
 161     Pan2.ar(
 162         SinOsc.ar(
 163             Gendy1.kr(2, 4,
 164                 SinOsc.kr(0.1,0,0.49,0.51),
 165                 SinOsc.kr(0.13,0,0.49,0.51),
 166                 3.4, 3.5,
 167                 SinOsc.kr(0.17,0,0.49,0.51),
 168                 SinOsc.kr(0.19,0,0.49,0.51),
 169                 10,10,50, 350),
 170         0, 0.3),
 171     0.0)
 172 }.play
 173 )
 174
 175 //wasp
 176 {Pan2.ar(Gendy1.ar(0, 0, SinOsc.kr(0.1, 0, 0.1, 0.9),1.0, 50,1000, 1,0.005, 12, 12, 0.2), 0.0)}.play
 177
 178
 179 //modulate distributions
 180 //change of pitch as distributions change the duration structure and spectrum
 181 {Pan2.ar(Gendy1.ar(MouseX.kr(0,7),MouseY.kr(0,7),mul:0.2), 0.0)}.play
 182
 183
 184 //modulate num of CPs
 185 {Pan2.ar(Gendy1.ar(knum:MouseX.kr(1,13),mul:0.2), 0.0)}.play
 186
 187
 188 (//Gendy into Gendy...with cartoon side effects
 189 {Pan2.ar(Gendy1.ar(
 190     maxfreq:Gendy1.kr(5,4,0.3, 0.7, 0.1, MouseY.kr(0.1,10), 1.0, 1.0, 5,5, 500, 600),
 191     knum:MouseX.kr(1,13),mul:0.2), 0.0)
 192 }.play
 193 )
 194
 195 //use SINUS to track any oscillator and take CP positions from it, use adparam and ddparam as the inputs to sample
 196 {Pan2.ar(Gendy1.ar(6,6,LFPulse.kr(100, 0, 0.4, 1.0), SinOsc.kr(30, 0, 0.5),mul:0.2), 0.0)}.play
 197
 198
 199 //try out near the corners especially
 200 (
 201 {Pan2.ar(Gendy1.ar(6,6,LFPulse.kr(MouseX.kr(0,200), 0, 0.4, 1.0),
 202     SinOsc.kr(MouseY.kr(0,200), 0, 0.5),mul:0.2), 0.0)}.play
 203 )
 204
 205 //texture
 206 (
 207 {
 208 Mix.fill(10,{
 209 var freq;
 210
 211 freq= rrand(130,160.3);
 212 Pan2.ar(SinOsc.ar(Gendy1.ar(6.rand,6.rand,SinOsc.kr(0.1,0,0.49,0.51),
 213     SinOsc.kr(0.13,0,0.49,0.51),freq ,freq, SinOsc.kr(0.17,0,0.49,0.51),
 214     SinOsc.kr(0.19,0,0.49,0.51), 12, 12, 200, 400), 0, 0.1), 1.0.rand2)
 215 });
 216 }.play
 217 )
 218
 219 //wahhhhhhhh- try durscale 10.0 and 0.0 too
 220 (
 221 {Pan2.ar(
 222 CombN.ar(
 223 Resonz.ar(
 224 Gendy1.ar(2,3,minfreq:1, maxfreq:MouseX.kr(10,700), durscale:0.1, initCPs:10),
 225 MouseY.kr(50,1000), 0.1)
 226 ,0.1,0.1,5, 0.6
 227 )
 228 , 0.0)}.play
 229 )
 230
 231 //overkill
 232 (
 233 {
 234 var n;
 235 n=10;
 236
 237 Mix.fill(n,{
 238 var freq, numcps;
 239
 240 freq= rrand(130,160.3);
 241 numcps= rrand(2,20);
 242 Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq ,freq, 1.0.rand, 1.0.rand, numcps,
 243     SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 244 });
 245 }.play
 246 )
 247
 248 //another traffic moment
 249 (
 250 {
 251     var n;
 252     n=10;
 253
 254     Resonz.ar(
 255     Mix.fill(n,{
 256     var freq, numcps;
 257
 258     freq= rrand(50,560.3);
 259     numcps= rrand(2,20);
 260     Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq ,freq, 1.0.rand, 1.0.rand, numcps,
 261         SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 262     })
 263     ,MouseX.kr(100,2000), MouseY.kr(0.01,1.0))
 264     ;
 265 }.play
 266 )
 267
 268 (
 269 {
 270 var n;
 271 n=15;
 272
 273 Out.ar(0,
 274 Resonz.ar(
 275 Mix.fill(n,{
 276 var freq, numcps;
 277
 278 freq= rrand(330,460.3);
 279 numcps= rrand(2,20);
 280 Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq,MouseX.kr(freq,2*freq), 1.0.rand, 1.0.rand, numcps,
 281     SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 282 })
 283 ,MouseX.kr(100,2000), MouseY.kr(0.01,1.0))
 284 )
 285
 286 }.play;
 287 )
 288 ::
 289