HelpSource/Classes/Gendy1.schelp

   1 class:: Gendy1
   2 summary:: Dynamic stochastic synthesis generator.
   3 related:: Classes/Gendy2, Classes/Gendy3
   4 categories::  UGens>Generators>Stochastic
   5
   6
   7 Description::
   8
   9 An implementation of the dynamic stochastic synthesis generator conceived
  10 by Iannis Xenakis and described in  emphasis::Formalized Music (1992, Stuyvesant, NY: Pendragon Press) chapter 9 (pp 246-254) and chapters 13 and 14 (pp 289-322)::.
  11
  12 The BASIC program in the book was written by Marie-Helene Serra so I
  13 think it helpful to credit her too.
  14
  15 The program code has been adapted to avoid infinities in the probability
  16 distribution functions.
  17
  18 The distributions are hard-coded in C but there is an option to have new
  19 amplitude or time breakpoints sampled from a continuous controller input.
  20
  21 subsection:: Technical notes
  22 X's plan as described in chapter 13 allows the 12 segments in the period to be successively modified with each new period.
  23 Yet the period is allowed to vary as the sum of the segment durations, as figure 1 demonstrates.
  24 We can setup some memory of n (conventionally 12) points, or even simply vary successively a single point's ordinate and
  25 duration. There are thus various schemes available to us. In one, fix period T and only move the (ti, Ei) within the period. In another, have a memory of 12 segments but allow continuous modification of the inter point intervals and the amplitudes.
  26 In yet another, just have one point and random walk its amplitude and duration based on the probability distribution.
  27 In this implementation I allow the user to initialise a certain number of memory points which is up to them.
  28 To restrict the period to be unchanging, you must set rate variation to zero (dscale=0).
  29
  30 SuperCollider implementation by Nick Collins.
  31
  32
  33 classmethods::
  34
  35 method::ar, kr
  36
  37 argument::ampdist
  38
  39 Choice of probability distribution for the next perturbation of
  40 the amplitude of a control point.
  41
  42 The distributions are (adapted from the GENDYN program in Formalized Music):
  43
  44 table::
  45 ## 0: || LINEAR.
  46 ## 1: || CAUCHY.
  47 ## 2: || LOGIST.
  48 ## 3: || HYPERBCOS.
  49 ## 4: || ARCSINE.
  50 ## 5: || EXPON.
  51 ## 6: || SINUS.
  52 ::
  53
  54 Where the sinus (Xenakis' name) is in this implementation taken
  55 as sampling from a third party oscillator. See example below.
  56
  57
  58 argument::durdist
  59
  60 Choice of distribution for the perturbation of the current inter
  61 control point duration.
  62
  63
  64 argument::adparam
  65
  66 A parameter for the shape of the amplitude probability
  67 distribution, requires values in the range 0.0001 to 1 (there are
  68 safety checks in the code so don't worry too much if you want to
  69 modulate!).
  70
  71
  72 argument::ddparam
  73
  74 A parameter for the shape of the duration probability
  75 distribution, requires values in the range 0.0001 to 1.
  76
  77
  78 argument::minfreq
  79
  80 Minimum allowed frequency of oscillation for the Gendy1
  81 oscillator, so gives the largest period the duration is allowed
  82 to take on.
  83
  84
  85 argument::maxfreq
  86
  87 Maximum allowed frequency of oscillation for the Gendy1
  88 oscillator, so gives the smallest period the duration is allowed
  89 to take on.
  90
  91
  92 argument::ampscale
  93
  94 Normally 0.0 to 1.0, multiplier for the distribution's delta
  95 value for amplitude. An ampscale of 1.0 allows the full range
  96 of  -1 to 1 for a change of amplitude.
  97
  98
  99 argument::durscale
 100
 101 Normally 0.0 to 1.0, multiplier for the distribution's delta
 102 value for duration. An ampscale of 1.0 allows the full range of
 103 -1 to 1 for a change of duration.
 104
 105
 106 argument::initCPs
 107
 108 Initialise the number of control points in the memory.
 109 Xenakis specifies 12. There would be this number of control
 110 points per cycle of the oscillator, though the oscillator's
 111 period will constantly change due to the duration distribution.
 112
 113
 114 argument::knum
 115
 116 Current number of utilised control points, allows modulation.
 117
 118 discussion::
 119 All parameters can be modulated at control rate except for code::initCPs:: which is used only at initialisation.
 120
 121 Examples::
 122
 123 warning::
 124 if you have lots of CPs and you have fast frequencies, the CPU cost goes up a lot because a new CP move happens every sample!
 125 ::
 126
 127 code::
 128 //defaults
 129 {Pan2.ar(Gendy1.ar)}.play
 130
 131 //wandering bass/ powerline
 132 {Pan2.ar(Gendy1.ar(1,1,1.0,1.0,30,100,0.3,0.05,5))}.play
 133
 134 //play me
 135 {Pan2.ar(RLPF.ar(Gendy1.ar(2,3,minfreq:20,maxfreq:MouseX.kr(100,1000),durscale:0.0,initCPs:40),500,0.3,0.2),0.0)}.play
 136
 137 //scream! - careful with your ears for this one!
 138 (
 139 {
 140     var mx, my;
 141
 142     mx= MouseX.kr(220,440);
 143     my= MouseY.kr(0.0,1.0);
 144
 145     Pan2.ar(Gendy1.ar(2,3,1,1,minfreq:mx, maxfreq:8*mx, ampscale:my, durscale:my, initCPs:7, mul:0.3), 0.0)
 146 }.play
 147 )
 148
 149
 150 //1 CP = random noise effect
 151 {Pan2.ar(Gendy1.ar(initCPs:1))}.play
 152
 153 //2 CPs = suudenly an oscillator (though a fast modulating one here)
 154 {Pan2.ar(Gendy1.ar(initCPs:2))}.play
 155
 156
 157 //used as an LFO
 158 (
 159 {
 160     Pan2.ar(
 161         SinOsc.ar(
 162             Gendy1.kr(2, 4,
 163                 SinOsc.kr(0.1,0,0.49,0.51),
 164                 SinOsc.kr(0.13,0,0.49,0.51),
 165                 3.4, 3.5,
 166                 SinOsc.kr(0.17,0,0.49,0.51),
 167                 SinOsc.kr(0.19,0,0.49,0.51),
 168                 10,10,50, 350),
 169         0, 0.3),
 170     0.0)
 171 }.play
 172 )
 173
 174 //wasp
 175 {Pan2.ar(Gendy1.ar(0, 0, SinOsc.kr(0.1, 0, 0.1, 0.9),1.0, 50,1000, 1,0.005, 12, 12, 0.2), 0.0)}.play
 176
 177
 178 //modulate distributions
 179 //change of pitch as distributions change the duration structure and spectrum
 180 {Pan2.ar(Gendy1.ar(MouseX.kr(0,7),MouseY.kr(0,7),mul:0.2), 0.0)}.play
 181
 182
 183 //modulate num of CPs
 184 {Pan2.ar(Gendy1.ar(knum:MouseX.kr(1,13),mul:0.2), 0.0)}.play
 185
 186
 187 (//Gendy into Gendy...with cartoon side effects
 188 {Pan2.ar(Gendy1.ar(
 189     maxfreq:Gendy1.kr(5,4,0.3, 0.7, 0.1, MouseY.kr(0.1,10), 1.0, 1.0, 5,5, 500, 600),
 190     knum:MouseX.kr(1,13),mul:0.2), 0.0)
 191 }.play
 192 )
 193
 194 //use SINUS to track any oscillator and take CP positions from it, use adparam and ddparam as the inputs to sample
 195 {Pan2.ar(Gendy1.ar(6,6,LFPulse.kr(100, 0, 0.4, 1.0), SinOsc.kr(30, 0, 0.5),mul:0.2), 0.0)}.play
 196
 197
 198 //try out near the corners especially
 199 (
 200 {Pan2.ar(Gendy1.ar(6,6,LFPulse.kr(MouseX.kr(0,200), 0, 0.4, 1.0),
 201     SinOsc.kr(MouseY.kr(0,200), 0, 0.5),mul:0.2), 0.0)}.play
 202 )
 203
 204 //texture
 205 (
 206 {
 207 Mix.fill(10,{
 208 var freq;
 209
 210 freq= rrand(130,160.3);
 211 Pan2.ar(SinOsc.ar(Gendy1.ar(6.rand,6.rand,SinOsc.kr(0.1,0,0.49,0.51),
 212     SinOsc.kr(0.13,0,0.49,0.51),freq ,freq, SinOsc.kr(0.17,0,0.49,0.51),
 213     SinOsc.kr(0.19,0,0.49,0.51), 12, 12, 200, 400), 0, 0.1), 1.0.rand2)
 214 });
 215 }.play
 216 )
 217
 218 //wahhhhhhhh- try durscale 10.0 and 0.0 too
 219 (
 220 {Pan2.ar(
 221 CombN.ar(
 222 Resonz.ar(
 223 Gendy1.ar(2,3,minfreq:1, maxfreq:MouseX.kr(10,700), durscale:0.1, initCPs:10),
 224 MouseY.kr(50,1000), 0.1)
 225 ,0.1,0.1,5, 0.6
 226 )
 227 , 0.0)}.play
 228 )
 229
 230 //overkill
 231 (
 232 {
 233 var n;
 234 n=10;
 235
 236 Mix.fill(n,{
 237 var freq, numcps;
 238
 239 freq= rrand(130,160.3);
 240 numcps= rrand(2,20);
 241 Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq ,freq, 1.0.rand, 1.0.rand, numcps,
 242     SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 243 });
 244 }.play
 245 )
 246
 247 //another traffic moment
 248 (
 249 {
 250     var n;
 251     n=10;
 252
 253     Resonz.ar(
 254     Mix.fill(n,{
 255     var freq, numcps;
 256
 257     freq= rrand(50,560.3);
 258     numcps= rrand(2,20);
 259     Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq ,freq, 1.0.rand, 1.0.rand, numcps,
 260         SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 261     })
 262     ,MouseX.kr(100,2000), MouseY.kr(0.01,1.0))
 263     ;
 264 }.play
 265 )
 266
 267 (
 268 {
 269 var n;
 270 n=15;
 271
 272 Out.ar(0,
 273 Resonz.ar(
 274 Mix.fill(n,{
 275 var freq, numcps;
 276
 277 freq= rrand(330,460.3);
 278 numcps= rrand(2,20);
 279 Pan2.ar(Gendy1.ar(6.rand,6.rand,1.0.rand,1.0.rand,freq,MouseX.kr(freq,2*freq), 1.0.rand, 1.0.rand, numcps,
 280     SinOsc.kr(exprand(0.02,0.2), 0, numcps/2, numcps/2), 0.5/(n.sqrt)), 1.0.rand2)
 281 })
 282 ,MouseX.kr(100,2000), MouseY.kr(0.01,1.0))
 283 )
 284
 285 }.play;
 286 )
 287 ::
 288