HelpSource/Classes/Convolution2L.schelp

   1 class:: Convolution2L
   2 summary:: Real-time convolver with linear interpolation
   3 related:: Classes/Convolution, Classes/Convolution2, Classes/Convolution3, Classes/StereoConvolution2L
   4 categories::  UGens>FFT, UGens>Convolution
   5
   6 Description::
   7 Strict convolution with fixed kernel which can be updated using a trigger signal. There is a linear crossfade between the buffers upon change.
   8
   9 See emphasis:: Steven W Smith, The Scientist and Engineer's Guide to Digital Signal Processing: chapter 18:: -
  10 http://www.dspguide.com/ch18.htm
  11
  12 classmethods::
  13 private:: categories
  14
  15 method::ar
  16
  17 argument::in
  18 processing target
  19
  20 argument::kernel
  21 buffer index for the fixed kernel, may be modulated in combination with the trigger
  22
  23 argument::trigger
  24 update the kernel on a change from <=0 to >0
  25
  26 argument::framesize
  27 size of FFT frame, must be a power of two. Convolution uses twice this number internally, maximum value you can give this argument is 2^16=65536. Note that it gets progressively more expensive to run for higher powers! 512, 1024, 2048, 4096 standard.
  28
  29 argument::crossfade
  30 The number of periods over which a crossfade is made. The default is 1. This must be an integer.
  31
  32
  33 Examples::
  34
  35 code::
  36 (// allocate three buffers
  37 b = Buffer.alloc(s, 2048);
  38 c = Buffer.alloc(s, 2048);
  39 d = Buffer.alloc(s, 2048);
  40
  41 b.zero;
  42 c.zero;
  43 d.zero;
  44 )
  45
  46 (
  47 50.do({ |it| c.set(20*it+10, 1.0.rand); });
  48 3.do({ |it| b.set(400*it+100, 1); });
  49 20.do({ |it| d.set(40*it+20, 1); });
  50 )
  51 ::
  52 code::
  53 (
  54 SynthDef(\conv_test, { arg kernel, t_trig=0;
  55         var input;
  56
  57         input=Impulse.ar(1);
  58
  59         // must have power of two framesize
  60         Out.ar(0, Convolution2L.ar(input, kernel, t_trig, 2048, 1, 0.5));
  61 }).add
  62 )
  63
  64 x = Synth(\conv_test, [\kernel, b]);
  65
  66 // changing the buffer number:
  67 x.set(\kernel, c);
  68 x.set(\t_trig, 1); // after this trigger, the change will take effect.
  69 x.set(\kernel, d);
  70 x.set(\t_trig, 1); // after this trigger, the change will take effect.
  71
  72 d.zero;
  73 40.do({ |it| d.set(20*it+10, 1); });// changing the buffers' contents
  74 x.set(\t_trig, 1); // after this trigger, the change will take effect.
  75
  76 x.set(\kernel, b);
  77 x.set(\t_trig, 1); // after this trigger, the change will take effect.
  78
  79 x.free;
  80 ::
  81
  82 code::
  83 // longer crossfade
  84 (
  85 SynthDef( \conv_test2, { arg kernel, t_trig=0;
  86         var input;
  87
  88         input=Impulse.ar(1);
  89
  90         // must have power of two framesize
  91         Out.ar(0, Convolution2L.ar(input, kernel, t_trig, 2048, 5, 0.5));
  92 }).add
  93 )
  94
  95 x = Synth(\conv_test2, [\kernel, b]);
  96
  97 // changing the buffer number:
  98 x.set(\kernel, c);
  99 x.set(\t_trig, 1); // after this trigger, the change will take effect.
 100 x.set(\kernel, d);
 101 x.set(\t_trig, 1); // after this trigger, the change will take effect.
 102
 103 d.zero;
 104 40.do({ |it| d.set(20*it+10, 1); });// changing the buffers' contents
 105 x.set(\t_trig, 1); // after this trigger, the change will take effect.
 106
 107 x.set(\kernel, b);
 108 x.set(\t_trig, 1); // after this trigger, the change will take effect.
 109
 110 x.free;
 111 ::
 112
 113 code::
 114 // next example
 115
 116 b = Buffer.read(s, Help.dir +/+ "sounds/a11wlk01.wav");
 117
 118 (
 119         { var input, kernel;
 120
 121         input= SoundIn.ar(0);
 122
 123         // must have power of two framesize
 124         Convolution2L.ar(input, b, 0, 512, 1, 0.5);
 125         }.play;
 126
 127 )
 128 ::
 129
 130 code::
 131 // another example
 132
 133 (
 134 // must have power of two framesize- FFT size will be sorted by Convolution2 to be double this
 135 // maximum is currently a=8192 for FFT of size 16384
 136 a=2048;
 137 // kernel buffer
 138 g = Buffer.alloc(s, a, 1);
 139 )
 140
 141 (
 142 g.set(0, 1.0);
 143 100.do({arg i; g.set(a.rand, (i+1).reciprocal)});
 144 )
 145
 146 (
 147 // random impulse response
 148
 149         {
 150         var input, inputAmp, threshhold, gate;
 151
 152         input = SoundIn.ar(0);
 153         inputAmp = Amplitude.kr(input);
 154         threshhold = 0.02;      // noise gating threshold
 155         gate = Lag.kr(inputAmp > threshhold, 0.01);
 156
 157         Convolution2L.ar(input*gate, g, 0, a, 1, 0.5);
 158         }.play;
 159
 160 )
 161 ::
 162
 163 code::
 164 // one last example
 165 (
 166 b = Buffer.alloc(s, 512, 1);
 167 b.sine1(1.0/[1, 2, 3, 4, 5, 6], true, true, true);
 168 )
 169
 170 (
 171         { var input, kernel;
 172
 173         input=SoundIn.ar(0);
 174
 175         // must have power of two framesize
 176         Convolution2L.ar(input, b, 0, 512, 1, 0.5);
 177         }.play;
 178
 179 )
 180 ::
 181